Problem replacing Null nodes with real values in XML documents...

Question

Oracle Database 10g Enterprise Edition Release 10.2.0.4.0 - 64bit Production
Our friends in Java land are insisting on passing data between Java and PL/SQL using fairly small XML documents (don't ask). I then need to extract the input parameter values and pass them, on to the stored procedures that actually do the work. These return a result which needs to be returned to the java layer in the output XML document.
Here is a cut down version of the input XML...
<ParameterList xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<Parameter>
<Id>1</Id>
<Result xsi:nil="true"/>
</Parameter>
<Parameter>
<Id>2</Id>
<Result xsi:nil="true"/>
</Parameter>
</ParameterList>
and this is an example of what I am expected to return...
<ParameterList xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<Parameter>
<Id>1</Id>
*<Result>SUCCESS</Result>*
</Parameter>
<Parameter>
<Id>2</Id>
*<Result>WARNING</Result>*
</Parameter>
</ParameterList>
i.e. I am expected to replace the value of the Result node with a string indicating the succes or otherwise of the underlying PL/SQL process.
I am extracting the input values using the DBMS_XMLDOM functions and naively assumed that DBMS_XMLDOM.SETNODEVALUE could be used to update the value in the Result node - It didn't work so I resorted to reading the documentation which revealed that it will not work for a null node.
Am I going to have to use XSLT to generate the output XML from the Input and incorprate the result? Or is there a simpler way?
I have used XSLT in Oracle before and still have the nervous tick...

Answer 1

Thanks A Non,
With your suggestion and a bit of help from the w3schools.com xml dom tutorial I eventually managed to work out how to do this.
Here is the code (with all my debug stuff in so it looks worse than it is...)
create or replace
PROCEDURE ExtractXMLValues (p_inXml IN CLOB ) IS
l_string VARCHAR2(4000);
l_value VARCHAR2(4000);
l_DOM_doc dbms_xmldom.DOMDocument;
l_DOM_node dbms_xmldom.DOMNode;
l_new_DOM_node dbms_xmldom.DOMNode;
l_new_element dbms_xmldom.DOMElement;
l_new_DOM_nodevalue dbms_xmldom.DOMNode;
l_value_Node dbms_xmldom.DOMNode;
l_parameter_Node dbms_xmldom.DOMNode;
--l_DOM_nodelist    dbms_xmldom.DOMNodeList;
l_Result_DOM_node dbms_xmldom.DOMNode;
BEGIN
l_DOM_doc := dbms_xmldom.newDomDocument(p_inXml);
l_DOM_node := dbms_xmldom.makeNode(l_DOM_doc);
dbms_xmldom.writeToBuffer(l_DOM_node, l_string);
dbms_output.put_line('1 ' || l_string);
l_parameter_node := dbms_xslprocessor.selectSingleNode(l_DOM_node,'//Parameter');
-- get the current values in the XML document for Id and Result
l_Result_DOM_node := dbms_xslprocessor.selectSingleNode(l_DOM_node,'//Id');
l_value_Node := dbms_xmldom.getFirstChild(l_Result_DOM_node);
l_value := dbms_xmldom.getnodevalue(l_value_Node);
dbms_xmldom.writeToBuffer(l_Result_DOM_node, l_string);
dbms_output.put_line('2 ' || l_string || ' : ' || l_value);
l_Result_DOM_node := dbms_xslprocessor.selectSingleNode(l_DOM_node,'//Result');
l_value_Node := dbms_xmldom.getFirstChild(l_Result_DOM_node);
l_value := dbms_xmldom.getnodevalue(l_value_Node);
dbms_xmldom.writeToBuffer(l_Result_DOM_node, l_string);
dbms_output.put_line('3 ' || l_string || ' : ' || l_value);
-- create new Result node
l_new_DOM_node      := dbms_xmldom.makenode(dbms_xmldom.createElement(l_DOM_doc, 'Result'));
dbms_xmldom.writeToBuffer(l_new_DOM_node, l_string);
dbms_output.put_line('4 New node : ' || l_string);
-- create a value for it
l_new_DOM_nodevalue := dbms_xmldom.makenode(dbms_xmldom.createtextnode(l_DOM_doc, 'SUCCESS'));
dbms_xmldom.writeToBuffer(l_new_DOM_nodevalue, l_string);
dbms_output.put_line('5 New node value : ' || l_string);
-- add the value to the new Result node
l_new_DOM_nodevalue := dbms_xmldom.appendchild(l_new_DOM_node,  l_new_DOM_nodevalue);
dbms_xmldom.writeToBuffer(l_new_DOM_node, l_string);
dbms_output.put_line('6 New node : ' || l_string);
-- replace the old node with the new one
l_Result_DOM_node := dbms_xmldom.replaceChild(l_parameter_node, l_new_DOM_node, l_Result_DOM_node);
dbms_xmldom.writeToBuffer(l_parameter_node, l_string);
dbms_output.put_line('6 parameter node : ' || l_string);
dbms_xmldom.writeToBuffer(l_DOM_node, l_string);
dbms_output.put_line('7 Updated document ' || l_string);
dbms_xmldom.freeDocument(l_DOM_doc);
END ExtractXMLValues;
and the output...
1 <ParameterList xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<Parameter>
<Id>1</Id>
<Result xsi:nil="true"/>
</Parameter>
</ParameterList>
2 <Id>1</Id> : 1
3 <Result xsi:nil="true"/> :
4 New node : <Result/>
5 New node value : SUCCESS
6 New node : <Result>SUCCESS</Result>
6 parameter node : <Parameter>
<Id>1</Id>
<Result>SUCCESS</Result>
</Parameter>
7 Updated document <ParameterList xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<Parameter>
<Id>1</Id>
*<Result>SUCCESS</Result>*
</Parameter>
</ParameterList>
One question, why do the dbms_xmldom functions return the Old value? I was expecting the returned value to be the updated node.
Edited by: Lone voice on May 14, 2009 11:24 AM