Stumped by mount volume quirk

Question

Okay, this works fine:
set Uname to "<my_username>"
set Pword to "<my_password>"
set someVolume to "afp://168.116.236.41/MHCProduction"
mount volume someVolume as user name Uname with password Pword
If I run this script, the volume in question mounts immediately. However, when I incorporate the above concept into a slightly more involved script, when it gets to the mount volume command it throws up a dialog asking for the server address. The mount volume command is built identically (in fact I cut and pasted it from one script to the other. The only difference is that in the longer script, the URL string in someVolume is read from an external text file and the username and password are initally entered via a dialog box and thereafter stored in properties of the script. Here's the code from the longer script:
property Uname : missing value
property Pword : missing value
global selectedVolumes
my checkProps()
tell application "Finder"
set thePath to (path to application support folder from user domain as string) & "<path:to:textfile>"
if (exists file thePath) then
set selectedVolumes to my readPrefs()
end if
end tell
repeat with someVolume in selectedVolumes
mount volume someVolume as user name Uname with password Pword
end repeat
on checkProps()
if Uname is missing value then
set Uname to text returned of (display dialog "Enter your Username:" default answer "")
end if
if Pword is missing value then
set Pword to text returned of (display dialog "Enter your Password:" default answer "")
end if
end checkProps
on readPrefs()
set prefFile to open for access (((path to application support folder from user domain) as string) & "<path:to:textfile>")
read prefFile using delimiter return
end readPrefs
can anyone tell me why the mount volume command goes off without a hitch in the first instance, but not in the second? I've verified that the URL string is correct in the second script using 'display dialog someVolume' right before the mount volume command, and it shows a properly formatted URL string (afp://yadayada/yada).
Any input greatly appreciated.
St!ff
Dual 2.0 GHz Powermac G5   Mac OS X (10.4.4)  

Answer 1

I've discovered a much quicker and more relaible means to accomplish this:
property Uname : missing value
property Pword : missing value
global selectedVolumes, theIteration
my checkProps()
tell application "Finder"
set thePath to (path to application support folder from user domain as string) & <path:to:textfile>
if (exists file thePath) then
set rawData to my readPrefs(thePath)
end if
end tell
set cleanData to (characters (offset of <ServerIP> in rawData) thru -2 of rawData) as text
set {oldTIDs, AppleScript's text item delimiters} to {AppleScript's text item delimiters, return}
set selectedVolumes to text items of cleanData
set AppleScript's text item delimiters to oldTIDs
set theIteration to 1
repeat with someVolume in selectedVolumes
set theDir to "/Volumes/mntpnt" & theIteration
set mkdirCmd to "mkdir " & theDir
set mountCmd to "mount_afp afp://" & Uname & ":" & Pword & "@" & someVolume & " " & theDir
try
do shell script mkdirCmd
do shell script mountCmd
on error errMsg number errNum
display dialog "Error! " & errNum & return & errMsg & return & someVolume
set theCleanupCmd to "rmdir " & theDir
do shell script theCleanupCmd
end try
set theIteration to theIteration + 1
end repeat
on checkProps()
if Uname is missing value then
set Uname to text returned of (display dialog "Enter your Username:" default answer "")
end if
if Pword is missing value then
set Pword to text returned of (display dialog "Enter your Password:" default answer "")
end if
end checkProps
on readPrefs(somePath)
set prefFile to open for access somePath
set theData to read prefFile
close access prefFile
return theData
end readPrefs
Dual 2.0 GHz Powermac G5   Mac OS X (10.4.4)