Record contents of variables

Question

Dear Friends,
do you know a way how to achieve this.
Record contents of the processed variables e.g. of a report or program.
Assume any report has been performed and there is a way to record or store
all its variables for evaluating .
If it is not possible by abap maybe there is a way to solve it with system calls.
I mean  same as like CALL 'ABAP_CALLSTACK  but only for variables. Maybe there is a
system call something like CALL ABAP_STACK_VARIABLES.
Kindly Regards
Alex

Answer 1

and list of global variables of a program:
REPORT z_write_global_variables.
PARAMETERS progname TYPE program DEFAULT 'SAPLSALV'.
START-OF-SELECTION.
  PERFORM write_global_variables USING progname.
*&      Form  find_global_variables
FORM write_global_variables USING progname TYPE program.
  DATA lo_prog TYPE REF TO cl_abap_compiler.
  DATA lt_types TYPE scr_rtags.
  DATA ls_types TYPE LINE OF scr_rtags.
  DATA lt_result2 TYPE scr_glrefs.
  DATA ls_result2 TYPE scr_glref.
  DATA lt_grades TYPE scr_grades.
  DATA ls_grades TYPE LINE OF scr_grades.
  CREATE OBJECT lo_prog
    EXPORTING
      p_name = progname.
  ls_types-sign = 'I'.
  ls_types-option = 'EQ'.
  ls_types-low = cl_abap_compiler=>tag_data.
  APPEND ls_types TO lt_types.
  ls_grades-sign = 'I'.
  ls_grades-option = 'EQ'.
  ls_grades-low = cl_abap_compiler=>grade_direct.
  APPEND ls_grades TO lt_grades.
  lo_prog->get_all_refs(
        EXPORTING
          p_local = 'X'
          p_types = lt_types
          p_grades = lt_grades
        IMPORTING
          p_result = lt_result2 ).
  DATA l_start TYPE string.
  CONCATENATE '\' cl_abap_compiler=>tag_program ':' progname '\'
        cl_abap_compiler=>tag_data '*' INTO l_start.
  LOOP AT lt_result2 INTO ls_result2 WHERE full_name CP l_start.
    WRITE / ls_result2-full_name.
  ENDLOOP.
ENDFORM.                    "write_global_variables