Script help.. find folders (title oversimplified..)

Question

What I need:
Have list of folder names in Excel
Script uses list to find specified folders. Folders (items in list) are actually three folders deep in directory (external archive disk/dated folder/folder I want).
Script then copies folders to another location.
Basically, I have a main archive directory (Archive1). On that disk are dated folders (102013). Inside the dated folders there are anywhere from 10-20 folders.. those contain the data (study data).. and those are the folders I want. I will have a list of 50-100 data folders provided to me.. all from random dates. I dont want to manually find, then drag and drop data into new archive. I have a list.. and would like to automate this.
What I have:
Script that will find FILES.. not folders... and not in subdirectories. It does everything i need.. if I was only looking for files in one folder.
Script I have is below. If one of you kind souls would point me in the right direction, id appreciate it.
If you want to test the script below:
Make a short list in excel.. maybe just a, b, c in a column.
Create two (named mine archive and transfer) folders on your desktop.. Place three dummy files named a, b, and c in the archive folder. Run the script wile the spreadsheet is open. You will be asked to choose the archive folder. Then the transfer folder. All files from archive folder will then be copied to transfer folder. The spreadsheet will be updated to include filenames with extension in the B colum.
Script:
set studiestofind to (choose folder with prompt "Choose Archive Location")
set transferto to (choose folder with prompt "Choose the Transfer Location")
tell application "Microsoft Excel"
          tell active sheet
                    set lastIndex to first row index of last cell of (get used range)
                    repeat with i from 2 to lastIndex
                              set tFileName to my find_filenames(get value of range ("A" & i), studiestofind)
                              if tFileName is not "" then -- Study Found
                                        set r to my duplicateImage(tFileName, studiestofind, transferto)
                                        if r is not "" then -- no error on duplicate file
                                                  set value of range ("B" & i) to tFileName
                                        else
                                                  set value of range ("B" & i) to ""
                                        end if
                              end if
                    end repeat
          end tell
end tell
on duplicateImage(tName, iFolder, mFolder)
          try
                    tell application "Finder" to return (duplicate file tName of iFolder to mFolder) as string
          on error
                    return ""
          end try
end duplicateImage
on find_filenames(tVal, thefolder)
  --if cell begins with space or ends with space , text items of tVal return empty string, empty string added in list excludedWords
          set excludedWords to {"Mini", "and", ""} -- words in Menu Item to exclude in search
          set otid to text item delimiters
          set text item delimiters to " "
          set tWords to text items of tVal
          set text item delimiters to otid
          set thefolder to quoted form of POSIX path of thefolder
          set myListOfWords to {}
          repeat with i in tWords -- must be valid
                    if contents of i is not in excludedWords then set end of myListOfWords to contents of i
          end repeat
          if (count myListOfWords) = 1 then -- more filler i dont really understand
                    set i to quoted form of (tVal & ".")
  -- search file name 
                    set tpath to do shell script "cd " & thefolder & " &&  /usr/bin/find . -type f -maxdepth 1 -iname " & i & "*"
                    if tpath is not "" then return text 3 thru -1 of tpath --return name of exact match
          end if
          repeat with i in myListOfWords
                    set tPaths to do shell script "cd " & thefolder & " &&  /usr/bin/find . -type f -maxdepth 1 -iregex '.*[_/]" & i & "[_.].*'  \\! -name '.*' "
                    if tPaths is not "" then
                              set L to paragraphs of tPaths
                              if (count L) = 1 then return text 3 thru -1 of tPaths -- one path found
                              repeat with tpath in L -- many paths found, loop each path
                                        set isGood to false
                                        repeat with tword in myListOfWords -- check each word of this Menu Item in tpath
                                                  if ("/" & tword & "_") is in tpath or ("/" & tword & ".") is in tpath or ("_" & tword & ".") is in tpath or ("_" & tword & "_") is in tpath then
                                                            set isGood to true
                                                  else
                                                            set isGood to false
                                                            exit repeat
                                                  end if
                                        end repeat
                                        if isGood then return text 3 thru -1 of tpath -- each word of this Menu Item is in name of tpath
                              end repeat
                    end if
          end repeat
          return ""
end find_filenames

Answer 1

