Regarding uploading data from excel sheet to internal table

Question

hi,
while executing the code im getting the output one by one but i want it to be displayed in a table format can any one help me regarding this issue.
thanks and regards,
siri

Answer 1

Hi Sirisha,
Through this FM we can't get the data in tabular format. After getting data from this FM we have to convert to tabular format. As far as i know there is no FM for Excel upload which directly gives data in tabular format.
Check below sample code which uploads 3 columns from excel file.
U can add as many case statements as the number of fields.
PARAMETERS: po_file TYPE rlgrap-filename DEFAULT 'E:test.xls'.
TYPES: BEGIN OF t_final,
          empno(10) TYPE c,
          name(30) TYPE c,
          state(25) TYPE c,
       END OF t_final.
DATA: i_tab    TYPE STANDARD TABLE OF alsmex_tabline,
      i_final  TYPE STANDARD TABLE OF t_final,
      wa_tab   TYPE alsmex_tabline,
      wa_final TYPE t_final.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR po_file.
PERFORM open_folder.
START-OF-SELECTION.
CALL FUNCTION 'ALSM_EXCEL_TO_INTERNAL_TABLE'
     EXPORTING
          filename                = po_file
          i_begin_col             = 1
          i_begin_row             = 1
          i_end_col               = 3
          i_end_row               = 65256
     TABLES
          intern                  = i_tab
     EXCEPTIONS
          inconsistent_parameters = 1
          upload_ole              = 2
          OTHERS                  = 3.
CHECK NOT i_tab[] IS INITIAL.
LOOP AT i_tab INTO wa_tab.
  CASE wa_tab-col.
    WHEN 1.
      wa_final-empno = wa_tab-value.
    WHEN 2.
      wa_final-name = wa_tab-value.
    WHEN 3.
      wa_final-state = wa_tab-value.
  ENDCASE.
  AT END OF row.
    APPEND wa_final TO i_final.
    CLEAR wa_final.
  ENDAT.
ENDLOOP.
FORM open_folder .
  DATA: li_file  TYPE TABLE OF sdokpath,
        lwa_file TYPE sdokpath.
  CLEAR: po_file, lwa_file.
  REFRESH li_file[].
  CALL FUNCTION 'TMP_GUI_FILE_OPEN_DIALOG'
       TABLES
            file_table = li_file
       EXCEPTIONS
            cntl_error = 1
            OTHERS     = 2.
  IF sy-subrc IS INITIAL.
    READ TABLE li_file INTO lwa_file INDEX 1.
    IF sy-subrc IS INITIAL.
      po_file = lwa_file-pathname.
    ENDIF.
  ENDIF.
ENDFORM.                    " open_folder
Just try executing above code in debug mode. U will understand the functionality.
Thanks,
Vinod.