Sample Code request

Question

Hi experts!!
I 'm new to ABAP objects and i would like you, if possible, to provide me with some "real"  code using objects.
All i find on the internet is small examples with airplanes, cars etc..
They are easy to understand as syntax but  not realistic enough to understand the business use of objects.
Thanx in advance!!!

Answer 1

alv invoice report
*& Report  ZLCL_ALV_INT_INVOICE                                        *
REPORT  ZLCL_ALV_INT_INVOICE                    .
DATA: O_CONT1 TYPE REF TO CL_GUI_CUSTOM_CONTAINER,
      O_CONT2 TYPE REF TO CL_GUI_CUSTOM_CONTAINER,
      O_GRID1 TYPE REF TO CL_GUI_ALV_GRID,
      O_GRID2 TYPE REF TO CL_GUI_ALV_GRID.
DATA: IT_VBRK LIKE VBRK OCCURS 1 WITH HEADER LINE.
DATA: IT_VBRP LIKE VBRP OCCURS 1 WITH HEADER LINE.
DATA: WA_VBRK LIKE VBRK.
*--Layout
DATA: WA_LAYO TYPE LVC_S_LAYO.
      CLASS LCL_BILLING DEFINITION
CLASS LCL_BILLING DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS: HANDLE_HOTSPOT_CLICK
             FOR EVENT HOTSPOT_CLICK
             OF CL_GUI_ALV_GRID
             IMPORTING E_ROW_ID.
ENDCLASS.                    "LCL_BILLING DEFINITION
      CLASS LCL_BILLING IMPLEMENTATION
CLASS LCL_BILLING IMPLEMENTATION.
  METHOD HANDLE_HOTSPOT_CLICK.
    IF NOT E_ROW_ID IS INITIAL.
*--Reading selected billing docno
      READ TABLE IT_VBRK INTO WA_VBRK INDEX E_ROW_ID-INDEX.
*--GETTING BILLING DOC ITEMS
      REFRESH IT_VBRP.
      SELECT *
        FROM VBRP
        INTO TABLE IT_VBRP
        WHERE VBELN = WA_VBRK-VBELN.
      CALL SCREEN 200.
    ENDIF.
  ENDMETHOD.                    "HANDLE_HOTSPOT_CLICK
ENDCLASS.                    "LCL_BILLING IMPLEMENTATION
SELECT-OPTIONS: S_VBELN FOR IT_VBRK-VBELN.
START-OF-SELECTION.
  PERFORM GET_DATA.
  SET SCREEN 100.
*&      Form  GET_DATA
      text
FORM GET_DATA .
*--billing header data
  SELECT *
    FROM VBRK
    INTO TABLE IT_VBRK
    WHERE VBELN IN S_VBELN.
  IF SY-SUBRC <> 0.
    MESSAGE I000(Z00) WITH 'No Data Found'.
  ENDIF.
  EXIT.
ENDFORM.                    " GET_DATA
*&      Module  STATUS_0100  OUTPUT
      text
MODULE STATUS_0100 OUTPUT.
  SET PF-STATUS 'MENU'.
ENDMODULE.                 " STATUS_0100  OUTPUT
*&      Module  USER_COMMAND_0100  INPUT
      text
MODULE USER_COMMAND_0100 INPUT.
  CASE SY-UCOMM.
    WHEN 'BACK'.
      PERFORM EXIT_PROGRAM.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT
*&      Module  PBO_100  OUTPUT
      text
MODULE PBO_100 OUTPUT.
  IF O_CONT1 IS INITIAL.
    CREATE OBJECT O_CONT1
      EXPORTING
        CONTAINER_NAME              = 'VBRK_CONT'
      EXCEPTIONS
        CNTL_ERROR                  = 1
        CNTL_SYSTEM_ERROR           = 2
        CREATE_ERROR                = 3
        LIFETIME_ERROR              = 4
        LIFETIME_DYNPRO_DYNPRO_LINK = 5
        OTHERS                      = 6
    IF SY-SUBRC <> 0.
      MESSAGE I000(Z00) WITH 'Error in container'.
      EXIT.
    ENDIF.
    CREATE OBJECT O_GRID1
      EXPORTING
         I_PARENT          = O_CONT1
      EXCEPTIONS
        ERROR_CNTL_CREATE = 1
        ERROR_CNTL_INIT   = 2
        ERROR_CNTL_LINK   = 3
        ERROR_DP_CREATE   = 4
        OTHERS            = 5
    IF SY-SUBRC <> 0.
      MESSAGE I000(Z00) WITH 'Error in Grid'.
      EXIT.
    ENDIF.
  ENDIF.
*--Layout for 1st grid
  WA_LAYO-KEYHOT = 'X'.
  WA_LAYO-GRID_TITLE = 'Billing Document Header Data'.
  CALL METHOD O_GRID1->SET_TABLE_FOR_FIRST_DISPLAY
    EXPORTING
      I_STRUCTURE_NAME              = 'VBRK'
      IS_LAYOUT                     = WA_LAYO
    CHANGING
      IT_OUTTAB                     = IT_VBRK[]
    EXCEPTIONS
      INVALID_PARAMETER_COMBINATION = 1
      PROGRAM_ERROR                 = 2
      TOO_MANY_LINES                = 3
      OTHERS                        = 4.
  IF SY-SUBRC <> 0.
    MESSAGE I000(Z00) WITH 'Error in showing grid'.
    EXIT.
  ENDIF.
