Save alv report as excel file directly from program

Question

Hello guys,
I require this in my work.
I want to save the ALV report tat is to be generated in the filepath that is given in the selection screen (want to save it locally eg: my windows desktop) and in the layout which is also given in the selection screen.
your comments will be very much appreciated.
Thanks in Advance,
Johny

Answer 1

Hi Johny,
Actually we have an option to download report output in ALV but it does not download the specified on Selection-screen. For this Create on button for Excell download by setting PF status. and use USER_COMMAND event to trigger when u click on the button and download data to specified path.
1.
declare events table like this.
data :
      i_events  type slis_t_event,
      w_events  like line of i_events.
2.
Build events table .
w_events-name = 'USER_COMMAND' .
w_events-form = 'USER_COMMAND' .
append w_events to i_events.
clear w_events.
w_events-name = 'PF_STATUS_SET' .
w_events-form = 'PF_STATUS_SET' .
append w_events to i_events.
clear w_events.
3.
pass this events table through REUSE_ALV_GRID_DISPLAY.
4.
USER_COMMAND and PF_STATUS_SET call back subroutines should be like this in your case. These are nowhere called using PERFORM statement in ur program.
5.
PF_STATUS_SET' subroutine should be like this.
*&      Form  pf_status_set
form pf_status_set    using extab type slis_t_extab.
set pf-status 'STATUS1' excluding g_extab.
"If you write like above Standard status will be gone.
"For that u have to copy standard status of any ALV program which has standard status.
"1. goto SE41 tcode. give program SAPLKKBL and status :STANDARD_FULLSCREEN .
2.Click on the Copy status button below program is ur program and status ur program status.
3. After that create your own button for Excel downlod.
endform.                    "pf_status_set
6.
USER_COMMAND subroutine should be like this.
*&      Form  user_command
form user_command using ucomm like sy-ucomm
                  selfield type slis_selfield.
  case ucomm .
    when 'XLS_DOWN'.
    perform download_to_xls.
  endcase.
endform.                    "user_command
Here is the sample program to download data into Excel file with header and Columns..
Check this program by running.
*& Report  ZVENKAT_DOWNLOAD_XLS_WITH_HEAD
REPORT  zvenkat_download_xls_with_head.
"  Data retrieval related declarations
TYPES:
     BEGIN OF t_emp_dat,
       pernr TYPE pa0001-pernr,
       persg TYPE pa0001-persg,
       persk TYPE pa0001-persk,
       plans TYPE pa0001-plans,
       stell TYPE pa0001-stell,
     END OF t_emp_dat,
     t_attachment TYPE  solisti1.
DATA:
     w_emp_data TYPE t_emp_dat,
     w_attachment     TYPE  t_attachment.
DATA:
     i_emp_data TYPE STANDARD TABLE OF t_emp_dat,
     i_attachment     TYPE STANDARD TABLE OF t_attachment.
PARAMETERS: p_file TYPE string DEFAULT 'c:\tmp\test.xls'.
"Start-of-selection.
START-OF-SELECTION.
  PERFORM get_data.
  PERFORM build_xls_data_and_download.
  "Form  get_data from PA0001
FORM get_data.
  SELECT pernr
         persg
         persk
         plans
         stell
   FROM pa0001
   INTO CORRESPONDING FIELDS OF TABLE i_emp_data
   UP TO 4 ROWS.
ENDFORM.                    " get_data
"Form  build_xls_data_and_download
FORM build_xls_data_and_download.
  "If you have Unicode check active in program attributes then
  "you will need to declare constants as follows.
  CLASS cl_abap_char_utilities DEFINITION LOAD.
  CONSTANTS:
      con_tab  TYPE c VALUE cl_abap_char_utilities=>horizontal_tab,
      con_cret TYPE c VALUE cl_abap_char_utilities=>cr_lf.
  DATA :l_lines TYPE char10.
  DESCRIBE TABLE i_emp_data LINES l_lines.
  CONCATENATE 'Total no of records:' l_lines
         INTO  w_attachment
SEPARATED BY  con_tab.
  CONCATENATE con_cret
              w_attachment
         INTO w_attachment.
  APPEND w_attachment TO i_attachment.
  CLEAR  w_attachment.
  CONCATENATE 'PERNR' 'PERSG' 'PERSK' 'PLANS' 'STELL'
         INTO  w_attachment
SEPARATED BY  con_tab.
  CONCATENATE con_cret
              w_attachment
         INTO w_attachment.
  APPEND w_attachment TO i_attachment.
  CLEAR  w_attachment.
  LOOP AT i_emp_data INTO w_emp_data.
    CONCATENATE w_emp_data-pernr
                w_emp_data-persg
                w_emp_data-persk
                w_emp_data-plans
                w_emp_data-stell
           INTO w_attachment
   SEPARATED BY con_tab.
    CONCATENATE con_cret w_attachment
           INTO w_attachment.
    APPEND w_attachment TO i_attachment.
    CLEAR  w_attachment.
  ENDLOOP.
  CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      filename              = p_file
      write_field_separator = con_tab
    TABLES
      data_tab              = i_attachment.
  IF sy-subrc  <>  0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM.                    "build_xls_data_and_download
I hope that it helps u .
Regards,
Venkat.O