Trying to create a number stamp utility

Question

I've already figured out the basics of Automator. But this one has me stumped.
We run a pool company and would like to assign a new, sequential number to every customer/opportunity. So when a customer walks in we input their info into Daylite and setup folders on the server. I'd like to assign a sequential number with prefix to everything..i.e. P00001...then the next time someone double clicks the app, it will spit out P00002, etc.
I'm trying to write an Automator app that will remember the last number, increase by 1 and give us that number.
Any thoughts?

Answer 1

The same thing can be done by placing a resource (a text file containing the number) into the application bundle. The prefix number would then be saved in the application itself, so as long as everyone is running the same application the number shouldn't reset. The Run AppleScript action for that is:
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFEE80;
overflow: auto;"
title="this text can be pasted into an Automator 'Run AppleScript' action">on run {input, parameters} -- increment and save a new prefix number
set PrefixFile to ((path to me) as text) & "Contents:Resources:PrefixFile.txt" -- the application resource containing the number
if PrefixFile contains "Automator.app" then -- this action is running in a workflow document
display alert "Run AppleScript error" message "The AppleScript action that gets a prefix number needs to be run from an application.  Save the workflow as an application and try again."
error number -128 -- cancel
end if
do shell script "touch " & quoted form of POSIX path of PrefixFile -- create the file if it doesn't exist
try -- get the number
set PrefixNumber to (read file PrefixFile) as integer
on error -- empty file (or doesn't have the prefix number), so start at the beginning
set PrefixNumber to 0
end try
set PrefixNumber to text 2 thru -1 of ((100000 + PrefixNumber + 1) as text) -- leading zeros
try -- write the new number 
set TheOpenFIle to (open for access file PrefixFile with write permission)
set eof of TheOpenFIle to 0 -- overwrite previous file contents
write PrefixNumber to TheOpenFIle starting at eof
close access TheOpenFIle
on error
try
close access TheOpenFIle
end try
end try
return "P" & PrefixNumber
end run</pre>
My Copy Folder Structure action just deals with creating folders from a template, it doesn't do anything with files. I also have a Trim FIle Names action that can use variables to add to the name - it is set up for trimming characters from a file name, but can be used to add prefixes and suffixes if you are having problems doing that.
Copy Folder Structure:
Trim File Names: