SQL "LIKE" statement isn't working right -- help please!

Question

Good day everyone,
I thought about putting this in the "SQL on Oracle" forum, but it looked like those messages were geared more toward the Oracle platform itself, so here I am.  I apologize if this isn't the best forum.
I have the following SQL statement:
  SELECT zzreporting_ut1
         zzreporting_ut2
         zzreporting_ut3
         zzreporting_ut4
         zzreporting_ut5
      UP TO 1000 ROWS
      INTO TABLE it_gmia_gmgrresp_data
        FROM gmspprogram
   WHERE ( ( zzreporting_ut1 LIKE '4011%'   OR
             zzreporting_ut1 LIKE '4012%'   OR
             zzreporting_ut1 LIKE '4013%' ) OR
           ( zzreporting_ut2 LIKE '4011%'   OR
             zzreporting_ut2 LIKE '4012%'   OR
             zzreporting_ut2 LIKE '4013%' ) OR
           ( zzreporting_ut3 LIKE '4011%'   OR
             zzreporting_ut3 LIKE '4012%'   OR
             zzreporting_ut3 LIKE '4013%' ) OR
           ( zzreporting_ut4 LIKE '4011%'   OR
             zzreporting_ut4 LIKE '4012%'   OR
             zzreporting_ut4 LIKE '4013%' ) OR
           ( zzreporting_ut5 LIKE '4011%'   OR
             zzreporting_ut5 LIKE '4012%'   OR
             zzreporting_ut5 LIKE '4013%' ) ).
All I want to do is bring back the rows where one of those 5 "ut" fields begins with 4011, 4012, or 4013.  However, when I run it, it brings back anything:  rows where all 5 "ut" fields are empty, where the ut1 field begins with 4014, etc.
Does anyone know what I'm doing wrong in my SQL statement?
Thank you!  And as always, points awarded for ALL HELPFUL answers!
Dave
Edited by: Dave Packard on Jul 1, 2008 2:18 PM

Answer 1

Hi Dave,
because I don't know such a table named gmspprogram I'm not sure what to say.
According to boolean expression syntax you do not need any of the brackets because the only operator used is OR.
I'd suggest.
data: lt_pattern_range type range of gmspprogram-zzreporting_ut2.
perform insert_range using 'ICP':
  '4011*' '' changing lt_pattern_range,
  '4012*' '' changing lt_pattern_range,
  '4013*' '' changing lt_pattern_range.
SELECT
  zzreporting_ut1
  zzreporting_ut2
  zzreporting_ut3
  zzreporting_ut4
  zzreporting_ut5
  UP TO 1000 ROWS
  INTO CORRESPONDING FIELDS OF TABLE it_gmia_gmgrresp_data
  FROM gmspprogram
  WHERE zzreporting_ut1 in lt_pattern_range
     OR zzreporting_ut2 in lt_pattern_range
     OR zzreporting_ut3 in lt_pattern_range
     OR zzreporting_ut4 in lt_pattern_range.
* need form
*&      Form  insert_range
*       insert selection range - handles any range type "CLI20061218
FORM insert_range  USING    p_signopt     TYPE c            "#EC CALLED
                            p_low         TYPE any
                            p_high        TYPE any
                   CHANGING pt_range      TYPE table.
  FIELD-SYMBOLS:
    <range>                               TYPE ANY,
    <sign>                                TYPE ANY,
    <option>                              TYPE ANY,
    <low>                                 TYPE ANY,
    <high>                                TYPE ANY.
  DATA:
    lv_ref                                TYPE REF TO data.
  CHECK NOT (
              p_low     IS INITIAL AND
              p_high    IS INITIAL ).
  CREATE DATA lv_ref                      LIKE LINE OF pt_range.
  ASSIGN lv_ref->* TO <range>.
  CHECK sy-subrc                          = 0.
  ASSIGN COMPONENT 'SIGN' OF STRUCTURE <range> TO <sign>.
  CHECK sy-subrc                          = 0.
  ASSIGN COMPONENT 'OPTION' OF STRUCTURE <range> TO <option>.
  CHECK sy-subrc                          = 0.
  ASSIGN COMPONENT 'LOW' OF STRUCTURE <range> TO <low>.
  CHECK sy-subrc                          = 0.
  ASSIGN COMPONENT 'HIGH' OF STRUCTURE <range> TO <high>.
  CHECK sy-subrc                          = 0.
  <sign>                                  = p_signopt(1).
  <option>                                = p_signopt+1(2).
  <low>                                   = p_low.
  <high>                                  = p_high.
  READ TABLE pt_range WITH KEY table_line = <range> BINARY SEARCH
    TRANSPORTING NO FIELDS.
  CHECK sy-subrc                          <> 0.
  INSERT <range> INTO pt_range INDEX sy-tabix.
ENDFORM.                    " insert_range
At least - I think - this looks better. And you may reuse the FORM insert_range whereever you want.
Regards,
Clemens