Search help on select optionbased on other select ooption entered

Question

hi,
I need to know search help for selection screen based on value entered in another select options
SELECT-OPTIONS : s_bukrs FOR bkpf-bukrs OBLIGATORY,
                 s_belnr FOR bkpf-belnr,
                 s_gjahr FOR bkpf-gjahr OBLIGATORY,
                 s_budat FOR bkpf-budat OBLIGATORY,
                 s_akont FOR lfb1-akont,
                 s_saknr FOR bseg-saknr.    """"""""""
*PARAMETERS : p_akont type lfb1-akont.
here i need to get the vaues of s_akont based on values entered in s_bukrs,
In event at selection screeen for s_akont i am writing
    SELECT a~bukrs
          a~saknr
          a~mitkz
          b~txt50
                 FROM skb1 AS a
                 INNER JOIN skat AS b
                 ON asaknr = bsaknr
                  INTO CORRESPONDING FIELDS OF TABLE lt_skb1
                  WHERE bukrs IN s_bukrs
                    AND mitkz = 'K'
                    AND b~spras = 'EN'.
but not getting value of s_bukrs at this point of execution. I requir the fiels in select statement in F4 of s_akont.
what are the function modules to call and what is the way to do??
thanks..

Answer 1

Check the below solution for your issue - The FM "'RS_SELECTIONSCREEN_READ" is used to get the S_BUKRS values. Even though the FM returns single values of the Select options ( Low & High ) it fits the requirement.As the trick part is...If user enters multiple values or even enters sign for select options, S_BUKRS itself will have the value. That's why we have If else S_BUKRS[] is initial and R_BUKRS. Let me know if you have any issues with the solution provided.
TABLES: bkpf, lfb1.
DATA lt_fieldvalues TYPE STANDARD TABLE OF rsselread.
DATA ls_fieldvalue TYPE rsselread.
DATA r_bukrs TYPE RANGE OF bkpf-bukrs.
DATA ls_bukrs LIKE LINE OF r_bukrs.
SELECT-OPTIONS: s_bukrs FOR bkpf-bukrs,
                s_akont FOR lfb1-akont.
INITIALIZATION.
  ls_fieldvalue-name = 'S_BUKRS'.
  ls_fieldvalue-kind = 'S'.
  ls_fieldvalue-position = 'LOW'.
  APPEND ls_fieldvalue TO lt_fieldvalues.
  ls_fieldvalue-name = 'S_BUKRS'.
  ls_fieldvalue-kind = 'S'.
  ls_fieldvalue-position = 'HIGH'.
  APPEND ls_fieldvalue TO lt_fieldvalues.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR s_akont-low.
  refresh r_bukrs.
  clear ls_bukrs.
  IF s_bukrs[] IS INITIAL.
    CALL FUNCTION 'RS_SELECTIONSCREEN_READ'
      EXPORTING
        program     = sy-repid
        dynnr       = '1000'
      TABLES
        fieldvalues = lt_fieldvalues.
    IF NOT lt_fieldvalues[] IS INITIAL.
      ls_bukrs-sign = 'I'.
      READ TABLE lt_fieldvalues INTO ls_fieldvalue WITH KEY position = 'LOW'.
      IF sy-subrc EQ 0.
        ls_bukrs-low  = ls_fieldvalue-fieldvalue.
      ENDIF.
      READ TABLE lt_fieldvalues INTO ls_fieldvalue WITH KEY position = 'HIGH'.
      IF sy-subrc EQ 0.
        ls_bukrs-high = ls_fieldvalue-fieldvalue.
      ENDIF.
      IF ls_bukrs-high IS NOT INITIAL.
        ls_bukrs-option = 'BT'.
      ELSE.
        ls_bukrs-option = 'EQ'.
      ENDIF.
      if ls_bukrs-low is not initial or ls_bukrs-high is not initial.
        APPEND ls_bukrs TO r_bukrs.
      endif.
    ENDIF.
  ELSE.
    r_bukrs[] = s_bukrs[].
  ENDIF.
  SELECT a~bukrs a~saknr a~mitkz b~txt50 FROM skb1 AS a
         INNER JOIN skat AS b
         ON a~saknr = b~saknr
         INTO CORRESPONDING FIELDS OF TABLE lt_skb1
         WHERE bukrs IN r_bukrs         " Changed to r_burks
         AND mitkz = 'K'
         AND b~spras = 'EN'.