SO_NEW_DOCUMENT_ATT_SEND_API1 sending pdf with wrong special characters

Question

Hi Experts,
Im using the fm SO_NEW_DOCUMENT_ATT_SEND_API1 to send out a pdf (into sap office box). But when I open it
I get totally wrong special characters (Chinese for instance, and ' is replaced by #).
I have already applied the note 1430123 but it didnt resolve the issue.
Can anybody help on this?
Help will highly appreciated.
Hubert

Answer 1

Yes. This is very much possible.
gv_xstring contains the pdf data in XSTRING format.
Check the code :
*   ---------- create persistent send request ----------------------
  send_request = cl_bcs=>create_persistent( ).
*   ---------- Create document ----------------------------------------
*   get PDF xstring and convert it to BCS format
  lp_pdf_size = XSTRLEN( gv_xstring ).
  pdf_content = cl_document_bcs=>xstring_to_solix(
      ip_xstring = gv_xstring ).
*     Create Mail Body
  CLEAR ls_body.
  CONCATENATE 'Dear' gv_name1 ',' INTO ls_body SEPARATED BY space .
  APPEND ls_body TO lt_body.
  CLEAR ls_body.
  APPEND ls_body TO lt_body.
  CLEAR ls_body.
  ls_body = 'Warm greetings '.
  APPEND ls_body TO lt_body.
  CLEAR ls_body.
  ls_body = 'Manager'.
  APPEND ls_body TO lt_body.
  document = cl_document_bcs=>create_document(
                  i_type    = 'RAW'
                  i_text    = lt_body
*                  i_length  = '12'
                  i_subject = 'Letter' ).
**   Add Attachment to send request
  CALL METHOD document->add_attachment
    EXPORTING
      i_attachment_type    = 'PDF'
      i_attachment_subject = 'Letter'
      i_att_content_hex    = pdf_content.
*     add document to send request
  CALL METHOD send_request->set_document( document ).
*   ---------- add recipient (e-mail address) ----------------------
  IF gv_adrnr IS INITIAL.
    SELECT SINGLE adrnr
      FROM kna1
      INTO gv_adrnr
     WHERE kunnr EQ gv_kunrg.
  ENDIF.
  SELECT SINGLE smtp_addr
    INTO lv_email
    FROM adr6
   WHERE addrnumber EQ gv_adrnr.
  recipient = cl_cam_address_bcs=>create_internet_address(
      i_address_string = lv_email ).
*   add recipient to send request
  send_request->add_recipient( i_recipient = recipient ).
*   ---------- send document ---------------------------------------
  sent_to_all = send_request->send(
      i_with_error_screen = 'X' ).
  IF sent_to_all = 'X'.
*    MESSAGE i022(so).
    gv_emailflag = 'X'.
  ENDIF.
*   ---------- explicit 'commit work' is mandatory! ----------------
  COMMIT WORK.