Hello
It is not hard to modify the existing script you posted so as to retrieve directories at depth 2 but I chose to rewrite it as follows because its filtering logic is very inefficient. In the current form, the script below will retrieve directories at depth 2 in the chosen folder.
The part scripting Excel is not tested, for I don't have Excel. It might fail to set the value of cell in column B when there are multiple matches in which case the script will try to set cell value to multi-line text of every found path. If it fails, we can adjust the code to work aronud it. Your original script only processes the first matched file but I thought it's better to process every matched one.
# Notes
• Filtering logic is modified so that it is now wholly processed by find(1). Also the regexp pattern is modified so that it compares the query word with string delimited by _ and . in file name.
E.g., Given query = "apple orange bananna", the original script matches these -
    apple_orange_bananna.tex
    apple_bananna_orange.dvi
    _bananna__orange__apple.ps
    _bananna._apple._orange.pdf
    _orange.blueberry_bananna_apple....djvu
but not these -
    apple.orange.bananna.txt
    apple_.orange_.bananna.txt
    apple_orange_blueberry.html
    apple_orange_bananna
The new script will match all of them except for "apple_orange_blueberry.html".
• I added code to handle NFD-NFC issue of HFS+ name. HFS+ name is represented as Unicode in NFD (Normalization Form D), while name in Excel could be in NFC (Normalization Form C), in which case find(1) will not match the name whose NFD and NFC are different. This is not a issue if name is only in a-zA-Z0-9. But, e.g., any diacriticals will cause trouble if not with special treatment.
• Script will write log to file on desktop when a) some query gives no result or b) some of the matched files/folders are not copied because item with the same name already exists in the destination.
• Script will behave (mostly) the same as the original script when you set the find parameters properties in _main() as -
    -- find parameters
    property type : "f" -- d = directory, f = file
    property mindepth : 1
    property maxdepth : 1
• Currently the value in column B will be the (list of) found and copied path(s) and not the found path(s). If you need all of the found path(s) to be put in column B, switch the following statements in _main():
    set value of range ("B" & i) to my _join(return, qq) -- found and copied
    --set value of range ("B" & i) to my _join(return, pp) -- found
