Selecting from bseg misses dupicalte entry

Question

Hi,
i select entries from bkpf/bseg as below:
  select bukrs belnr gjahr budat bldat waers
         into table lt_bkpf
         from bkpf
         where bukrs in s_bukrs
         and   blart in s_blart
         and   bldat in s_bldat
         and   budat in s_budat
  select bukrs belnr hkont wrbtr dmbtr shkzg vbund
         from bseg
         into table lt_bseg
         for all entries in lt_bkpf
         where bukrs =   lt_bkpf-bukrs
         and   belnr =   lt_bkpf-belnr
         and   gjahr =   lt_bkpf-gjahr
         and   hkont in  s_hkont.
this works fine except for a few docs which all have the same 'issue' where there is a duplicate WRBTR value in bseg. e.g.
BUKRS|BELNR|BUZEI|WRBTR|HKONT
1000|12345678|001|1000.00|7777
1000|12345678|002|1355.00|7777
1000|12345678|003|1000.00|7777
1000|12345678|004|9879.00|7777
my select statements output :
1000|12345678|001|1000.00|7777
1000|12345678|002|1355.00|7777
1000|12345678|004|9879.00|7777
Notice that item 3 is not found.
Note 416076 looks kind of related but we are on 470 and that is only for 4.6X.
Any ideas, as I am stumped?
thanks.

Answer 1

This is a trap when using the FOR ALL ENTRIES option on a select.  It is mentioned in the documentation of the command.  It is not related to indexes of the table.
FOR ALL ENTRIES has the same result as a SELECT DISTINCT -- duplicates are removed from the result set.
to get all entries that exist, make sure you specify ALL fields of the table primary key in the list of fields you retrieve.
so add the missing two fields to your internal table and modify your BSEG select to the following.
  select bukrs belnr GJAHR BUZEI hkont wrbtr dmbtr shkzg vbund
         from bseg
         into table lt_bseg
         for all entries in lt_bkpf
         where bukrs =   lt_bkpf-bukrs
         and   belnr =   lt_bkpf-belnr
         and   gjahr =   lt_bkpf-gjahr
         and   hkont in  s_hkont.
This will get all BSEG entries.
To prove this in DEV/Unit Test environment with less data available, try the following:
  select bukrs shkzg
         from bseg
         into table lt_bseg
         for all entries in lt_bkpf
         where bukrs =   lt_bkpf-bukrs
         and   belnr =   lt_bkpf-belnr
         and   gjahr =   lt_bkpf-gjahr
         and   hkont in  s_hkont.
Andrew