Rename multiple iTunes songs

Question

Hi,
I have just imported 165 mp3 files, which do have nice and proper ID3 tags but song name is in wrong format, it is like: "123.Songname" or, three digit and dot, no space, then the real name. Is there some automatic way how to remove first four characters from the name of each song?

Answer 1

I have a script that I wrote to strip the first word (track number) of a file name that should do the trick. It can be run as a script, applet, or droplet. Spaces, periods, and dashes (not underscores) are word delimiters, so filenames that begin with any number separated by one of those are renamed:
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFDDFF;
overflow: auto;"
title="this text can be pasted into the Script Editor">
-- strip CD track numbers
-- contents of subfolders are not read
property SingleFile : false -- set to true to select individual files
on run -- double-clicked
if SingleFile then
set FileList to (choose file with multiple selections allowed without invisibles)
else
set FileList to (choose folder with multiple selections allowed without invisibles)
end if
open FileList
end run
on open FileList -- items dropped
set MyList to {}
repeat with SomeFile in FileList
if folder of (info for SomeFile) then -- expand folder contents
try
tell application "Finder" to set MyList to MyList & (get every file of SomeFile) as alias list
on error -- Tiger
tell application "Finder" to set MyList to MyList & (get every file of SomeFile) as alias as list
end try
else
set the end of MyList to SomeFile
end if
end repeat
tell application "Finder" to repeat with SomeFile in MyList
set TheName to the name of SomeFile
try -- strip a track number prefix if it exists
get (the first word of TheName) as number as text -- "words" are delimiter sensitive
set the name of SomeFile to text (word 2) thru -1 of TheName
end try
end repeat
end open
</pre>