Sysdate in pl/sql

Question

Hi all
I am executing following pl/sql block
DECLARE
hiredate emp.hiredate%TYPE;
sysdate hiredate%TYPE;
empno emp.empno%TYPE := 7839;
BEGIN
SELECT hiredate,sysdate
INTO hiredate,sysdate
FROM emp
WHERE empno = 7839;
dbms_output.put_line(hiredate||' '||sysdate);
END;
17-NOV-81
only hiredate id displaying at runtime , why sysdate is not displaying?????

Answer 1

but if i could not declare sysdate in PL/SQL block, it should not get compiled.The point is, you can declare sysdate in your pl/sql block and because of the way that oracle handles naming resolution, you will not get the result you appear to be looking for as your local delcaration of SYSDATE will override the global declaration of SYSDATE
SQL> DECLARE
  2
  3     sysdate date;
  4  BEGIN
  5     SELECT
  6             sysdate
  7     INTO
  8             sysdate
  9     FROM
10             dual;
11
12     dbms_output.put_line(NVL(sysdate,TO_DATE('01/01/2005','dd/mm/yyyy')));
13  END;
14  /
01-JAN-05
PL/SQL procedure successfully completed.
SQL> DECLARE
  2
  3     sysdate date :=TO_DATE('31/12/2005','dd/mm/yyyy');
  4  BEGIN
  5     SELECT
  6             sysdate
  7     INTO
  8             sysdate
  9     FROM
10             dual;
11
12     dbms_output.put_line(NVL(sysdate,TO_DATE('01/01/2005','dd/mm/yyyy')));
13  END;
14  /
31-DEC-05
PL/SQL procedure successfully completed.
SQL> DECLARE
  2
  3     sysdate date;
  4  BEGIN
  5  -- SELECT
  6  --         sysdate
  7  -- INTO
  8  --         sysdate
  9  -- FROM
10  --         dual;
11  --
12     dbms_output.put_line(NVL(sysdate,TO_DATE('01/01/2005','dd/mm/yyyy')));
13  END;
14  /
01-JAN-05
PL/SQL procedure successfully completed.
SQL> DECLARE
  2
  3  -- sysdate date;
  4  BEGIN
  5  -- SELECT
  6  --         sysdate
  7  -- INTO
  8  --         sysdate
  9  -- FROM
10  --         dual;
11  --
12     dbms_output.put_line(NVL(sysdate,TO_DATE('01/01/2005','dd/mm/yyyy')));
13  END;
14  /
14-SEP-05
PL/SQL procedure successfully completed.
SQL> DECLARE
  2
  3     sys_date date;
  4  BEGIN
  5     SELECT
  6             sysdate
  7     INTO
  8             sys_date
  9     FROM
10             dual;
11
12     dbms_output.put_line(NVL(sys_date,TO_DATE('01/01/2005','dd/mm/yyyy')));
13  END;
14  /
14-SEP-05
PL/SQL procedure successfully completed.Also, if you get rid of your declaration of sysdate and try the same query again, you will get an error:
SQL> DECLARE
  2
  3  -- sysdate date;
  4  BEGIN
  5     SELECT
  6             sysdate
  7     INTO
  8             sysdate
  9     FROM
10             dual;
11
12     dbms_output.put_line(NVL(sysdate,TO_DATE('01/01/2005','dd/mm/yyyy')));
13  END;
14  /
                sysdate
ERROR at line 8:
ORA-06550: line 8, column 3:
PLS-00321: expression 'SYSDATE' is inappropriate as the left hand side of an
assignment statement
ORA-06550: line 5, column 2:
PL/SQL: SQL Statement ignoredHave a look at the docs for more info on how oracle handles naming resolution:
http://download-west.oracle.com/docs/cd/B10501_01/appdev.920/a96624/d_names.htm#3693
HTH
David