Read exchange mailbox from oracle

Question

Hello all,
Is there anyway i can read a mailbox in outlook from forms with pl/sql or anything else ?
thanks

Answer 1

Right now i can't find the link, but i've the content which was posted by Billy in this forum. So, i'm posting it exactly what he posted -
> Can you provide me some references for the same? (sample inplementation or study
material)
Well, here is a very basic example of a PL/SQL pipelined table function that wraps a POP3 mail account into a SQL table - allowing you to run SQLs directly against the e-mail account.
I did a few basic tests using a local POP3 server on my Linux box and it seems to work fine.
SQL> create or replace type TStrings is table of varchar2(4000);
  2  /
Type created.
SQL>  
SQL> create or replace function pop3( userName varchar2, password varchar2, msgNum number ) return TStrings pipelined is
  2          POP3_SERVER             constant varchar2(19) := '127.0.0.1';
  3          POP3_PORT               constant number := 110;
  4          POP3_TIMEOUT            constant number := 5;
  5          POP3_OK                 constant varchar2(10) := '+OK';
  6
  7          E_POP3_ERROR    exception;
  8          E_READ_TIMEOUT  exception;
  9          pragma exception_init( E_READ_TIMEOUT, -29276 );
10
11          socket  UTL_TCP.connection;
12          line    varchar2(4000);
13          bytes   integer;
14
15          -- send a POP3 command
16          -- (we expect each command to respond with a +OK)
17          function  WriteToPop( command varchar2 ) return varchar2 is
18                  len     integer;
19                  resp    varchar2(4000);
20          begin
21                  len := UTL_TCP.write_line( socket, command );
22                  UTL_TCP.Flush( socket );
23
24                  -- using a hack to check the popd response
25                  len := UTL_TCP.read_line( socket, resp );
26
27                  if SUBSTR(resp,1,3) != POP3_OK then
28                          raise E_POP3_ERROR;
29                  end if;
30
31                  return( resp );
32          end;
33
34
35
36  begin
37          PIPE ROW( 'pop3:'||POP3_SERVER||' port:'||POP3_PORT );
38          -- open a socket connection to the POP3 server
39          socket := UTL_TCP.open_connection(
40                          remote_host => POP3_SERVER,
41                          remote_port => POP3_PORT,
42                          tx_timeout => POP3_TIMEOUT,
43                          charset     => 'US7ASCII'
44          );
45
46          -- read the server banner/response from the pop3 daemon
47          PIPE ROW( UTL_TCP.get_line(socket) );
48
49          -- authenticate with the POP3 server using the USER and PASS commands
50          PIPE ROW( 'USER '||userName ); PIPE ROW( WriteToPop('USER '||userName) );
51          PIPE ROW( 'PASS '||password ); PIPE ROW( WriteToPop('PASS '||password) );
52
53          -- retrieve the specific message
54          PIPE ROW( 'RETR '||msgNum ); PIPE ROW( WriteToPop('RETR '||msgNum) );
55          PIPE ROW( '*** START OF INTERNET MESSAGE BODY ***' );
56          loop
57                  bytes := UTL_TCP.Available( socket );
58                  if bytes > 0 then
59                          bytes := UTL_TCP.read_line( socket, line );
60                          PIPE ROW( line );
61                  end if;
62
63                  exit when bytes = 0;
64          end loop;
65          PIPE ROW( '*** END OF INTERNET MESSAGE BODY ***' );
66
67          -- close connection
68          PIPE ROW( 'QUIT' );     PIPE ROW( WriteToPop('QUIT') );
69
70          UTL_TCP.close_connection( socket );
71  end;
72  /
Function created.
SQL> show errors
No errors.
SQL>
SQL> select * from TABLE( pop3('billy','my-secret-password-goes-here',1) );
COLUMN_VALUE
pop3:127.0.0.1 port:110
+OK You are connected to a test Dovecot POP3 server
USER billy
+OK
PASS my-secret-password-goes-here
+OK Logged in.
RETR 1
+OK 548 octets
*** START OF INTERNET MESSAGE BODY ***
Return-path: <[email protected]>
Envelope-to: [email protected]
Delivery-date: Mon, 20 Aug 2007 09:23:38 +0200
Received: from localhost ([127.0.0.1])
        by localhost.com with smtp (Exim 4.63)
        (envelope-from <[email protected]>)
        id 1IN1bC-0001BC-9A
        for [email protected]; Mon, 20 Aug 2007 09:23:38 +0200
Subject: Test E-Mail
X-Mailer: telnet
Message-Id: <[email protected]>
From: [email protected]
Date: Mon, 20 Aug 2007 09:23:21 +0200
This is a test message.
Blah blah blah...
*** END OF INTERNET MESSAGE BODY ***
QUIT
+OK Logging out.
31 rows selected.
SQL>Note that the trailing period is the end-of-message-body marker and not really part of the message body that the sender created.
PS. Oh yes - I defined a timeout exception and tried catching that to determine the eof for the message body, but ran into what seems to be an Oracle bug. However, simply checking whether there is data to read, using the UTL_TCP.Available() function, works great.
Regards.
Satyaki De
N.B.: Credit goes to Billy.