Shifting DB Objects into new table space

Question

Hi Guys,
We did not create any tablespace and all the users and their objects that we have created so far are in system tablespace...
Now we have created a tablespace. How can we shift our objects, users and their tables, view, packages, triigers in new tablespace.
Please explain with example if possible. And how to delete the objects from system tablespace. Please explain in details.
Looking forward for your kind help.
Imran Baig

Answer 1

What about the packages, procedures and functions.Those objects, as views does not own a Data Segment, their definition is stored in system catalog. There's nothing you need to do, that's 100% OK.
is this commans necessary to run after all the tables are in new tablespace?
alter index xyz rebuild onlineYes. In fact, when moving a table, rebuilding its indexes must be done. As for me, it's best to rebuild the indexes just after the table is moved. You can create a package or procedure to do this.
Oh, bah, I can give you some code sample. It's a package I created some time ago that can generate object movement code depending on their size to move them to appropriately sized tablespaces (extent size, etc):create or replace PACKAGE MGTSPACE
IS
  -- Record qui permet de définir les bornes hautes/basse par tablespace.
  TYPE tMinMax IS RECORD
    minsize NUMBER(38),
    maxsize NUMBER(38)
  -- Tableau stockant les valeurs par indexation par nom de tablespace
  TYPE tTS_MinMax IS TABLE
    OF tMinMax
    INDEX BY VARCHAR2(30);
  -- Variable qui va stocker les diférentes valeurs de bornage
  vTS_MinMax tTS_MinMax;
  -- Type qui va stocker la liste des tablespaces à gérer
  TYPE tListeChaine IS TABLE
    OF VARCHAR2(30)
    INDEX BY BINARY_INTEGER;
  -- Variable qui stocke la liste des tablespaces à gérer 
  vListeTablespace tListeChaine;
  -- Procédure d'initialisation
  PROCEDURE INIT;
  -- Procédure de recherche des tables dans un tablespace spécifique
  PROCEDURE TS_SCAN(pTSname IN VARCHAR2);
  -- Procédure de recherche des tables dans l'ensemble des tablespaces configurés
  PROCEDURE TS_SCAN_ALL;
