Regexp_replace xml tags, including tags with chr(10)s in between them

Question

regexp experts!
I have the following string held in a table (there's a carriage return in the middle, and there could be multiple carriage returns):
<COMMENT>This is a test line1
Regards, testing team </COMMENT>
I've searched all the forums without success for a) a regexp_subtr to return just the bits between the tags or a b) regexp_replace to replace the tags with another string.
So ideally I'm looking for a regexp_substr to return
This is a test line1
Regards, testing team
or a regexp_replace to return
<NEW_TAG>This is a test line1
Regards, testing team </NEW_TAG>
Any advice appreciated!
Edited by: user13007502 on 19-Dec-2011 06:00

Answer 1

If you don't know the tag names (seems a bit of an odd design though as you should know what you're dealing with)... you could use the XML DOM functionality built into the database to parse the nodes of the DOM document...
SQL> set serveroutput on
SQL> ed
Wrote file afiedt.buf
  1  declare
  2    v_xml XMLTYPE := XMLTYPE('<messages>
  3  <comment>Here is a comment
  4  from customer services</comment>
  5  <disclaimer>And a disclaimer to say that you
  6  should only do this if you know what you are doing</disclaimer>
  7  </messages>');
  8    v_xsdoc     DBMS_XMLDOM.DOMDocument;
  9    v_dn        DBMS_XMLDOM.DOMNode;
10    PROCEDURE processnode; -- forward declaration
11    PROCEDURE processattributes IS
12      nm                      DBMS_XMLDOM.DOMNamedNodeMap;
13      attr                    DBMS_XMLDOM.DOMAttr;
14      attnode                 DBMS_XMLDOM.DOMNode;
15      attname                 VARCHAR2(50);
16      attval                  VARCHAR2(250);
17    BEGIN
18      nm := DBMS_XMLDOM.GetAttributes(v_dn);
19      FOR i IN 0..DBMS_XMLDOM.GetLength(nm)-1
20      LOOP
21        attnode := DBMS_XMLDOM.Item(nm, i);
22        attr := DBMS_XMLDOM.MakeAttr(attnode);
23        attname := DBMS_XMLDOM.GetName(attr);
24        attval := DBMS_XMLDOM.GetValue(attr);
25        dbms_output.put_line('Attribute: '||attname||' Value: '||attval);
26      END LOOP;
27    END;
28    PROCEDURE parse_node_element IS
29      eltype        VARCHAR2(100);
30    BEGIN
31      eltype := DBMS_XMLDOM.GetTagName(DBMS_XMLDOM.MakeElement(v_dn));
32      dbms_output.put_line('Tag: '||eltype);
33      processattributes;
34      processnode;
35    END;
36    PROCEDURE parse_node_text IS
37    BEGIN
38      DBMS_OUTPUT.PUT_LINE('Text: '||DBMS_XMLDOM.GetNodeValue(v_dn));
39    END;
40    PROCEDURE processnode IS
41      dnl      DBMS_XMLDOM.DOMNodeList;
42      nt       PLS_INTEGER;
43    BEGIN
44      dnl := DBMS_XMLDOM.GetChildNodes(v_dn);
45      dbms_output.put_line('Child Nodes Found: '||DBMS_XMLDOM.GetLength(dnl));
46      IF NOT DBMS_XMLDOM.IsNull(dnl) THEN
47        FOR i IN 0 .. (DBMS_XMLDOM.GetLength(dnl) - 1)
48        LOOP
49          v_dn := DBMS_XMLDOM.Item(dnl, i);
50          nt := DBMS_XMLDOM.GetNodeType(v_dn);
51          CASE
52            WHEN nt = DBMS_XMLDOM.ELEMENT_NODE THEN
53              parse_node_element;
54            WHEN nt IN (DBMS_XMLDOM.TEXT_NODE) THEN
55              parse_node_text();
56          ELSE
57            NULL; -- Unhandled node type;
58          END CASE;
59        END LOOP;
60      END IF;
61    END;
62  BEGIN
63    v_xsdoc := DBMS_XMLDOM.NewDOMDocument(v_xml);
64    v_dn := DBMS_XMLDOM.GetFirstChild(DBMS_XMLDOM.MakeNode(v_xsdoc));
65    processnode;
66* END;
SQL> /
Child Nodes Found: 2
Tag: comment
Child Nodes Found: 1
Text: Here is a comment
from customer services
Tag: disclaimer
Child Nodes Found: 1
Text: And a disclaimer to say that you
should only do this if you know what you are doing
PL/SQL procedure successfully completed.