Server threw an exception while updating BP-Addresses

Question

Hi experts,
I am trying to add (or update if already exist) addresses on a Business Partner. I am always getting an error that "The server threw an exception. (Exception from HRESULT: 0x80010105 (RPC_E_SERVERFAULT))".
I  have even tried to use different objects for finding, add or update, but still no luck..
Can anyone advise me, please? my code looks like that:
        Dim oBP As SAPbobsCOM.BusinessPartners
        oBP = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.oBusinessPartners)
        oBP.GetByKey(CardCode)
        Dim flag As Integer = -1
        For i As Integer = 0 To oBP.Addresses.Count - 1
            oBP.Addresses.SetCurrentLine(i)
            If (oBP.Addresses.AddressName = Address_1) Then 
                flag = i
                Exit For
            End If
        Next
        System.Runtime.InteropServices.Marshal.ReleaseComObject(oBP)
        oBP = Nothing
        GC.Collect()
        If flag = -1 Then
            Dim oBP1 As SAPbobsCOM.BusinessPartners
            oBP1 = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.oBusinessPartners)
            oBP1.GetByKey(CardCode)
            Dim iL As Integer = 0
            iL = oBP1.Addresses.Count
            oBP1.Addresses.Add()
            oBP1.Addresses.SetCurrentLine(iL)
            oBP1.Addresses.AddressName = Address_1
            oBP1.Addresses.Street = Address_2
            oBP1.Addresses.City = City
            oBP1.Addresses.ZipCode = Zip
            oBP1.Addresses.AddressType = SAPbobsCOM.BoAddressType.bo_BillTo
            Try
                lRetCode = oBP1.Update()
                System.Runtime.InteropServices.Marshal.ReleaseComObject(oBP1)
                oBP1 = Nothing
                GC.Collect()
            Catch ex As Exception
                MsgBox(lErrCode & " " & ex.Message)
            End Try
        Else
            Dim oBP2 As SAPbobsCOM.BusinessPartners
            oBP2 = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.oBusinessPartners)
            oBP2.GetByKey(CardCode)
            oBP2.Addresses.SetCurrentLine(flag)
            oBP2.Addresses.Street = Address_2
            Try
                lRetCode = oBP2.Update()
                System.Runtime.InteropServices.Marshal.ReleaseComObject(oBP2)
                oBP2 = Nothing
                GC.Collect()
            Catch ex As Exception
                MsgBox(lErrCode & " " & ex.Message)
            End Try
        End If
Thank you in advance,
Aris

Answer 1

Hi Aris,
There are a few things wrong with the logic but I don't think any of them would directly cause your error message
1) You ought to use the GetByKey method in an If statement as the method returns true or false depending on whether the BP exists. I'm assuming that for your testing the CardCode variable does return a valid BP.
2) In the For/Next loop you need to check that the selected address has the correct AddressName and AddressType for the address you are searching for. In SBO it is possible to have a billing and shipping address on the same BP that have the same address name.
3) I don't understand why you need to use 3 BusinessPartner objects. You could do all the processing using a single BP and simplify your code. I appreciate that your code sample may be designed that way for reasons that aren't apparent in the context of this issue.
This works for me:
Dim oBP As SAPbobsCOM.BusinessPartners = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.oBusinessPartners)
Try
     If oBP.GetByKey(CardCode) then
          Dim found As Boolean = false
          Dim iL As Integer = oBP.Addresses.Count
             For i As Integer = 0 To oBP.Addresses.Count - 1
                 oBP.Addresses.SetCurrentLine(i)
                 If oBP.Addresses.AddressName = Address_1 and oBP.Addresses.AddressType = SAPbobsCOM.BoAddressType.bo_BillTo Then
                     oBP.Addresses.Street = Address_2
               found = true
                     Exit For
                 End If
             Next
          If not found then
               oBP.Addresses.Add()
                      oBP.Addresses.SetCurrentLine(iL)
                      oBP.Addresses.AddressName = Address_1
                      oBP.Addresses.Street = Address_2
                      oBP.Addresses.City = City
                      oBP.Addresses.ZipCode = Zip
                      oBP.Addresses.AddressType = SAPbobsCOM.BoAddressType.bo_BillTo     
          End if
          If oBP.Update() <> 0 then
               oApp.MessageBox(oCompany.GetLastErrorDescription, 1, "OK", "", "")
          End if
     End if
Catch ex as Exception
     oApp.MessageBox(ex.Message, 1, "OK", "", "")
Finally
     System.Runtime.InteropServices.Marshal.ReleaseComObject(oBP)
     oBP = Nothing
     GC.Collect()
End Try
If that doesn't help then please let us know what version and patch level you are on and exactly where the error occurs.
Kind Regards,
Owen