• Script is tested under OSX 10.5.8. (except for Excel scripting)
# Script
_main()
on _main()
    script o
        -- directories and logfile
        property srcdir : (choose folder with prompt "Choose Archive Location")'s POSIX path
        property dstdir : (choose folder with prompt "Choose the Transfer Location")'s POSIX path
        property logf : (path to desktop)'s POSIX path & "copy_log@" & (do shell script "date +'%F.txt'")
        -- find parameters
        property type : "d" -- d = directory, f = file
        property mindepth : 2
        property maxdepth : 2
        -- working lists
        property pp : {}
        property qq : {}
        property rr : {}
        -- find & copy nodes
        tell application "Microsoft Excel"
            tell active sheet
                set lastIndex to first row index of last cell of (get used range)
                repeat with i from 2 to lastIndex
                    set query to value of range ("A" & i)
                    set pp to my find_filenames(query, srcdir, type, mindepth, maxdepth)
                    if pp = {} then -- not found
                        tell current application to set ts to do shell script "date +'%F %T%z'"
                        set entry to "Did not found a name with query word(s): " & query
                        my log_to_file("%-26s%s\\n", {ts, entry}, logf)
                    else
                        set qq to {}
                        repeat with p in my pp
                            set p to p's contents
                            set q to my cp(srcdir & p, dstdir, {replacing:false})
                            if q ≠ "" then
                                set end of my qq to p -- found and copied
                            else
                                set end of my rr to srcdir & p -- found but not copied
                            end if
                        end repeat
                        set value of range ("B" & i) to my _join(return, qq) -- found and copied
                        --set value of range ("B" & i) to my _join(return, pp) -- found
                    end if
                end repeat
            end tell
        end tell
        -- log duplicates
        if rr ≠ {} then
            set ts to do shell script "date +'%F %T%z'"
            set entry to "Did not copy the following node(s) due to existing name in destination: " & dstdir
            my log_to_file("%-26s%s\\n", {ts, entry}, logf)
            repeat with r in my rr
                my log_to_file("%-28s%s\\n", {"", r's contents}, logf)
            end repeat
        end if
    end script
    tell o to run
end main
on log_to_file(fmt, lst, f)
        string fmt : printf format string
        list lst : list of strings
        string f : POSIX path of log file
    local args
    set args to ""
    repeat with a in {fmt} & lst
        set args to args & space & a's quoted form
    end repeat
    do shell script "printf " & args & " >> " & f's quoted form
end log_to_file
on cp(src, dstdir, {replacing:_replacing})
        string src : POSIX path of source file or directory
        string dstdir : POSIX path of destination directory
        boolean _replacing : true to replace existing destination, false otherwise
        return string : POSIX path of copied file or directory, or "" if not copied
    set rep to _replacing = true
    if src ends with "/" then set src to src's text 1 thru -2
    if dstdir ends with "/" then set dstdir to dstdir's text 1 thru -2
    set sh to "
rep=$1
src=\"$2\"
dstdir=\"$3\"
dst=\"${dstdir}/${src##*/}\"
[[ $rep == false && -e \"$dst\" ]] && exit
cp -f -pPR \"$src\" \"$dstdir\" && echo \"$dst\" || exit $?
    do shell script "/bin/bash -c " & sh's quoted form & " - " & rep & " " & src's quoted form & " " & dstdir's quoted form
end cp
on find_filenames(query, dir, type, mind, maxd)
        string query : space delimited words to search
        string dir : POSIX path of target root directory
        string type : node type to retrieve
                    f => file
                    d => directory
        integer mind : min depth of nodes in dir to retrieve
        integer maxd : max depth of nodes in dir to retrieve
        return list : list of POSIX path of found node(s)
    script o
        property exclude_list : {"Mini", "and", ""} -- list of words to be excluded from query
        property pp : _split(space, NFD(query))
        property qq : {}
        property rr : {}
        -- exclude words in exclude_list from query words
        repeat with p in my pp
            set p to p's contents
            if p is not in my exclude_list then set end of my qq to p
        end repeat
        -- build arguments for find(1)
        (* query words are compared with tokens delimited by _ or . in file name *)
        repeat with q in my qq
                e.g. Given qq = {"apple", "orange", "bananna"}, rr is list of -
                    -iregex '.*[/_.]apple([_.].*|$)'
                    -iregex '.*[/_.]orange([_.].*|$)'
                    -iregex '.*[/_.]bananna([_.].*|$)'
                ( Note: |'s must be balanced even in comment... )
            set q to quotemeta(q) -- quote non-alphanumeric characters to be recognised as literal in regexp
            set end of rr to "-iregex '.*[/_.]" & q & "([_.].*|$)'"
        end repeat
        set |-iregex| to " \\( " & _join(" -and ", my rr) & " \\)"
        set |-type| to " -type " & type
        set |-mindepth| to " -mindepth " & mind
        set |-maxdepth| to " -maxdepth " & maxd
        -- build shell script
        set sh to "export LC_ALL=en_GB.UTF-8
cd " & dir's quoted form & " || exit
/usr/bin/find  -E . " & |-type| & |-mindepth| & |-maxdepth| & |-iregex| & " \\! -name '.*' -print0 |
/usr/bin/perl -CS -ln0e 'print substr($_, 2);'
        -- run shell script
        return paragraphs of (do shell script sh)
    end script
    tell o to run
end find_filenames
on NFD(t)
        string t : source string
        return Unicode text : t in NFD (Normalization Form D)
    set pl to "/usr/bin/perl -CSDA -MUnicode::Normalize <<-'EOF' - \"$*\"
print $ARGV[0] ? NFD($ARGV[0]) : qq();
EOF"
    do shell script "/bin/bash -c " & pl's quoted form & " - " & t's quoted form
end NFD
on quotemeta(t)
        string t : source string
        return string : t where all non-alphanumeric characters are quoted by backslash
    set pl to "/usr/bin/perl -CSDA -e 'print quotemeta $ARGV[0];' \"$*\""
    do shell script "/bin/bash -c " & pl's quoted form & " - " & t's quoted form
end quotemeta
on _join(d, tt)
        string d : separator
        list tt : source list
        return string : tt joined with d
    local astid, astid0, t
    set astid to a reference to AppleScript's text item delimiters
    try
        set {astid0, astid's contents} to {astid's contents, {} & d}
        set t to "" & tt
        set astid's contents to astid0
    on error errs number errn
        set astid's contents to astid0
        error errs number errn
    end try
    return t
end _join
on _split(d, t)
        string or list d : separator(s)
        string t : source string
        return list : t splitted by d
    local astid, astid0, tt
    set astid to a reference to AppleScript's text item delimiters
    try
        set {astid0, astid's contents} to {astid's contents, {} & d}
        set tt to t's text items
        set astid's contents to astid0
    on error errs number errn
        set astid's contents to astid0
        error errs number errn
    end try
    return tt
end _split
Hope this may help
H
Message was edited by: Hiroto (fixed some typos)