Unable to create Insert process in forms

Question

Hi All,
I have created a tabular form where i am able to update & delete and adding rows with out any problem.
When i am trying a insert a new record it is throwin gth ebelow error... Below is the error which i had mentioned to u.
Error in mru internal routine: ORA-20001: Error in MRU: row= 1, ORA-20001: ORA-20001: Current version of data in database has changed since user initiated update process. current checksum = "D47F24D590E442A8BCF98D5BA7D782AC", item checksum = "B3FF449D4A98A3313839C25D15586A17"., update "APEX_DEMO_SCHEME"."DEPT" set "DEPTNO" = :b1, "DNAME" = :b2, "LOC" = :b3
can u please help me out how to reolve this problem.. as i am not able to get the rtesults from past few days..
Thanks,
Anoo..

Answer 1

So I've posted this example before, but don't hesitate to ask questions:
Okay, Here's a quick rundown on how to build a manual form using APEX_ITEM and collections. The process goes in 4 steps: gather the data, display the data, update based on user input, then write the changes. Each step requires it's own piece of code, but you can extend this out as far as you want. I have a complex form that has no less than a master table and 4 children I write to based on user input, so this can get as complex as you need. Let me know if anything doesn't make sense.
First, create the basic dataset you are going to work with. This usually includes existing data + empty rows for input. Create a Procedure that fires BEFORE HEADER or AFTER HEADER but definitely BEFORE the first region.
DECLARE
  v_id     NUMBER;
  var1     NUMBER;
  var2     NUMBER;
  var3     VARCHAR2(10);
  var4     VARCHAR2(8);
  cursor c_prepop is
  select KEY, col1, col2, col3, to_char(col4,'MMDDYYYY')
    from table1
    where ...;
  i         NUMBER;
  cntr      NUMBER := 5;  --sets the number of blank rows
