Type long columns

Question

I can't do "insert as select" statement on tables with long type column.

Answer 1

you will need to create some conversion codes to have the long converted into varchar2 datatype.
  CREATE OR REPLACE Function convert_long_to_char( pTableName in varchar2,
                                                   pColumnName in varchar2,
                                                   pRowId in rowid ) return varchar2 As
    vCursor    integer default dbms_sql.open_cursor;
    vN         number;
    vLongVal  varchar2(4000);
    vLongLen  number;
    vBuflen    number := 4000;
    vCurPos    number := 0;
  begin
    dbms_sql.parse( vCursor,'select ' || pColumnName || ' from ' || pTableName ||
                                                          ' where rowid = :x',
                    dbms_sql.native );
    dbms_sql.bind_variable( vCursor, ':x', pRowId );
    dbms_sql.define_column_long(vCursor, 1);
    vN := dbms_sql.execute(vCursor);
    if (dbms_sql.fetch_rows(vCursor)>0) then
      dbms_sql.column_value_long(vCursor, 1, vBuflen, vCurpos ,
                                 vLongVal, vLongLen );
    end if;
    dbms_sql.close_cursor(vCursor);
    return vLongVal;
  end convert_long_to_char;
  SQL> describe tmp1;
   Name                                      Null?    Type
   P_CODE                                             LONG
  SQL> select p_code from tmp1;
  P_CODE
  1234567890 ABCDEFGHIJKLMNOPQRSTUVWXYZ 0987654321 QAZWSXEDCRFVTGBYHNUJMIKOLP 0192
  SQL> describe tmp2;
   Name                                      Null?    Type
   P_CODE                                             LONG
  SQL> select p_code from tmp2;
  no rows selected
  SQL> insert into tmp2
    2  select p_code from tmp1;
  select p_code from tmp1
  ERROR at line 2:
  ORA-00997: illegal use of LONG datatype
  SQL> insert into tmp2
    2  select convert_long_to_char('tmp1','p_code',rowid) p_code from tmp1;
  1 row created.
  SQL> commit;