Read R/3 or BW Table into Excel

Question

Hi Gurus,
is it possible to read a table content from R/3 or BW into Excel?
Does anyone has a piece of working code?
Regards,
Memoli

Answer 1

Hi Memoli,
i dont know what you really want to do with that information but there are many ays. maybe you can use the following VBA code which connects to SAP system and uses the function module "TABLE_ENTRIES_GET_VIA_RFC":
Sub retrieve_table_contents()
Dim R3, MyFunc, App As Object
Dim SEL_TAB, NAMETAB, TABENTRY, ROW As Object
Dim Result As Boolean
Dim iRow, iColumn, iStart, iStartRow As Integer
iStartRow = 4
Sheets("Tabelle1").Select
Range("A1").Select
Range(Selection, ActiveCell.SpecialCells(xlLastCell)).Select
Selection.ClearContents
Range("A1").Select
'Create Server object and Setup the connection
Set R3 = CreateObject("SAP.Functions")
R3.Connection.System = "YOUR_SYSTEM_ID"
R3.Connection.SystemNumber = "YOUR_SYSTEM_NUMBER"
R3.Connection.ApplicationServer = "YOUR_SERVER"
R3.Connection.client = "YOUR_CLIENT_NUMBER"
R3.Connection.user = "YOUR_USER"
R3.Connection.Password = "YOUR_PASSWORD."
R3.Connection.Language = "YOUR_LANGUAGE"
If R3.Connection.logon(0, False) <> True Then
Exit Sub
End If
'Call RFC function TABLE_ENTRIES_GET_VIA_RFC
Set MyFunc = R3.Add("TABLE_ENTRIES_GET_VIA_RFC")
Dim oParam1 As Object
Dim oParam2 As Object
Dim oParam3 As Object
Dim oParam4 As Object
Set oParam1 = MyFunc.exports("LANGU")
Set oParam2 = MyFunc.exports("ONLY")
Set oParam3 = MyFunc.exports("TABNAME")
Set oParam4 = MyFunc.Tables("SEL_TAB")
oParam1.Value = "E"
oParam2.Value = ""
oParam3.Value = "TSTCT"
oParam4.Rows.Add
' oParam4.Value(1, "ZEILE") = ""
Result = MyFunc.call
If Result = True Then
Set NAMETAB = MyFunc.Tables("NAMETAB")
Set SEL_TAB = MyFunc.Tables("SEL_TAB")
Set TABENTRY = MyFunc.Tables("TABENTRY")
Else
MsgBox MyFunc.EXCEPTION
R3.Connection.LOGOFF
Exit Sub
End If
'Result = R3.TABLE_ENTRIES_GET_VIA_RFC(EXCEPTION, BELNR:="*8670", LANGU:="E", ONLY:="", NAMETAB:="COSP")
'Quit the SAP Application
R3.Connection.LOGOFF
If Result <> True Then
MsgBox (EXCEPTION)
Exit Sub
End If
'Display table header
iColumn = 1
For Each ROW In NAMETAB.Rows
Cells(iStartRow - 1, iColumn) = ROW("FIELDNAME")
' For C and N datatypes, explicitly set the cell to TEXT format, otherwise leading zeroes will be lost
' when numbers are imported from a SAP text field
If ROW("INTTYPE") = "C" Or ROW("INTTYPE") = "N" Then
Range(Cells(iStartRow - 1, iColumn), Cells(iStartRow - 1 + TABENTRY.RowCount, iColumn)).Select
Selection.NumberFormat = "@"
End If
Cells(iStartRow, iColumn) = ROW("FIELDTEXT")
iColumn = iColumn + 1
Next
Range(Cells(iStartRow - 1, 1), Cells(iStartRow, NAMETAB.RowCount)).Font.Bold = True
'Display Contents of the table
iColumn = 1
For iRow = iStartRow + 1 To TABENTRY.RowCount
For iColumn = 1 To NAMETAB.RowCount
iStart = NAMETAB(iColumn, "OFFSET") + 1
' If this is the last column, calculate the length differently than the other columns
If iColumn = NAMETAB.RowCount Then
iLength = Len(TABENTRY(iRow, "ENTRY")) - iStart
Else
iLength = NAMETAB(iColumn + 1, "OFFSET") - NAMETAB(iColumn, "OFFSET")
End If
' If the fields at the end of the record are blank, then explicitly set the value
If iStart > Len(TABENTRY(iRow, "ENTRY")) Then
Cells(iRow, iColumn) = Null
Else
Cells(iRow, iColumn) = Mid(TABENTRY(iRow, "ENTRY"), iStart, iLength)
End If
Next
Next
'Format the Columns
Range(Cells(iStartRow, 1), Cells(iStartRow + TABENTRY.RowCount, NAMETAB.RowCount)).Select
Selection.EntireColumn.AutoFit
End Sub
The most important part is this one:
'Call RFC function TABLE_ENTRIES_GET_VIA_RFC
Set MyFunc = R3.Add("TABLE_ENTRIES_GET_VIA_RFC")
Dim oParam1 As Object
Dim oParam2 As Object
Dim oParam3 As Object
Dim oParam4 As Object
Set oParam1 = MyFunc.exports("LANGU")
Set oParam2 = MyFunc.exports("ONLY")
Set oParam3 = MyFunc.exports("TABNAME")
Set oParam4 = MyFunc.Tables("SEL_TAB")
oParam1.Value = "E"
oParam2.Value = ""
oParam3.Value = "TSTCT"
oParam4.Rows.Add
' oParam4.Value(1, "ZEILE") = ""
oParam3.Value = "TSTCT" --> TABLE NAME
oParam4.Value --> Here you can make selections!!!
Regards,
Adem
PS: Maybe i cant post the coding correct in the browser as the code can be changed by the forum software. Than i can send it to your mail.