BEGIN
  OPEN c_prepop;
    LOOP
      FETCH c_prepop into v_id, var1, var2, var3, var4;
      EXIT WHEN c_prepop%NOTFOUND;
        APEX_COLLECTION.ADD_MEMBER(
        p_collection_name => 'MY_COLLECTION',
        p_c001 => v_id,  --Primary Key
        p_c002 => var1, --Number placeholder
        p_c003 => var2, --Number placeholder
        p_c004 => var3, --text placeholder
        p_c005 => var4 --Date placeholder
    END LOOP;
  CLOSE c_prepop;
  for i in 1..cntr loop
    APEX_COLLECTION.ADD_MEMBER(
        p_collection_name => 'MY_COLLECTION',
        p_c001 => 0, --designates this as a new record
        p_c002 => 0, --Number placeholder
        p_c003 => 0, --Number placeholder
        p_c004 => NULL, --text placeholder
        p_c005 => to_char(SYSDATE,'MMDDYYYY') --Date placeholder
  end loop;
END;Now I have a collection populated with rows I can use. In this example I have 2 NUMBERS, a TEXT value, and a DATE value stored as text. Collections can't store DATE datatypes, so you have to cast it to text and play with it that way. The reason is because the user is going to see and manipulate text - not a DATE datatype.
Now build the form/report region so your users can see/manipulate the data. Here is a sample query:
SELECT rownum, apex_item.hidden(1, c001),  --Key ID
     apex_item.text(2, c002, 8, 8) VALUE1,
     apex_item.text(3, c003, 3, 3) VALUE2,
     apex_item.text(4, c004, 8, 8) VALUE3,
     apex_item.date_popup(5, null,c005,'MMDDYYYY',10,10) MY_DATE
FROM APEX_COLLECTIONS
WHERE COLLECTION_NAME = 'MY_COLLECTION'This will be a report just like an SQL report - you're just pulling the data from the collection. You can still apply the nice formatting, naming, sorting, etc. of a standard report. In the report the user will have 3 "text" values and one Date with Date Picker. You can change the format, just make sure to change it in all four procedures.
What is critical to note here are the numbers that come right before the column names. These numbers become identifiers in the array used to capture the data. What APEX does is creates an array of up to 50 items it designates as F01-F50. The F is static, but the number following it corresponds to the number in your report declaration above, ie, F01 will contain the primary key value, F02 will contain the first numeric value, etc. While not strictly necessary, it is good practice to assign these values so you don't have to guess.
One more note: I try to align the c00x values from the columns in the collection with the F0X values in the array to keep myself straight, but they are separate values that do NOT have to match. If you have an application you think might get expanded on, you can leave gaps wherever you want. Keep in mind, however, that you only have 50 array columns to use for data input. That's the limit of the F0X array even though a collection may have up to 1000 values.
Now you need a way to capture user input. I like to create this as a BEFORE COMPUTATIONS/VALIDATIONS procedure that way the user can see what they changed (even if it is wrong). Use the Validations to catch mistakes.
declare
  j pls_integer := 0;
begin
for j1 in (
  select seq_id from apex_collections
  where collection_name = 'MY_COLLECTION'
  order by seq_id) loop
  j := j+1;
  --VAL1 (number)
  apex_collection.update_member_attribute (p_collection_name=> 'MY_COLLECTION',
      p_seq=> j1.seq_id,p_attr_number =>2,p_attr_value=>wwv_flow.g_f02(j));
  --VAL2 (number)
  apex_collection.update_member_attribute (p_collection_name=> 'MY_COLLECTION',
      p_seq=> j1.seq_id,p_attr_number =>3,p_attr_value=>wwv_flow.g_f03(j));
  --VAL3 (text)
  apex_collection.update_member_attribute (p_collection_name=> 'MY_COLLECTION',
      p_seq=> j1.seq_id,p_attr_number =>4,p_attr_value=>wwv_flow.g_f04(j));
  --VAL4 (Date)
  apex_collection.update_member_attribute (p_collection_name=> 'MY_COLLECTION',
      p_seq=> j1.seq_id,p_attr_number =>5,p_attr_value=>wwv_flow.g_f05(j));
end loop;
end;Clear as mud? Walk through it slowly. The syntax tells APEX which Collection (p_collection_name), then which row (p_seq), then which column/attribute (p_attr_number) to update with which value (wwv_flow.g_f0X(j)). The attribute number is the column number from the collection without the "c" in front (ie c004 in the collection = attribute 4).
The last one is your procedure to write the changes to the Database. This one should be a procedure that fires AFTER COMPUTATIONS AND VALIDATIONS. It uses that hidden KEY value to determine whether the row exists and needs to be updated, or new and needs to be inserted.
declare
begin
  --Get records from Collection
  for y in (select TO_NUMBER(c001) x_key, TO_NUMBER(c002) x_1,
             TO_NUMBER(c003) x_2,
             c004 x_3,
             TO_DATE(c005,'MMDDYYYY') x_dt
           FROM APEX_COLLECTIONS
           WHERE COLLECTION_NAME = 'MY_COLLECTION') loop
    if y.x_key = 0 then  --New record
        insert into MY_TABLE (KEY_ID, COL1,
            COL2, COL3, COL4, COL5)
          values (SEQ_MY_TABLE.nextval, y.x_1,
              y.x_2, y.x_3, y.x_4, y.x_dt);
    elsif y.x_key > 0 then  --Existing record
        update MY_TABLE set COL1=y.x_1, COL2=y.x_2,
             COL3=y.x_3, COL4=y.x_4, COL5=y.x_dt
         where KEY_ID = y.x_key;
    else
      --THROW ERROR CONDITION
    end if;
  end loop;
end;Now I usually include something to distinguish the empty new rows from the full new rows, but for simplicity I'm not including it here.
Anyway, this works very well and allows me complete control over what I display on the screen and where all the data goes. I suggest using the APEX forms where you can, but for complex situations, this works nicely. Let me know if you need further clarifications.