Question regarding a particular query

Question

hi all
i need ur help to write a query. please cosider the following scenario:
There is a table having colums (Attribute, Value) and data:
Attribute Value
a1 1
a2 2
a3 3.2
a4 a1*a2+a3
a5 a3 - a1
is it possible to write a query which will bring:
a1 1
a2 2
a3 3.2
a4 5.2
a5 2.2
Meaning the same column (Value) contains the numeric values as well as the formulas. There can be any number of operands, and all kind of possible operators.
Waiting for a response.
Omer

Answer 1

Given you have following table:
Name
VARIABLE VARCHAR2
FORMEL VARCHAR2
and you implement the following package:
CREATE OR REPLACE PACKAGE EVALUATE_STRING AS
FUNCTION evaluate(v_formel VARCHAR2, level NUMBER:= 0) RETURN VARCHAR2;
END;
CREATE OR REPLACE PACKAGE BODY EVALUATE_STRING AS
FUNCTION evaluate(v_formel VARCHAR2, level NUMBER:= 0) RETURN VARCHAR2 IS
CYCLIC_ERROR EXCEPTION;
UNDEFINED_VARIABLE EXCEPTION;
V_AKT_VAR VARCHAR2(4000);
V_AKT_CHAR VARCHAR2(1);
V_OPERANDS VARCHAR2(20):= '+-*/()';
V_TODO VARCHAR2(32767);
what VARCHAR2(20):= 'A NUMBER';
V_ERGEBNIS VARCHAR2(4000);
V_FORMEL_WERT VARCHAR2(32767);
v_error VARCHAR2(255);
FUNCTION IS_NUMBER(v_string VARCHAR2) RETURN BOOLEAN IS
laenge NUMBER;
help VARCHAR2(32767);
anz NUMBER;
erg BOOLEAN:= TRUE;
BEGIN
laenge:= length(v_string);
anz:= 1;
WHILE erg AND (anz<=laenge) LOOP
IF instr('1234567890.',substr(v_string,anz,1))!= 0 THEN
anz:= anz+1;
ELSE
erg:= FALSE;
END IF;
END LOOP;
RETURN erg;
EXCEPTION
WHEN OTHERS THEN RETURN FALSE;
END IS_NUMBER;
FUNCTION IS_FORMEL(v_string VARCHAR2) RETURN BOOLEAN IS
laenge NUMBER;
help VARCHAR2(32767);
anz NUMBER;
erg BOOLEAN:= FALSE;
BEGIN
laenge:= length(v_string);
anz:= 1;
WHILE NOT erg AND (anz<=laenge) LOOP
IF instr(V_OPERANDS,substr(v_string,anz,1)) = 0 THEN
anz:= anz+1;
ELSE
erg:= TRUE;
END IF;
END LOOP;
RETURN erg;
EXCEPTION
WHEN OTHERS THEN RETURN FALSE;
END IS_FORMEL;
BEGIN
IF level >= 40 THEN
raise CYCLIC_ERROR;
END IF;
IF NOT IS_NUMBER(v_formel) THEN
FOR x IN 1 .. NVL(LENGTH(v_formel),0) LOOP
V_AKT_CHAR:= substr(v_formel,x,1);
IF instr(V_OPERANDS,V_AKT_CHAR) != 0 OR V_AKT_CHAR = ' ' OR x = LENGTH(v_Formel) THEN
IF x = LENGTH(v_Formel) THEN
V_AKT_VAR:= V_AKT_VAR||V_AKT_CHAR;
END IF;
IF V_AKT_VAR IS NOT NULL THEN
IF IS_NUMBER(V_AKT_VAR) THEN
V_TODO:= V_TODO||V_AKT_VAR;
ELSE
IF IS_FORMEL(V_AKT_VAR) THEN
V_TODO:= V_TODO||evaluate(V_AKT_VAR,level+1);
ELSE -- a Variable
begin
SELECT FORMEL
INTO V_FORMEL_WERT
FROM FORMULAR
WHERE VARIABLE = V_AKT_VAR;
exception
when others then
RAISE UNDEFINED_VARIABLE;
end;
V_TODO:= V_TODO||evaluate(V_FORMEL_WERT,level+1);
END IF; /* if is_formel(..*/
END IF; /* if is number */
END IF; /* if v_akt_var is not null */
V_AKT_VAR:= NULL;
IF instr(V_OPERANDS,V_AKT_CHAR) != 0 THEN
V_TODO:= V_TODO||V_AKT_CHAR;
END IF;
ELSE
V_AKT_VAR:= V_AKT_VAR||V_AKT_CHAR;
END IF; /* if instr(V_OPERANDS,V_AKT_CHAR) .. */
END LOOP;
ELSE
V_TODO:= v_formel;
END IF;
EXECUTE IMMEDIATE 'SELECT '||V_TODO||' FROM DUAL' INTO V_ERGEBNIS;
RETURN V_ERGEBNIS;
EXCEPTION
WHEN CYCLIC_ERROR THEN
RAISE_APPLICATION_ERROR (-20000, 'Error:Max. level reached!');
WHEN UNDEFINED_VARIABLE THEN
RAISE_APPLICATION_ERROR (-20000, 'Undefinded Variable: '||V_AKT_VAR);
WHEN OTHERS THEN
v_error:= SQLERRM;
RAISE_APPLICATION_ERROR (-20000,v_error||' '||V_TODO);
END evaluate;
END;
you are able to select:
SQL> select substr(variable,1,10) VAR,
2 substr(formel,1,20) FORMEL,
3 substr(evaluate_string.evaluate(formel,0),1,30) erg
4 from formular;
VAR FORMEL ERG
a1 1 1
a2 2 2
a3 3.2 3.2
a4 a1*a2+a3 5.2
a5 a3 - a1 2.2
a6 (5-3)*2 4
a7 3 * 3 9
Regards
Anna