Refresh of single sheet in a workbook

Question

Hi all,
I have a workbook with 5 sheets and each sheet has 2 different queries. Users want to have a refresh button on each sheet, so that when they click on refresh button only that sheet should be refreshed. I know this can be done using VBA but does anyone have the code which does this functionality?
Thanks in advance.

Answer 1

Hi Hansa,
    Here is what you need to do.
1) Place a Button on Each Sheet that you would like to Refresh.
2) On Each button Place the Following Code.
    Me.Select
   ' Cell from the first Query.
    Range("B2").Activate
    Run "SAPBEX.XLA!SAPBEXrefresh", False
   'Cell in the Second Query
   Range("AA2").Activate
   Run "SAPBEX.XLA!SAPBEXrefresh", False
   'So on for all the Queries on that Sheet.
You can add some Error Handling if you need to.
If you use
Run "SAPBEX.XLA!SAPBEXrefresh", True
Then all Queries will be refreshed so I think you will have to do the above.
If you Really want this to be Dynamic where in every time you add a Query to the Sheet you don't want to change the Code then here is my Suggestion.
'Do this when the sheet is setup.
'On the Button of Each Sheet
Private Sub CommandButton1_Click()
          Send the Sheet Name to a Generic Code in a Module
         'Here the Row Number is a Cell Where you can add all
         ' the Ranges for that Sheet.
' e.g. on a Hidden Sheet
' Cell A5 for Sheet 1 looks like Below
' B2, Z2, A100
' Indicates that Sheet1 has 3 Queries Starting on Cell B2, A100
         Call RefreshSheet("Sheet1",5 )
End Sub
' In a Module Create this
Public Sub RefreshSheet(ByVal sSheet As String, ByVal iRow As Integer)
    'Assumptions: There is a Sheet called Update.
    'Cells have Starting Cell of Each Query in Rows. Column "A"
    On Error GoTo Err_RefreshSheet
    Dim arrCells() As String
    Dim wks As Worksheet
    Dim iLoop As Integer
        Set wks = ThisWorkbook.Worksheets(sSheet)
        'Here Update is my Hidden sheet and Row, 1 is the Cells that holds Ranges
        arrCells = Split(ThisWorkbook.Sheets("Update").Cells(iRow, 1), ",")
        'Activate the Sheet that needs to be refreshed.
        wks.Activate
        'This will Loop on all the Cells where there is Query and Refresh it.
        For iLoop = 0 To UBound(arrCells)
           wks.Range(arrCells(iLoop)).Activate
           Run "SAPBEX.XLA!SAPBEXrefresh", False
        Next
Exit_RefreshSheet:
    Set wks = Nothing
    Exit Sub
Err_RefreshSheet:
    MsgBox "There Following Error in RefreshSheet" & vbCrLf & _
           Err.Description
    Err.Clear
    Resume Exit_RefreshSheet
End Sub
This way when you add a new Query on  Any Sheet all you do is go to Update Sheet and on the Line for the Sheet with new Query Add the Cell to Comma seperated Values.
The Code is Almost there, you will have to tweak it a bit.
Hope this Helps. !!
Datta.