Problem with LIKE in Cursor

Question

I have table week_tab with data
week_num bkg1 bkg2 bkg_type
1     10     20     at_prod
2     40     10     at_serv
3     30     20     prod
2     20     60     at_prod
1     10     50     at_serv
1     20     80     at_net
3     10     30     at_net
I'm trying to put this query in a cursor
SELECT SUM(bkg2), bkg_type
FROM week_tab
WHERE bkg_type LIKE 'at%'
GROUP BY bkg_type;
PROCEDURE get_bkg_tot(
p_colName IN VARCHAR2,
p_refCursor OUT ref_cursor) AS
v_query VARCHAR2(4000);
BEGIN
v_query := 'select sum('||p_colName||'), bkg_type
from week_tab
where bkg_type like : x
group by bkg_type';
OPEN p_refcursor FOR v_query USING 'at%';
END;
PROCEDURE get_total_val AS
v_refCursor ref_cursor;
v_sum NUMBER;
v_week NUMBER;
v_total NUMBER := 0;
v_colName STRARRAY := STRARRAY ('BKG1','BKG2');
BEGIN
FOR i IN v_colName.FIRST .. v_colName.LAST LOOP
get_bkg_tot ('bkg2', v_refcursor);
LOOP
FETCH v_refCursor
INTO v_sum, v_week;
EXIT WHEN v_refcursor%NOTFOUND;
v_total := v_total + v_sum;
DBMS_OUTPUT.PUT_LINE ('Week '|| v_week||' : '|| v_sum);
END LOOP;
DBMS_OUTPUT.PUT_LINE ('Total Bookings Sale :'|| v_total);
END LOOP;
END get_total_val;
When I tried to execute get_total_val, I'm getting
ORA-01722: invalid number
ORA-06512: at "SCOTT.GET_TOTAL", line 45
ORA-06512: at line 2
What could be the error?
Thanks in advance

Answer 1

Hi,
After corrected fetch into clause...
CREATE OR REPLACE PACKAGE BODY GET_TOTAL AS
   PROCEDURE get_week_total(p_colName   IN VARCHAR2,
                            p_refCursor OUT ref_cursor) AS
      v_query VARCHAR2(4000);
   BEGIN
      v_query := 'SELECT SUM(' || p_colName ||
                 '), week_num FROM week_tab GROUP BY week_num ORDER BY week_num';
      OPEN p_refcursor FOR v_query;
   END get_week_total;
   PROCEDURE get_bkg_tot(p_colName   IN VARCHAR2,
                         p_refCursor OUT ref_cursor) AS
      v_query VARCHAR2(4000);
   BEGIN
      v_query := 'select sum(' || p_colName || '), WEEK_NUM ';
      v_query := v_query || 'from week_tab ';
      v_query := v_query || 'where bkg_type like :x ';
      v_query := v_query || 'group by week_num';
      OPEN p_refcursor FOR v_query
         USING 'at%';
   END;
   PROCEDURE get_total_val AS
      v_refCursor ref_cursor;
      v_sum       NUMBER;
      v_week      NUMBER;
      v_total     NUMBER := 0;
      v_colName   STRARRAY := STRARRAY('BKG1',
                                       'BKG2');
   BEGIN
      FOR i IN v_colName.FIRST .. v_colName.LAST LOOP
         get_bkg_tot(v_colName(i),
                     v_refcursor);
         LOOP
            FETCH v_refCursor
               INTO v_sum, v_week;
            EXIT WHEN v_refcursor%NOTFOUND;
            v_total := v_total + v_sum;
            DBMS_OUTPUT.PUT_LINE('Week ' || v_week || ' : ' || v_sum);
         END LOOP;
         DBMS_OUTPUT.PUT_LINE('Total Bookings Sale :' || v_total);
      END LOOP;
   END get_total_val;
END GET_TOTAL;The output is:
Week 1 : 40
Week 2 : 60
Week 3 : 10
Total Bookings Sale :110
Week 1 : 150
Week 2 : 70
Week 3 : 30
Total Bookings Sale :360Regards,