*-Setting the focus on the grid
  CALL METHOD CL_GUI_CONTROL=>SET_FOCUS
    EXPORTING
      CONTROL           = O_GRID1 "Grid control object
    EXCEPTIONS
      CNTL_ERROR        = 1
      CNTL_SYSTEM_ERROR = 2
      OTHERS            = 3.
  IF SY-SUBRC <> 0.
    MESSAGE I000(Z00) WITH 'Error in setting focus'.
  ENDIF.
*--Event handler registration
  SET HANDLER LCL_BILLING=>HANDLE_HOTSPOT_CLICK FOR O_GRID1.
ENDMODULE.                 " PBO_100  OUTPUT
*&      Module  STATUS_0200  OUTPUT
      text
MODULE STATUS_0200 OUTPUT.
  SET PF-STATUS 'MENU'.
ENDMODULE.                 " STATUS_0200  OUTPUT
*&      Module  USER_COMMAND_0200  INPUT
      text
MODULE USER_COMMAND_0200 INPUT.
  CASE SY-UCOMM.
    WHEN 'BACK'.
      LEAVE TO SCREEN 100.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0200  INPUT
*&      Module  PBO_200  OUTPUT
      text
MODULE PBO_200 OUTPUT.
  IF O_CONT2 IS INITIAL.
    CREATE OBJECT O_CONT2
        EXPORTING
        CONTAINER_NAME              = 'VBRP_CONT'
    EXCEPTIONS
      CNTL_ERROR                  = 1
      CNTL_SYSTEM_ERROR           = 2
      CREATE_ERROR                = 3
      LIFETIME_ERROR              = 4
      LIFETIME_DYNPRO_DYNPRO_LINK = 5
      OTHERS                      = 6
    IF SY-SUBRC <> 0.
      MESSAGE I000(Z00) WITH 'Error in container'.
      EXIT.
    ENDIF.
    CREATE OBJECT O_GRID2
      EXPORTING
        I_PARENT          = O_CONT2
      EXCEPTIONS
        ERROR_CNTL_CREATE = 1
        ERROR_CNTL_INIT   = 2
        ERROR_CNTL_LINK   = 3
        ERROR_DP_CREATE   = 4
        OTHERS            = 5.
    IF SY-SUBRC <> 0.
      MESSAGE I000(Z00) WITH 'Error in grid linking'.
      EXIT.
    ENDIF.
    CALL METHOD O_GRID2->SET_TABLE_FOR_FIRST_DISPLAY
      EXPORTING
        I_STRUCTURE_NAME              = 'VBRP'
      CHANGING
        IT_OUTTAB                     = IT_VBRP[]
      EXCEPTIONS
        INVALID_PARAMETER_COMBINATION = 1
        PROGRAM_ERROR                 = 2
        TOO_MANY_LINES                = 3
        OTHERS                        = 4.
    IF SY-SUBRC <> 0.
      MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
                 WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
  ELSE.
*--refreshing the alv grid with the latest content of the internal table
*--which is linked
    CALL METHOD O_GRID2->REFRESH_TABLE_DISPLAY
      EXCEPTIONS
        FINISHED = 1
        OTHERS   = 2.
    IF SY-SUBRC <> 0.
      MESSAGE I000(Z00) WITH 'Error in Refreshing gird'.
    ENDIF.
  ENDIF.
ENDMODULE.                 " PBO_200  OUTPUT
*&      Form  EXIT_PROGRAM
      text
FORM EXIT_PROGRAM .
*--Deallocating the memory
  IF NOT O_CONT2 IS INITIAL.
    CALL METHOD O_CONT2->FREE
      EXCEPTIONS
        CNTL_ERROR        = 1
        CNTL_SYSTEM_ERROR = 2
        OTHERS            = 3.
    IF SY-SUBRC <> 0.
      MESSAGE I000(Z00) WITH 'Error in deallocating memory'.
      EXIT.
    ENDIF.
    CLEAR: IT_VBRP,
           IT_VBRP[].
    FREE:  IT_VBRP,
           IT_VBRP[].
  ENDIF.
  IF NOT O_CONT1 IS INITIAL.
    CALL METHOD O_CONT1->FREE
      EXCEPTIONS
        CNTL_ERROR        = 1
        CNTL_SYSTEM_ERROR = 2
        OTHERS            = 3.
    IF SY-SUBRC <> 0.
      MESSAGE I000(Z00) WITH 'Error in deallocating memory'.
      EXIT.
    ENDIF.
    CLEAR: IT_VBRK,
           IT_VBRK[].
    FREE:  IT_VBRK,
           IT_VBRK[].
  ENDIF.
*--Cearing the buffered content
  CALL METHOD CL_GUI_CFW=>FLUSH
    EXCEPTIONS
      CNTL_SYSTEM_ERROR = 1
      CNTL_ERROR        = 2
      OTHERS            = 3.
  IF SY-SUBRC <> 0.
    MESSAGE I000(Z00) WITH 'Error in clearing Buffer'.
    EXIT.
  ENDIF.
  LEAVE PROGRAM.
ENDFORM.                    " EXIT_PROGRAM
FOR SCREEN 100
PROCESS BEFORE OUTPUT.
  MODULE STATUS_0100.
  MODULE PBO_100.
PROCESS AFTER INPUT.
  MODULE USER_COMMAND_0100.
FOR SCREEN 200
PROCESS BEFORE OUTPUT.
  MODULE STATUS_0200.
  MODULE PBO_200.
PROCESS AFTER INPUT.
  MODULE USER_COMMAND_0200.