Search for a string in word document using VBA

Question

Hi,
I am new to VBA. My requirement is that VBA code should find the path in the word document., some of the paths are present in the word document.
search criteria should start with \\\\ and end with .doc. Could anyone please help me out on how to provide the search criteria and is there any predefined methods present.
Thanks in advance.
Thanks,.

Answer 1

Apologies, the line
Do While .Execute(FindText:=.Text = "\\\\*.doc", MatchWildCards:=True)
should read
Do While .Execute(FindText:="\\\\*.doc", MatchWildCards:=True)
It will however only work for the document body. If the string is in a different story range you will have to loop through those story ranges e.g.
Sub FindIt()
Dim wdApp As Object
Dim wdDoc As Object
Dim oRng As Object
Dim bStarted As Boolean
Dim i As Integer
    On Error Resume Next
    Set wdApp = GetObject(, "Word.Application")
    If Err Then
        Set wdApp = CreateObject("Word.Application")
        bStarted = True
    End If
    On Error GoTo 0
    ActiveWorkbook.Save
    Set wdDoc = wdApp.Documents.Open("C:\Path\DocumentName.docx")
    i = 1
    For Each oRng In wdDoc.StoryRanges
        With oRng.Find
            .MatchWildcards = True
            Do While .Execute(FindText:="\\\\*.doc")
                Range("A" & i) = oRng.Text
                oRng.Collapse 0
                i = i + 1
            Loop
        End With
        If oRng.StoryType <> wdMainTextStory Then
            While Not (oRng.NextStoryRange Is Nothing)
                Set oRng = oRng.NextStoryRange
                With oRng.Find
                    .MatchWildcards = True
                    Do While .Execute(FindText:="\\\\*.doc")
                        Range("A" & i) = oRng.Text
                        oRng.Collapse 0
                        i = i + 1
                    Loop
                End With
            Wend
        End If
    Next oRng
    wdDoc.Close 0
    If bStarted Then wdApp.Quit
    Set oRng = Nothing
    Set wdDoc = Nothing
    Set wdApp = Nothing
End Sub
Graham Mayor - Word MVP
www.gmayor.com