Report that works in CMS doesn't work in VB.

Question

I'm trying to get the VB viewer code from wssdk_net_samples_12 working on a report (with 1 parameter) I created against a postgres database but I keep getting the following error:
Message: "Failed to retrieve database logon info. Information is needed before this report can be processed. (WRE 02517)"
on this line:
Dim boDocInfo As DocumentInformation = boRepEng.GetDocumentInformation(repID, boMustFill, oActions, Nothing, Nothing)
The logon apprears to work properly.  I've tested it against the standard 'World Sales Report' report.
My report works fine in Crystal Server 2008 with the parameter so I'm wondering what I'm missing.
The code to log into the DB is actually done after this code.
I'm actually at the end of what little wit I have.
Any help would be greatly appreciated.
Thanks in advance,
J
Edited by: Jason Cameron on Sep 5, 2008 5:19 PM

Answer 1

'Hey there,  sorry about the delay...and the mess.  Here's my code and it still works! Ok some of this is 'mine, some of this is BObj's, and some of this was done by people here.  I can't remember exactly who 'but if you recognize a piece of code in there that might be yours it probably is.  Thanks.  This is a pretty 'messy windows command-line app to schedule a report and put it in a specific location. 
'j
Imports BusinessObjects.DSWS
Imports BusinessObjects.DSWS.BIPlatform
Imports BusinessObjects.DSWS.BIPlatform.Constants
Imports BusinessObjects.DSWS.BIPlatform.Desktop
Imports BusinessObjects.DSWS.BIPlatform.Dest
Imports BusinessObjects.DSWS.ReportEngine
Imports BusinessObjects.DSWS.Session
Imports System
Imports System.Data
Imports System.Configuration
Public Class ModuleMainClean
    Private WS_URL_SESSION As String
    Private WS_URL_REPORTENGINE As String
    Private WS_URL_BIPLATFORM As String
    Private REPORT_STRING As String
    Private REPORT_NAME As String
    Private FILE_EXTENSION As String
    Private REPORT_FORMAT As ReportFormatEnum
    Private bipService As BIPlatform
    Private boRepEng As ReportEngine
    Private wSession As Session
    Private gstrReportParameters() As String
    Sub Main()
        SetupEnvironment()
        Logon()
        Schedule()
    End Sub
    Sub SetupEnvironment()
        Dim c As Integer
        WS_URL_SESSION = My.Settings.BaseURL + "Session"
        WS_URL_REPORTENGINE = My.Settings.BaseURL + "reportengine"
        WS_URL_BIPLATFORM = My.Settings.BaseURL + "BIPlatform"
        REPORT_STRING = My.Application.CommandLineArgs(0)
        REPORT_NAME = My.Application.CommandLineArgs(1)
        REPORT_FORMAT = System.Enum.Parse(GetType(ReportFormatEnum), My.Application.CommandLineArgs(2))
        Select Case REPORT_FORMAT
            Case ReportFormatEnum.CRYSTAL_REPORT
                FILE_EXTENSION = ".rpt"
            Case ReportFormatEnum.EXCEL, ReportFormatEnum.EXCEL_DATA_ONLY
                FILE_EXTENSION = ".xls"
            Case ReportFormatEnum.MHTML
                FILE_EXTENSION = ".mhtml"
            Case ReportFormatEnum.PDF
                FILE_EXTENSION = ".pdf"
            Case ReportFormatEnum.RTF, ReportFormatEnum.RTF_EDITABLE
                FILE_EXTENSION = ".rtf"
            Case ReportFormatEnum.TEXT_CHARACTER_SEPARATED, ReportFormatEnum.TEXT_PAGINATED, ReportFormatEnum.TEXT_PLAIN, ReportFormatEnum.TEXT_TAB_SEPARATED, ReportFormatEnum.TEXT_TAB_SEPARATED_TEXT
                FILE_EXTENSION = ".txt"
            Case ReportFormatEnum.USER_DEFINED
                FILE_EXTENSION = ".ud"
            Case ReportFormatEnum.WORD
                FILE_EXTENSION = ".doc"
        End Select
        If My.Application.CommandLineArgs.Count > 3 Then
            ReDim gstrReportParameters(My.Application.CommandLineArgs.Count - 4)
            For c = 0 To gstrReportParameters.GetUpperBound(0)
                gstrReportParameters(c) = My.Application.CommandLineArgs(c + 3)
            Next
        End If
    End Sub
    Sub Logon()
        Dim wSession As BusinessObjects.DSWS.Session.Session
        Try
            Dim boConnection As BusinessObjects.DSWS.Connection = New BusinessObjects.DSWS.Connection(WS_URL_SESSION)
            ' login to BusinessObjects Enterprise using web services
            Console.WriteLine("Logging into web service...")
            Dim credential As New EnterpriseCredential
            credential.Login = My.Settings.User_Name
            credential.Password = My.Settings.User_Password
            credential.Domain = My.Settings.Cluster_Name
            credential.AuthType = My.Settings.Authentication_Type
            wSession = New BusinessObjects.DSWS.Session.Session(boConnection)
            wSession.Login(credential)
            Console.WriteLine("Logged into web service.")
            boConnection.URL = WS_URL_BIPLATFORM
            bipService = New BIPlatform(boConnection, wSession.ConnectionState)
            boConnection.URL = WS_URL_REPORTENGINE
            boRepEng = New ReportEngine(boConnection, wSession.ConnectionState)
        Catch ex As DSWSException
            Console.Error.WriteLine(ex)
            Console.Error.WriteLine(ex.CauseDetail)
            Throw
        End Try
    End Sub
    Private Sub Schedule()
        Try
            Dim oGetOptions As New GetOptions
            oGetOptions.IncludeSecurity = False
            Dim crPath As String = "path://InfoObjects/Root Folder/SCH Reports/" + REPORT_STRING + "@SI_SCHEDULEINFO,SI_PROCESSINFO"
            Dim rh As ResponseHolder = bipService.Get(crPath, oGetOptions)
            Dim oInfoObjects As InfoObjects = rh.InfoObjects
            Dim oReport As CrystalReport = oInfoObjects.InfoObject(0)
            oReport.Name = REPORT_NAME
            Dim oSchedulingInfo As New SchedulingInfo
            oReport.SchedulingInfo = oSchedulingInfo
            oReport.SchedulingInfo.RightNow = True
            'to schedule a report to pdf format, use the following code
            Dim procInfo As ReportProcessingInfo = oReport.PluginProcessingInterface
            Dim repFormat As New CrystalReportFormatOptions
            repFormat.Format = REPORT_FORMAT
            repFormat.FormatSpecified = True
            procInfo.ReportFormatOptions = repFormat
            oReport.PluginProcessingInterface = procInfo
            'to schedule to unmanaged disk, use the code below
            Dim oDestination(1) As Destination
            oDestination(0) = New Destination
            oDestination(0).Name = "CrystalEnterprise.DiskUnmanaged"
            Dim diskOptions As New DiskUnmanagedScheduleOptions
            Dim destinationFile(1) As String
            destinationFile(0) = My.Settings.Export_Location + oReport.Name + FILE_EXTENSION
            diskOptions.DestinationFiles = destinationFile
            oDestination(0).DestinationScheduleOptions = diskOptions
            oSchedulingInfo.Destinations = oDestination
            'to schedule a report with discrete parameter information, use the following code snippet
            Dim repParams() As ReportParameter = procInfo.ReportParameters
            Dim oCurrentValues As New CurrentValues
            Dim oPromptValue(gstrReportParameters.GetUpperBound(0)) As BusinessObjects.DSWS.BIPlatform.Desktop.PromptValue
            Dim c As Integer
            For c = 0 To oPromptValue.GetUpperBound(0)
                oPromptValue(c) = New BusinessObjects.DSWS.BIPlatform.Desktop.PromptValue
                oPromptValue(c).Data = gstrReportParameters(c)
            Next
            oCurrentValues.CurrentValue = oPromptValue
            repParams(0).CurrentValues = oCurrentValues
            bipService.Schedule(oInfoObjects)
        Catch ex As DSWSException
            Console.Error.WriteLine(ex)
            Console.Error.WriteLine(ex.CauseDetail)
            Throw
        Finally
            If Not wSession Is Nothing Then
                wSession.Logout()
            End If
            Console.Write("Done")
        End Try
    End Sub
End Class