END;
create or replace PACKAGE BODY MGTSPACE
IS
  -- Procédure d'initialisation
  PROCEDURE INIT
  IS
  BEGIN
    vTS_MinMax('DATBIG').minsize := 1536;
    vTS_MinMax('DATBIG').maxsize := 1000000;
    vTS_MinMax('DAT').minsize    := 20;
    vTS_MinMax('DAT').maxsize    := 1536;
    vTS_MinMax('DATLOW').minsize := 0;
    vTS_MinMax('DATLOW').maxsize := 20;
    vTS_MinMax('IDXBIG').minsize := 1000000;
    vTS_MinMax('IDXBIG').maxsize := 512;
    vTS_MinMax('IDX').minsize    := 100;
    vTS_MinMax('IDX').maxsize    := 512;
    vTS_MinMax('IDXLOW').minsize := 0;
    vTS_MinMax('IDXLOW').maxsize := 100;
    vListeTablespace(1):='DATBIG';
    vListeTablespace(2):='DAT';
    vListeTablespace(3):='IDXBIG';
    vListeTablespace(4):='IDX';
    vListeTablespace(5):='IDXLOW';
    vListeTablespace(6):='DATLOW';
  END;
  -- Déplace une partition d'index
  PROCEDURE MOVE_INDEX_PARTITION(pOwner IN VARCHAR2, pName IN VARCHAR2, pDestination IN VARCHAR2, pPartName IN VARCHAR2)
  IS
  BEGIN
    DBMS_OUTPUT.PUT_LINE('ALTER INDEX ' || pOwner || '.' || pName || ' REBUILD PARTITION ' || pPartName || ' TABLESPACE ' || pDestination || ' ONLINE COMPUTE STATISTICS;');
  END;
  -- Procédure de déplacement d'un index
  PROCEDURE MOVE_INDEX(pOwner IN VARCHAR2, pName IN VARCHAR2, pDestination IN VARCHAR2 := NULL)
  IS
  BEGIN
    IF (pDestination IS NOT NULL) THEN
      DBMS_OUTPUT.PUT_LINE('ALTER INDEX ' || pOwner ||'.' || pName || ' REBUILD TABLESPACE ' || pDestination || ' NOLOGGING ONLINE STORAGE (INITIAL 128k) COMPUTE STATISTICS;');
    ELSE
      DBMS_OUTPUT.PUT_LINE('ALTER INDEX ' || pOwner ||'.' || pName || ' REBUILD NOLOGGING ONLINE COMPUTE STATISTICS;');
    END IF;
  END;
  -- Procédure de déplacement d'une table
  PROCEDURE MOVE_TABLE(pOwner IN VARCHAR2,pName IN VARCHAR2, pDestination IN VARCHAR2)
  IS
  BEGIN
    -- Génération du code de déplacement
    DBMS_OUTPUT.PUT_LINE('ALTER TABLE ' || pOwner || '.' || pName || ' MOVE TABLESPACE ' || pDestination || ' STORAGE(INITIAL 128k);');
    -- Reconstruction des indexes associés
    FOR vListeIndexes IN (SELECT OWNER, INDEX_NAME FROM DBA_INDEXES WHERE TABLE_NAME=pName AND OWNER=pOwner)
    LOOP
      MOVE_INDEX(vListeIndexes.OWNER, vListeIndexes.INDEX_NAME);
    END LOOP;
  END;
  -- Procédure qui propose le déplacement d'un objet
  PROCEDURE MOVE_OBJECT(pType IN VARCHAR2,pOwner IN VARCHAR2,pName IN VARCHAR2, pPartName IN VARCHAR2,pDestination IN VARCHAR2,pSize IN NUMBER)
  IS
  BEGIN
    DBMS_OUTPUT.PUT_LINE('--');
    DBMS_OUTPUT.PUT_LINE('-- Doit déplacer l''objet ' || pType || ' ' || pOwner || '.' || NVL(pPartname,pName) || (CASE WHEN pPartName IS NOT NULL THEN ' partition de ' || pName ELSE NULL END) || ' vers ' || pDestination || '. Taille: ' || pSize || 'MiB');
    IF (pType = 'TABLE') THEN
      MOVE_TABLE(pOwner, pName, pDestination);
    ELSIF (pType = 'INDEX') THEN
      MOVE_INDEX(pOwner, pName, pDestination);
    ELSIF (pType = 'INDEX PARTITION') THEN
      MOVE_INDEX_PARTITION(pOwner, pName, pDestination, pPartName);
    ELSE
      DBMS_OUTPUT.PUT_LINE('Type d''objet non géré. ' || pOwner || '.' || pName || ' est de type: ' || pType||'/'||pPartName);
    END IF;
    DBMS_OUTPUT.PUT_LINE('--');
    DBMS_OUTPUT.PUT_LINE('--');
  END;
  -- Procédure de recherche des tables dans un tablespace spécifique
  PROCEDURE TS_SCAN(pTSname IN VARCHAR2)
  IS
    CURSOR cObjList IS
      SELECT OWNER, SEGMENT_NAME, PARTITION_NAME, BYTES/1024/1024 ACT_SIZE, SEGMENT_TYPE
      FROM DBA_SEGMENTS
      WHERE TABLESPACE_NAME=pTSname
      AND   (BYTES/1024/1024 <  vTS_MinMax(pTSname).minsize OR BYTES/1024/1024 >= vTS_MinMax(pTSname).maxsize);
  BEGIN
    -- On traite le tablespace passé en paramètre
    DBMS_OUTPUT.PUT_LINE('------------------------------------------------------------');
    DBMS_OUTPUT.PUT_LINE('-- Traitement du tablespace ' || pTSname || '('||vTS_MinMax(pTSname).minsize||'/'||vTS_MinMax(pTSname).maxsize||')');
    DBMS_OUTPUT.PUT_LINE('------------------------------------------------------------');
    -- Et on recherche tous les objets concernés
    FOR vObjList IN cObjList
    LOOP
      -- Cet objet est mal placé, on cherche ou il doit être relocalisé
      FOR vTSidx IN vListeTablespace.FIRST .. vListeTablespace.LAST
      LOOP
        -- On vérifie l'existence de l'entrée: précaution :)
        IF vListeTablespace.EXISTS(vTSidx) THEN
          -- Si c'est la même catégorie
          IF ((SUBSTR(vListeTablespace(vTSidx),1,3) = SUBSTR(pTSname,1,3)) AND (vObjList.ACT_SIZE BETWEEN vTS_MinMax(vListeTablespace(vTSidx)).minsize AND vTS_MinMax(vListeTablespace(vTSidx)).maxsize))THEN
            MOVE_OBJECT(vObjList.SEGMENT_TYPE,vObjList.OWNER,vObjList.SEGMENT_NAME,vObjList.PARTITION_NAME,vListeTablespace(vTSidx),vObjList.ACT_SIZE);
          END IF;
        END IF;
      END LOOP;
    END LOOP;
    DBMS_OUTPUT.PUT_LINE('');
    DBMS_OUTPUT.PUT_LINE('------------------------------------------------------------');
  END;
  -- Procédure de recherche des tables dans l'ensemble des tablespaces configurés
  PROCEDURE TS_SCAN_ALL
  IS
  BEGIN
    FOR vTSidx IN vListeTablespace.FIRST .. vListeTablespace.LAST
    LOOP
      IF vListeTablespace.EXISTS(vTSidx) THEN
        TS_SCAN(vListeTablespace(vTSidx));
      END IF;
    END LOOP;
  END;
