Req Help to Update LIKP-LIFSK,Delivery Header block through custom program.

Question

Hi everyone,
Can you please suggest a FM or BAPI to update the delivery header block field, LIFSK, in LIKP table through FM or a BAPI.
I tried using 'BAPI_OUTB_DELIVERY_CHANGE' as below to update the LIKP-LIFSK, but it is not working.
DATA : ls_likp TYPE likpvb,
       ls_dlv_header  TYPE bapiobdlvhdrchg,
       lt_dlv_items_control TYPE STANDARD TABLE OF bapiobdlvitemctrlchg,
       ls_dlv_item_control TYPE bapiobdlvitemctrlchg.
DATA : ls_dlv_hdr_control   TYPE bapiobdlvhdrctrlchg,
       ls_dlv_techn_control TYPE bapidlvcontrol,
       lt_bapireturn TYPE STANDARD TABLE OF bapiret2,
       ls_bapireturn TYPE bapiret2,
       lt_bapiext2 TYPE STANDARD TABLE OF bapiext,
       ls_bapiext2 TYPE bapiext.
DATA :  BEGIN OF ls_mns_of_del,
             vbeln TYPE likp-vbeln,     "delivery number
             lifsk TYPE likp-lifsk,     "means of transport
       END OF ls_mns_of_del.
CONSTANTS : lc_del_blck           TYPE bapiext-param VALUE 'LIKP-LIFSK'.
PARAMETERS : p_dlv TYPE likp-vbeln OBLIGATORY."  OBLIGATORY.
SELECT SINGLE *
  FROM likp
  INTO ls_likp
  WHERE vbeln = p_dlv.
CHECK sy-subrc = 0.
CLEAR : ls_bapiext2.
ls_mns_of_del-vbeln = ls_likp-vbeln.
ls_mns_of_del-lifsk = 'BX'.
ls_bapiext2-param = lc_del_blck .
ls_bapiext2-value = ls_mns_of_del.
APPEND ls_bapiext2 TO lt_bapiext2.
CALL FUNCTION 'MAP2E_LIKPVB_TO_BAPIOBDLVHDRCH'
  EXPORTING
    likpvb          = ls_likp
  CHANGING
    bapiobdlvhdrchg = ls_dlv_header.
CALL FUNCTION 'BAPI_OUTB_DELIVERY_CHANGE'
  EXPORTING
    header_data           = ls_dlv_header
    header_control        = ls_dlv_hdr_control
    delivery              = ls_likp-vbeln
    techn_control         = ls_dlv_techn_control
  TABLES
    extension2            = lt_bapiext2[]
    return                = lt_bapireturn[]
  EXCEPTIONS
    communication_failure = 1
    system_failure        = 2
    OTHERS                = 3.
IF lt_bapireturn[] IS INITIAL.
  COMMIT WORK AND WAIT.
  MESSAGE 'Success' TYPE 'I' DISPLAY LIKE 'S'.
  LEAVE LIST-PROCESSING.
ELSE.
  MESSAGE 'Error' TYPE 'I' DISPLAY LIKE 'E'.
  LEAVE LIST-PROCESSING.
ENDIF.

Answer 1

Hi ,
After seeing your code, you are not passing any parameters to header control data. once check the below code, it might useful.
DATA: h_data like bapiobdlvhdrchg,
         h_control like bapiobdlvhdrctrlchg,
        delivery like bapiobdlvhdrchg-deliv_numb,
        item_data like bapiobdlvitemchg occurs 0 with header line,
        item_control like bapiobdlvitemctrlchg occurs 0 with header line,
         return like bapiret2 occurs 0 with header line.
        CLEAR: h_data, h_control, delivery, item_data, item_control,
               return.
        REFRESH: item_data, item_control, return.
       h_data-deliv_numb = gst_alv_table-c6_vbeln.
       h_data-dlv_block  = p_new_del_blck.         "the new delivery block
       h_control-deliv_numb = gst_alv_table-c6_vbeln.
       h_control-dlv_block_flg = 'X'.
       delivery = gst_alv_table-c6_vbeln.
          CALL FUNCTION 'BAPI_OUTB_DELIVERY_CHANGE'
              EXPORTING
           header_data                   = h_data
         header_control                = h_control
          delivery                      = delivery
           TABLES
            return                        = return .
         "Check if return table got an error.
         READ TABLE return WITH KEY type = 'E'.
            IF NOT sy-subrc IS INITIAL.
           CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
               EXPORTING
              wait = 'X'.
             ELSE.
         ROLLBACK WORK.
                        ENDIF.
Regards,
Parupelly