Tables for VA41 / VA42 / VA43

Question

Hello,
We are creating Crystal Reports by connecting to SAP ECC. We are trying to create the VA43 report ( not all fields though) into Crystal.
Can some one tell me the exact table names used for VA 41/42/43 ( sales Order Contracts).
I am specifically looking for Sold To / Ship to / PO  info, which I know is coming out of a Struct. But I want the exact table names where it is stored.
P.S. I have seen the basic sales tables already ( VBAP / VBAK etc..)
Regds
Girish

Answer 1

Hello
Use the below program to find the tables used in  the given trasaction code.
REPORT zfsl_table_used_tcode NO STANDARD PAGE HEADING.
TABLES: d010tab, dd02l, tstc, tstct, dd02t.
*                          Types Defined                               *
TYPES: BEGIN OF ty_detail,
       tcode   LIKE tstct-tcode,
       ttext   LIKE tstct-ttext,
       tabname LIKE d010tab-tabname,
       ddtext  LIKE dd02t-ddtext,
       END OF ty_detail.
*            Declaration of Internal Tables & Variables                *
DATA: it_detail TYPE STANDARD TABLE OF ty_detail WITH HEADER LINE,
      wa_detail LIKE LINE OF it_detail,
      cursor_field(30).
*                      SELECTION SCREEN                                *
SELECTION-SCREEN BEGIN OF BLOCK a WITH FRAME TITLE text-001 NO INTERVALS.
SELECT-OPTIONS: sotcode  FOR tstct-tcode      NO INTERVALS MEMORY ID aaa,
                sotext   FOR tstct-ttext      NO INTERVALS,
                sotname  FOR d010tab-tabname  NO INTERVALS,
                soddtext FOR dd02t-ddtext     NO INTERVALS.
SELECTION-SCREEN END OF BLOCK a.
*                         AT SELECTION-SCREEN                          *
AT SELECTION-SCREEN.
  IF sotcode[] IS INITIAL AND sotext[] IS INITIAL AND sotname[] IS INITIAL AND soddtext[] IS INITIAL.
    MESSAGE 'You must select minimum one option' TYPE 'E'.
  ENDIF.
*                        START-OF-SELECTION                            *
START-OF-SELECTION.
  SELECT tstct~tcode tstct~ttext d010tab~tabname dd02t~ddtext
    INTO CORRESPONDING FIELDS OF TABLE it_detail
    FROM tstc INNER JOIN tstct    ON ( tstc~tcode = tstct~tcode )
              INNER JOIN d010tab  ON ( tstc~pgmna = d010tab~master )
              INNER JOIN dd02l    ON ( d010tab~tabname = dd02l~tabname )
              INNER JOIN dd02t    ON ( dd02l~tabname = dd02t~tabname )
    WHERE tstct~sprsl       EQ 'E'
      AND dd02l~as4local    EQ 'A'
      AND dd02l~as4vers     EQ '0000'
      AND dd02l~tabclass    EQ 'TRANSP'
      AND dd02t~ddlanguage  EQ 'E'
      AND tstct~tcode       IN sotcode
      AND tstct~ttext       IN sotext
      AND d010tab~tabname   IN sotname
      AND dd02t~ddtext      IN soddtext.
  IF sy-subrc EQ 0.
    SORT: it_detail BY tcode tabname.
    WRITE:  1(149) sy-uline,
            /1(1)   '|',
            3(20)   'Transaction Code'  CENTERED COLOR 1,
            24(1)   '|',
            26(36)  'Transaction Text'  CENTERED COLOR 1,
            63(1)   '|',
            65(20)  'Table Name'        CENTERED COLOR 1,
            86(1)   '|',
            88(60)  'Table Description' CENTERED COLOR 1,
            149(1)  '|',
            /1(149) sy-uline.
    LOOP AT it_detail INTO wa_detail.
      WRITE:  /1(1)   '|',
              3(20)   wa_detail-tcode    HOTSPOT ON,
              24(1)   '|',
              26(36)  wa_detail-ttext    HOTSPOT ON,
              63(1)   '|',
              65(20)  wa_detail-tabname  HOTSPOT ON,
              86(1)   '|',
              88(60)  wa_detail-ddtext   HOTSPOT ON,
              149(1)  '|'.
      HIDE: wa_detail.
    ENDLOOP.
    WRITE:  /1(149) sy-uline.
  ELSE.
    MESSAGE: 'Sorry, DATA not found for Given Criteria' TYPE 'S'.
  ENDIF.
AT LINE-SELECTION.
  GET CURSOR FIELD cursor_field.
  CASE cursor_field.
    WHEN 'WA_DETAIL-TCODE' OR 'WA_DETAIL-TTEXT'.
      PERFORM show_transaction USING wa_detail-tcode.
    WHEN 'WA_DETAIL-TABNAME' OR 'WA_DETAIL-DDTEXT'.
      PERFORM show_table USING wa_detail-tabname.
    WHEN OTHERS.
  ENDCASE.
*&      Form  show_table
*       text
*      -->TABLE_NAME text
FORM show_table USING table_name.
  CALL FUNCTION 'RS_DD_TABL_EDIT'
    EXPORTING
      objname              = table_name
      edit_mode            = 'S'
    EXCEPTIONS
      object_not_found     = 1
      object_not_specified = 2
      permission_failure   = 3
      not_executed         = 4
      OTHERS               = 5.
  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM.                    "show_table
*&      Form  show_transaction
*       text
*      -->FIELD_VALUE  text
FORM show_transaction USING tcode_in.
  DATA: tcode LIKE tstc-tcode.
  tcode = tcode_in.
  CALL FUNCTION 'RS_TRANSACTION_SHOW'
    EXPORTING
      objectname       = tcode
      monitor_activate = ' '
    EXCEPTIONS
      object_not_found = 1
      OTHERS           = 2.
  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM.                    "show_transaction
Edited by: krishna dussa on Mar 11, 2010 1:34 PM