END;Comments are in French, but you can guess :-)
You'll have to modify PROCEDURE INIT in order to set up YOUR tablespace names. For example, you'll have to add an entry in the table for the SYSTEM tablespace!
This is called using:SET SERVEROUTPUT ON SIZE 200000
BEGIN
     MGTSPACE.INIT;
     MGTSPACE.TS_SCAN_ALL;
END;
/Modify it to suit your needs, but you shouldn't have much work to do. For example, PROCEDURE INIT, for you, will be like:PROCEDURE INIT
  IS
  BEGIN
    vTS_MinMax('DAT').minsize := 0;
    vTS_MinMax('DAT').maxsize := 10000000;
    vTS_MinMax('IDX').minsize := 0;
    vTS_MinMax('IDX').maxsize := 10000000;
    vTS_MinMax('SYSTEM').minsize := 0;
    vTS_MinMax('SYSTEM').maxsize := 0;
    vListeTablespace(1):='SYSTEM';
    vListeTablespace(2):='DAT';
    vListeTablespace(3):='IDX';
  END;Note : This will generate the code, not run it.
Note2: This code assumes that tables tablespace names start with DAT and that index tablespace names start with IDX.
Note3: I know separating tables and indexes is useless, just some personnal organisation choice :-)
Note4: To avoid that (and you have to, because SYSTEM does not match) , change the code:IF ((SUBSTR(vListeTablespace(vTSidx),1,3) = SUBSTR(pTSname,1,3)) AND (vObjList.ACT_SIZE BETWEEN vTS_MinMax(vListeTablespace(vTSidx)).minsize AND vTS_MinMax(vListeTablespace(vTSidx)).maxsize))THEN
     MOVE_OBJECT(vObjList.SEGMENT_TYPE,vObjList.OWNER,vObjList.SEGMENT_NAME,vObjList.PARTITION_NAME,vListeTablespace(vTSidx),vObjList.ACT_SIZE);
END IF;
to
IF ((vObjList.ACT_SIZE BETWEEN vTS_MinMax(vListeTablespace(vTSidx)).minsize AND vTS_MinMax(vListeTablespace(vTSidx)).maxsize))THEN
     MOVE_OBJECT(vObjList.SEGMENT_TYPE,vObjList.OWNER,vObjList.SEGMENT_NAME,vObjList.PARTITION_NAME,vListeTablespace(vTSidx),vObjList.ACT_SIZE);
END IF; in procedure TS_SCAN
Note5: well, I'll let you do the remaining :-)
Note6: This is not optimized code, nor guaranteed.
Note7: Nothing to see here, move along.
Regards,
Yoann.