Smartform via Email

Question

Hi All,
I have developed a driver program and a smartform for Tax Invoice in SD module.The printing is going on well.The requirement is that the client wants that this Invoice should be sent via email.Please guide me for this.
My functional guy has created a new output type by changing the transmission medium.But we doubt whether it has to be 5 or 7.Please guide in all aspects.
Waiting for quick responses....
Thanks
Ankur Johri
9911316058

Answer 1

We use Faxination. So all mail output runs via the fax (Automatically forwarded to mail). But as a guideline, here's some code from a working program in 46C.
I know it is a lot of code just to send a silly email, but unfortunately, it seems to have to go like this...
Hopefully it's helpful.
* If output is send to email, then get OTF. No preview is possible for
* email.
  IF p_mail = 'X'.
    control_parameters-getotf = 'X'.
    control_parameters-preview   = ' '.
  ENDIF.
Email adress is copied to the spool for faxination...
*     Check if an email is to be sent. If so, the email address needs to
*     be copied to the spool request! Or else it will not work...
      IF p_mail = 'X'.
        PERFORM convert_otf.
        PERFORM prepare_email.
        PERFORM send_email.
      ENDIF.
*       Form  convert_otf
FORM convert_otf.
  CLEAR: gd_buffer.
  t_otfdata[] = job_output_info-otfdata[].
* Convert OTF to PDF (132 per line).
  CALL FUNCTION 'CONVERT_OTF'
       EXPORTING
            format       = 'PDF'
       IMPORTING
            bin_filesize = len_in
       TABLES
            otf          = t_otfdata
            lines        = t_lines.
  IF sy-subrc <> 0.
  ENDIF.
* Convert PDF from 132 to 255.
  LOOP AT t_lines.
    TRANSLATE t_lines USING ' ~'.
    CONCATENATE gd_buffer t_lines INTO gd_buffer.
  ENDLOOP.
  TRANSLATE gd_buffer USING '~ '.
  DO.
    it_mess_att = gd_buffer.
    APPEND it_mess_att.
    SHIFT gd_buffer LEFT BY 255 PLACES.
    IF gd_buffer IS INITIAL.
      EXIT.
    ENDIF.
  ENDDO.
ENDFORM.                    " convert_otf
*       Form  prepare_email
FORM prepare_email.
  DATA: z_filename LIKE tline-tdline.
  len_outn = len_out = len_in.
  CLEAR: reclist, reclist[],
         objhead, objhead[],
         objtxt,  objtxt[],
         objbin,  objbin[],
         objpack, objpack[].
* Object with PDF.
  CLEAR objbin.
  REFRESH objbin.
  objbin[] = it_mess_att[].
  DESCRIBE TABLE objbin LINES mail_attachment_lines.
* Object with main text of the mail.
  CONCATENATE 'Z_OPEN_ORDERS_EMAIL_BODY_' tvko-bukrs
              INTO text_name.
  PERFORM read_text USING control_parameters-langu
                          text_name.
  LOOP AT text_lines.
    objtxt = text_lines-tdline.
    APPEND: objtxt.
    CLEAR:  objtxt.
  ENDLOOP.
  DESCRIBE TABLE objtxt LINES mail_body_lines.
* Document information.
  doc_chng-obj_name   = 'BackOrderList'.
  doc_chng-expiry_dat = sy-datum + 10.
* Read subject text:
  CONCATENATE 'Z_OPEN_ORDERS_EMAIL_SUBJECT_' tvko-bukrs
              INTO text_name.
  PERFORM read_text USING control_parameters-langu
                          text_name.
  READ TABLE text_lines INDEX 1.
  doc_chng-obj_descr = text_lines-tdline.
  doc_chng-sensitivty = 'F'.
  doc_chng-doc_size = mail_body_lines * 255.
* Pack to main body.
  CLEAR objpack-transf_bin.
  objpack-head_start = 1.
  objpack-head_num   = 0.
  objpack-body_start = 1.
  objpack-body_num   = mail_body_lines.
  objpack-doc_type   = 'RAW'.
  APPEND objpack.
* Pack to PDF.
  objpack-transf_bin = 'X'.
  objpack-head_start = 1.
  objpack-head_num   = 1.
  objpack-body_start = 1.
  objpack-body_num   = mail_attachment_lines.
  objpack-doc_type   = 'PDF'.
  objpack-obj_name   = 'BackOrderList'.
  objpack-doc_size   = mail_attachment_lines * 255.
* Read filename text:
  CONCATENATE 'Z_OPEN_ORDERS_EMAIL_FILENAME_' tvko-bukrs
              INTO text_name.
  PERFORM read_text USING control_parameters-langu
                          text_name.
  READ TABLE text_lines INDEX 1.
  z_filename = text_lines-tdline.
  CONCATENATE z_filename '.pdf'
               INTO objpack-obj_descr.
  APPEND objpack.
  CLEAR reclist.
* reclist-copy = 'X'.
* e-mail receivers.
  reclist-receiver   = i_contactaddress-e_mail.
  reclist-express    = ' '.
  reclist-rec_type   = 'U'.
  reclist-notif_del  = ' '. " request delivery notification
  reclist-notif_ndel = ' '. " request not delivered notification
  APPEND reclist.
ENDFORM.                    " prepare_email
*       Form  send_email
FORM send_email.
* First try with 'From':
  CALL FUNCTION 'SO_DOCUMENT_SEND_API1'
       EXPORTING
            document_data              = doc_chng
            put_in_outbox              = 'X'
            sender_address             = p_from
            sender_address_type        = 'SMTP'
       TABLES
            packing_list               = objpack
            object_header              = objhead
            contents_hex               = objbin
            contents_txt               = objtxt
            receivers                  = reclist
       EXCEPTIONS
            too_many_receivers         = 1
            document_not_sent          = 2
            document_type_not_exist    = 3
            operation_no_authorization = 4
            parameter_error            = 5
            x_error                    = 6
            enqueue_error              = 7
            OTHERS                     = 8.
  IF sy-subrc <> 0.
    CALL FUNCTION 'SO_NEW_DOCUMENT_ATT_SEND_API1'
         EXPORTING
              document_data              = doc_chng
              put_in_outbox              = 'X'
         TABLES
              packing_list               = objpack
              object_header              = objhead
              contents_hex               = objbin
              contents_txt               = objtxt
              receivers                  = reclist
         EXCEPTIONS
              too_many_receivers         = 1
              document_not_sent          = 2
              document_type_not_exist    = 3
              operation_no_authorization = 4
              parameter_error            = 5
              x_error                    = 6
              enqueue_error              = 7
              OTHERS                     = 8.
    IF sy-subrc <> 0.
*     MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*             WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
  ENDIF.
ENDFORM.                    " send_email
Cheers,
Edwin.