Querying Cubes on Update Rules?

Question

I have an update rule that currently queries an ODS to get the value of a key figure and then apply that key figure to the cube the update rule is intended for.
Basically, this is the select statement I use in the routine:
select defect_quantity from table_a
  where notification = notification
    and notif_item = notif_item.
Since the ODS is a flat table, this works fine.  However, I am having trouble figuring out how to write this same query against a cube. 
Is there a way to query a cube with ABAP in an update rule?  Any info or link to how to do this would be appreciated.
Thanks,
Brent

Answer 1

Hi,
There is simple example:
**> You must fill G_T_RANGE table with selection conditions for
**> InfoCube data. In this case char 0VERSION = '1' and
**> 0CALYEAR = '2005'. 
  CLEAR G_S_RANGE.
  G_S_RANGE-CHANM    = '0VERSION'.
  G_S_RANGE-SIGN     = 'I'.
  G_S_RANGE-COMPOP   = 'EQ'.
  G_S_RANGE-LOW      = '1'.
  APPEND G_S_RANGE TO G_T_RANGE.
  G_S_RANGE-CHANM    = '0CALYEAR'.
  G_S_RANGE-SIGN     = 'I'.
  G_S_RANGE-COMPOP   = 'EQ'.
  G_S_RANGE-LOW      = '2005'.
  APPEND G_S_RANGE TO G_T_RANGE.
**> You should also provide information for which combination
**> of characteristic you need value
  CLEAR G_S_SFC.
  G_S_SFC-CHANM    = '0VERSION'.
  G_S_SFC-CHAALIAS = '0VERSION'.
  G_S_SFC-ORDERBY  = 0.
  INSERT G_S_SFC INTO TABLE G_TH_SFC.
  G_S_SFC-CHANM    = '0PROFIT_CTR'.
  G_S_SFC-CHAALIAS = '0PROFIT_CTR'.
  G_S_SFC-ORDERBY  = 0.
  INSERT G_S_SFC INTO TABLE G_TH_SFC.
  G_S_SFC-CHANM    = '0CALYEAR'.
  G_S_SFC-CHAALIAS = '0CALYEAR'.
  G_S_SFC-ORDERBY  = 0.
  INSERT G_S_SFC INTO TABLE G_TH_SFC.
**> And finaly which keyfigure should be aggregated
  CLEAR G_S_SFK.
  G_S_SFK-KYFNM    = '0AMOUNT'.
  G_S_SFK-KYFALIAS = '0AMOUNT'.
  G_S_SFK-AGGR     = 'SUM'.
  INSERT G_S_SFK INTO TABLE G_TH_SFK.
**> I_INFOPROV - InfoProvider name. In this case InfoCube name
**> I_TH_SFC - table with selected chars
**> I_TH_SFK - table with selected keyfs
**> I_T_RANGE - table selection conditions
**> I_PACKAGESIZE - number of records in one function call
**> You should call this function as many times as parameter
**> E_END_OF_DATA will receive 'X' which means that last data
**> packet has been read
**> G_T_DATA - table with aggregated data from InfoCube
  CALL FUNCTION 'RSDRI_INFOPROV_READ'
    EXPORTING
      I_INFOPROV                   = 'ZINFOCUBE'
      I_TH_SFC                     = G_TH_SFC
      I_TH_SFK                     = G_TH_SFK
      I_T_RANGE                    = G_T_RANGE
      I_PACKAGESIZE                = 10000
      I_ROLLUP_ONLY                = ''
    IMPORTING
      E_T_DATA                     = G_T_DATA
      E_END_OF_DATA                = END_OF_DATA
    CHANGING
      C_FIRST_CALL                 = G_FIRST_CALL
    EXCEPTIONS
      OTHERS                       = 1.
Krzys