Replacing Window Title with other value

Question

Hi to everyone
Can anyone tell me how can I replace the window title with other values...for example with active record...mean client name should appear instead of window title.
Thanks in advance

Answer 1

Here is the code I use from a simple form. You can see it handles three separate environments, Client/Server, Web separate frame, and Web inside browser window.
I like to remove the "Oracle Forms Runtime" from the main window, only in Client/Server, you cannot remove the brackets. So you are left with - [ Your Title ]Here is the code. It can be put into either the Pre-Form or When-New-Form-Instance trigger. But note that once you do this, EVERY form must set its title, or the one you set last will show up on all your subsequent forms:
    DECLARE
      WINDOW_ID        WINDOW := FIND_WINDOW('WINDOW0');
      WTitle           Varchar2(100) := 'My Test Form';
    BEGIN
      Set_Window_Property(Window_Id,Window_State,Maximize);
      If Get_Application_Property(User_Interface) = 'WEB' then
        --Web forms:  set MDI title, erase W0 title.
        Set_Window_Property(Window_Id,Title,' ');
        Set_Window_Property(Forms_MDI_Window,Title,' ' || WTitle);
        --- Check if running SeparateFrame=False (form within browser)
        If get_window_property(forms_mdi_window,title) is null then
          --SeparateFrame=False:  running inside browser window.
          --Cannot set browser title; need to set Window0 title
          Set_Window_Property(Window_Id,Title,' ' || WTitle);
        end if;
      Else -- client/server forms
        Set_Window_Property(Forms_MDI_Window,Title,' ');
        Set_Window_Property(Window_Id,Title,' '||WTitle||' ');
      End if;
    END;