Script to create a password pretected DMG with no prompts

Question

I've tried quite a few third part DMG tools (Drop DMG, DMG Master, iDMG etc) in the search for an app which can fully automate the creation of a secure DMG file.
In an ideal setup, I would simply drop a folder onto the scripts icon and it would then, completely automatically:
+1 - Set the DMG format to compressed.+
+2 - Set security to 256 Bit AES.+
+3 - Enter a password already stored in the script (no prompt).+
+4 - Save it using the original folders name for the DMG name.+
+5 - Save to the same location the folder came from.+
I'm sure many would say having the password stored in an AppleScript is not very secure, but for this particular workflow its not a problem (assuming I can even do that?)
Has anyone been able to create such an automatic DMG script - is it even possible to do all those steps with a script or could suggest another 3rd party tool I've missed?
Many thanks.

Answer 1

Although most people don't like [GUI Scripting|http://www.macosxautomation.com/applescript/uiscripting/index.html] very much, maybe you might want to try the following script, which, on my computer, seems to do exactly what you were asking for (most of the time in fact, with a few very strange exceptions).
on open theFolders
set thePassword to "Mark.Burton" -- you should change the password of course
tell application "Disk Utility" to activate
repeat with theCurrentFolder in theFolders
tell application "Finder"
set theName to displayed name of theCurrentFolder
set theContainer to container of theCurrentFolder
move theCurrentFolder to desktop -- temporarily
end tell
tell application "System Events"
tell process "Disk Utility"
keystroke "n" using {shift down, command down}
repeat until window 1 exists
end repeat
keystroke "d" using {command down} -- desktop
tell window 1
click radio button 2 of radio group 1 of group 1
select (row 1 of outline 1 of scroll area 2 of splitter group 1 of group 1 whose value of static text 1 of group 1 is theName)
click button "Image"
tell group 1
click pop up button 1
click menu item -1 of menu 1 of pop up button 1 -- AES 256
click pop up button 2
click menu item 2 of menu 1 of pop up button 2 -- compressed
end tell
end tell
keystroke return
end tell
tell process "SecurityAgent"
repeat until window 1 exists
end repeat
keystroke thePassword & tab & thePassword
click checkbox 1 of window 1
keystroke return
end tell
tell process "Disk Utility"
delay 1
repeat while window 2 exists
-- wait until the end of the creation process
end repeat
end tell
end tell
set theDiskImage to alias ((path to desktop as string) & theName & ".dmg")
tell application "Finder" to move {theCurrentFolder, theDiskImage} to theContainer
end repeat
tell application "Disk Utility" to quit
end open