Retrieve Data using SQL Data Reader

Question

Hello Team, I am working on a program where we have to read the data from sql database for specific barcode. Please have a look at the code below.
If SqlConnection.State = ConnectionState.Closed Then
SqlConnection.Open()
End If
Try
Dim SQLCommand As New SqlClient.SqlCommand("SELECT * FROM tblProducts WHERE Barcode= @Barcode", SqlConnection)
SQLCommand.Parameters.AddWithValue("@Barcode", txtPurchaseBarcode.Text)
frmNoBarcode.lblBarcode.Text = txtPurchaseBarcode.Text
Dim SQLReader As SqlClient.SqlDataReader
SQLReader = SQLCommand.ExecuteReader
If SQLReader.Read Then ' Barcode Exist
' Load Product Name
lblFetchProduct.Text = SQLReader.Item("ItemName").ToString
SQLReader.Close()
End If
Catch ex As Exception
End Try
If SqlConnection.State = ConnectionState.Open Then
SqlConnection.Close()
End If
So It display the records, I just want that, in some case, if the program is unable to search for the barcode,  then program should give me a message that the Item does not exist and Exit Sub the application. Can somebody help me up ?

Answer 1

Sir, can you please help me by giving me a code sample so I can understand in a better way, thanks
If you are referring to me, the way I would write the whole code: (just a suggestion...)
Private Function GetItemNameFromTblProductsByBarcode(ByVal Barcode As String) As String
If SqlConnection.State = ConnectionState.Closed Then
SqlConnection.Open()
End If
Try
Dim SQLCommand As New SqlClient.SqlCommand("SELECT ItemName FROM tblProducts WHERE Barcode= @Barcode", SqlConnection)
Dim Value As Object
SQLCommand.Parameters.AddWithValue("@Barcode", Barcode)
Value = SQLCommand.ExecuteScalar
Return If(Value Is Nothing, Nothing, Value.ToString)
Finally
SqlConnection.Close()
End Try
End Function
'' Call:
Dim Itemname As String
Itemname = GetItemNameFromTblProductsByBarcode(txtPurchaseBarcode.Text)
If Itemname Is Nothing Then
MessageBox.Show( _
"The item with the barcode " & txtPurchaseBarcode.Text & " does not exist.", "", _
MessageBoxButtons.OK, MessageBoxIcon.Information)
Else
lblFetchProduct.Text = Itemname
frmNoBarcode.lblBarcode.Text = Itemname
End If
I do not know whe meaning of lblFetchProduct and frmNoBarcode.lblBarcode, so I just set them both in case the barcode has been found.
Armin