Problems in uploading from excel sheet to internal table

Question

hi experts,
i got one problem regarding uploading data from excel sheet to int.table. I used FM ALSM_EXCEL_TO_INTERNAL_TABLE but in that the value is char of 50. but i need a case where i have to send value more than 50 characters. please suggest me any other FM to overcome this problem.
advanced thanks
vijay

Answer 1

Hi,
>
Vijay Krishna Arvapalli wrote:
> hi tarun,
>
> thank you for your reply
>
> but when i tried to use FM TEXT_CONVERT_XLS_TO_SAP it is giving error actually that 'Error generating the test frame'.
>
> so can you suggest me with some other option where i can upload the field with more than 50 character length.
>
> thank you
> regards
> vijay
Yes, when you execute the FM from SE37, then it displays a message.
Just copy the below code and paste it in a report (SE38) and execute.
Create a file in C:/ with name test.xls and execute it will display the records even with more than 50 characters of length.
I have tested and its working.
I have taken three fields in the excel file empid, name and doj.
TYPE-POOLS : truxs.
PARAMETERS : p_file TYPE rlgrap-filename DEFAULT 'C:\TEST.XLS'.
DATA : BEGIN OF itab OCCURS 0,
         empid(150) TYPE c,
         name(150) TYPE c,
         doj(150) TYPE c,
       END OF itab.
DATA: it_raw TYPE truxs_t_text_data.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
  PERFORM f4_file_process USING p_file.
AT SELECTION-SCREEN.
  PERFORM validate_file_path USING p_file.
START-OF-SELECTION.
  PERFORM upload_data.
END-OF-SELECTION.
  PERFORM display_data.
*&      Form  F4_FILE_PROCESS
*       text
*      -->P_FILE_PATH  text
FORM f4_file_process USING p_file.
  CALL FUNCTION 'F4_FILENAME'
    EXPORTING
      program_name  = syst-cprog
      dynpro_number = syst-dynnr
      field_name    = 'P_FILE'
    IMPORTING
      file_name     = p_file.
  IF sy-subrc NE 0.
    MESSAGE e000(zsd).
  ENDIF.
ENDFORM.                    " F4_FILE_PROCESS
*&      Form  VALIDATE_FILE_PATH
*       text
*      -->P_FILE  text
FORM validate_file_path USING p_file.
  DATA : lv_dir TYPE string,
         lv_file TYPE string,
         lv_result(1) TYPE c.
  DATA : lv_filename TYPE string.
  lv_filename = p_file.
  CALL FUNCTION 'SO_SPLIT_FILE_AND_PATH'
    EXPORTING
      full_name     = p_file
    IMPORTING
      stripped_name = lv_file
      file_path     = lv_dir
    EXCEPTIONS
      x_error       = 1
      OTHERS        = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
  CALL METHOD cl_gui_frontend_services=>directory_exist
    EXPORTING
      directory            = lv_dir
    RECEIVING
      result               = lv_result
    EXCEPTIONS
      cntl_error           = 1
      error_no_gui         = 2
      wrong_parameter      = 3
      not_supported_by_gui = 4
      OTHERS               = 5.
  IF lv_result IS INITIAL.
    MESSAGE 'Invalid Directory' TYPE 'E'.
  ENDIF.
  CLEAR lv_result.
  CALL METHOD cl_gui_frontend_services=>file_exist
    EXPORTING
      file                 = lv_filename
    RECEIVING
      result               = lv_result
    EXCEPTIONS
      cntl_error           = 1
      error_no_gui         = 2
      wrong_parameter      = 3
      not_supported_by_gui = 4
      OTHERS               = 5.
  IF lv_result IS INITIAL.
    MESSAGE 'Invalid File' TYPE 'E'.
  ENDIF.
ENDFORM.                    " VALIDATE_FILE_PATH
*&      Form  UPLOAD_DATA
*       text
*  -->  p1        text
*  <--  p2        text
FORM upload_data .
  CALL FUNCTION 'TEXT_CONVERT_XLS_TO_SAP'
    EXPORTING
      i_field_seperator    = 'X'
      i_line_header        = 'X'
      i_tab_raw_data       = it_raw
      i_filename           = p_file
    TABLES
      i_tab_converted_data = itab[]
    EXCEPTIONS
      conversion_failed    = 1
      OTHERS               = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM.                    " UPLOAD_DATA
*&      Form  DISPLAY_DATA
*       text
*  -->  p1        text
*  <--  p2        text
FORM display_data .
  LOOP AT itab.
    WRITE : / itab-empid, itab-name, itab-doj.
  ENDLOOP.
ENDFORM.                    " DISPLAY_DATA
Hope this helps you.
Regards,
Tarun