Sys_refcursor to dynamic record type

Question

Hi there,
I had a procedure A that is calling procedure B to return the sys_refcursor. And procedure A will using the data that return from cursor procedure B for some processing. Is there anyway that i don't need to fix the record column by calling <record name> <cursor name>%RowType? Because I had an error if i declare the record with the cursor type that not yet open. Example of the code as below.
Procedure ProcA(a1 Integer default Null) Is
cursor1 sys_refcursor;
record1 cursor1%RowType;
Begin
ProcB(0, cursor1);
If cursor1%Isopen Then
Loop
Fetch cursor1
Into record1;
Exit When cursor1%NotFound;
End Loop;
Close cursor1;
End If;
End;
Thanks in advance.

Answer 1

Yes, two methods comes to mind.
The complex, and more "correct", method is to create a DBMS_SQL cursor instead. Such a cursor has a describe interface that allows the receiver to dynamically determine the cursor's number of columns, data types of the the columns and so on.
DBMS_SQL is documented in the Oracle® Database PL/SQL Packages and Types Reference guide.
The second method is easier and flexible, but a bit of a hack as it can only deal with data types that can be implicitly converted to varchar2. It also requires the SELECT statement to call a type constructor using columns as properties for the constructor. The following code illustrates this concept.
SQL> create or replace type TStrings is table of varchar2(4000);
2 /
Type created.
SQL>
SQL>
SQL> create or replace procedure Cursor1( c IN OUT sys_refcursor ) is
2 begin
3 open c for
4 select TStrings( object_id, object_name, object_type ) from all_objects;
5 end;
6 /
Procedure created.
SQL>
SQL>
SQL> create or replace procedure Cursor2( c IN OUT sys_refcursor ) is
2 begin
3 open c for
4 select TStrings( rownum, username ) from all_users;
5 end;
6 /
Procedure created.
SQL>
SQL>
SQL>
SQL> declare
2 c sys_refcursor;
3 cols TStrings;
4
5 procedure W( cLine varchar2 ) is
6 begin
7 DBMS_OUTPUT.put_line( cLine );
8 exception when OTHERS then
9 NULL;
10 end;
11
12 procedure DisplayColumns( s TStrings ) is
13 begin
14 for i in 1..s.Count
15 loop
16 W( 'column '||i||' ['||s(i)||']' );
17 end loop;
18 end;
19
20 begin
21 W( '************' );
22
23 W( 'opening cursor 1' );
24 Cursor1( c );
25 -- fetch only 1 row to demonstrate
26 fetch c into cols;
27 W( 'cursor has '||cols.Count||' columns' );
28 DisplayColumns( cols );
29 close c;
30
31 W( '************' );
32
33 W( 'opening cursor 2' );
34 Cursor2( c );
35 fetch c into cols;
36 W( 'cursor has '||cols.Count||' columns' );
37 DisplayColumns( cols );
38 close c;
39
40 W( '************' );
41 end;
42 /
opening cursor 1
cursor has 3 columns
column 1 [258]
column 2 [DUAL]
column 3 [TABLE]
opening cursor 2
cursor has 2 columns
column 1 [1]
column 2 [RMAN]
PL/SQL procedure successfully completed.
SQL>