Scheduling an Apple Script [eyeTV DVB Update] more...

Question

Like many other eyeTV Users, I have opted out of the iceTV [Australia] annual subscription, and am using the DVB Program Guide.
But eyeTV does not support scheduled updates of the DVB Guide, only subscription services [annoying].
Recently ctzsnooze proposed an Apple Script which if run periodically would update of the eyeTV DVB Program Guide.
https://discussions.apple.com/thread/6043805
And a few years ago Camelot proposed a means to schedule a script to run periodically.
https://discussions.apple.com/thread/673340
After a little testing, I believe I have refined this script to properly run to a regular schedule.
Here is a copy of my updated version of Camelot's test routine: Note the following...
a) the initial date must be set in the future, otherwise the idle loop will run every five seconds [idle return is negative].
b) use >=, not simply > in the idle loop, otherwise the scheduled run time becomes offset [+5 * minutes in this example].
c) I found the display notification a really neat way to log progress of the script while testing, and have now incorporated a Notification into my file Script for the eyeTV Program Schedule Update, to confirm it has run once a day, or hour.
d) Compile then Save As, Application, and Stay open after run handler.  The first time you run it, you will need to authorise it...
property runTime : missing value
on run
          set runTime to date "Wednesday, 07 May 2014 13:45:00"
          display notification "Update Script initialised at: " & runTime
          display notification "Time now is: " & (current date)
end run
on idle
          if (get current date) ≥ runTime then
                    display notification "Update Script ran at: " & (current date)
                    set runTime to runTime + 5 * minutes
                    display notification "Next execution of Update Script will be at: " & runTime
          end if
          display notification "Script Return Value is: " & (runTime - (get current date))
          return (runTime - (get current date))
end idle
Here is an example run...
And here is my update to Ctzsnooxe's version of the eyeTV DVB Program Guide auto update script, and a copy of the resulting Notifications...
Delete the display notifications you do not wish to see from the script, once you prove the script.
property runTime : missing value
on run
          set runTime to date "Wednesday, 07 May 2014 15:00:00"
          display notification "eyeTV Programs Update Script initialised at: " & runTime
  display notification "Time now is: " & (current date)
end run
on idle
          if (get current date) ≥ runTime then
    display notification "eyeTV Programs Updated at: " & runTime
    tell application "EyeTV"
        activate
    end tell
    tell application "System Events"
      tell process "EyeTV"
        keystroke "g" using command down
        delay 1
        click (pop up button 1 of window 1)
        delay 1
        click menu item "Update DVB Program Guide" of menu 1 of pop up button 1 of window "EyeTV Programs"
      end tell
    end tell
    set runTime to runTime + 1 * days
    display notification "Next Update of eyeTV Programs will be at: " & runTime
          end if
          display notification "Script Return Value is: " & (runTime - (get current date))
          return (runTime - (get current date))
end idle

Answer 1

Stephen,
I ran into some scheduling issues after Wake from Sleep, and after some fiddling around, made the following changes.
This version is set up to run every hour [so I could test error handling, window, wake, and sleep issues]
-- eyeTVAutoUpdate (Hour) Script:
-- [for testing, setup to run every hour...]
-- When proper operation is confirmed,
--       Set Systems Preferences, Energy Saver, Schedule, Startup or Wake, to
--       Every Day, at 15:45hr, and
--       Set eyeTV Programs Update Script to run at 16:00hr every day
property runTime : missing value
on run
   set runTime to (get current date)
   set (time of runTime) to 10 * hours
  repeat while runTime < (get current date)
     set runTime to runTime + 1 * hours
  end repeat
  display notification "eyeTVAutoUpdate Script initialised: " & return & (current date)
end run
on idle
   try
   tell application "EyeTV"
      activate
      close controller window
   end tell
   tell application "System Events"
      tell process "EyeTV"
         keystroke "g" using command down
         delay 1
         click (pop up button 1 of window 1)
         delay 1
         click menu item "Go to Now" of menu 1 of pop up button 1 of window "EyeTV Programs"
         delay 1
         click (pop up button 1 of window 1)
         delay 1
         click menu item "Update DVB Program Guide" of menu 1 of pop up button 1 of window "EyeTV Programs"
      end tell
   end tell
   display notification "eyeTV Programs Updated: " & return & (current date)
on error errorMessage number errorNumber
   display notification ("An error occurred: " & errorNumber as text) & return & "Description: " & errorMessage as text
end try
repeat while runTime < (get current date)
   set runTime to runTime + 1 * hours
end repeat
display notification "Next Update of eyeTV Programs: " & return & runTime
display notification "eyeTVAutoUpdate Script Return: " & (runTime - (get current date))
return (runTime - (get current date))
end idle
Although I have not yet tested it, simply change the last repeat while loop time interval [now one hour] to suit, say to 8 or 24 hours.
For example...
repeat while runTime < (get current date)
   set runTime to runTime + 8 * hours
end repeat
  repe