Unable to implement Forall in a procedure

Question

Hi,
I have been unsuccessful in inserting data into a target table with resultset from a multiple tables as below.
I'm using Oracle Database 10g Enterprise Edition Release 10.2.0.1.0 - 64bit
I'm not sure if the below implementation is possible, Please advice on the error that I'm getting as below
Compilation errors for PROCEDURE PDR.PROC_COMPOSITE_DATA_LOAD
Compilation errors for PROCEDURE PDR.PROC_COMPOSITE_DATA_LOAD
Error: PL/SQL: ORA-00947: not enough values
Line: 37
Text: ) VALUES v1_pershing_staging(i);
Error: PL/SQL: SQL Statement ignored
Line: 29
Text: INSERT INTO PRD_DET_MON_LD(
create or replace procedure PROC_COMPOSITE_DATA_LOAD is
cursor CUR_pershing_staging is
select PRD_MST.PRD_ID,
       PRD_MST.Feed_Cur_Id,
       prd_stg.effective_date,
       '10000' as SRC_id,
       prd_stg.accts,
       prd_stg.return_type,
       prd_stg.mon_return
   from PRD_PERSHING_STAGING_LOAD PRD_STG, lv_mst, PRD_MST
   where PRD_STG.src ='PERSHING'
   and PRD_STG.Src_Provided_Id = lv_mst.geo_manager_code
   and lv_mst.lv_id = PRD_MST.lv_id
   and prd_mst.end_date > sysdate
   and lv_mst.end_date > sysdate;
TYPE t_pershing_staging IS TABLE OF CUR_pershing_staging%ROWTYPE
INDEX by PLS_INTEGER;
v1_pershing_staging t_pershing_staging;
BEGIN
  OPEN CUR_pershing_staging;
  LOOP
    FETCH CUR_pershing_staging BULK COLLECT INTO v1_pershing_staging LIMIT 1000;
    FORALL i IN 1..v1_pershing_staging.COUNT
    INSERT INTO PRD_DET_MON_LD(
        PRD_ID,
                    CUR_ID,
                    EFFECTIVE_DATE,
                    SRC_ID,
                    UNIT_VALUE,
                    RETURN_TYPE,
                    RETURN_VALUE
        ) VALUES v1_pershing_staging(i);
    EXIT WHEN v1_pershing_staging%NOTFOUND;
  END LOOP;
  CLOSE CUR_pershing_staging;
  COMMIT;
END PROC_COMPOSITE_DATA_LOAD;Thanks!
Edited by: Harinath Arasu on Aug 10, 2011 11:51 PM

Answer 1

Test data
SQL> select * from v$version where rownum < 2
  2  /
BANNER
Oracle Database 10g Enterprise Edition Release 10.2.0.3.0 - 64bi
SQL> create table emp
  2  (
  3    eno integer,
  4    ename varchar2(10)
  5  )
  6  /
Table created.
SQL> create table emp_target
  2  (
  3    eno integer,
  4    ename varchar2(10)
  5  )
  6  /
Table created.
SQL> insert into emp
  2  select level, 'A'||level
  3    from dual
  4  connect by level <= 1000
  5  /
1000 rows created.
SQL> commit
  2  /
Commit complete.In the version of oracle you are in referring a record type in FORALL is restricted.
Here is an example
SQL> declare
  2     cursor c is select * from emp;
  3     type tbl is table of c%rowtype index by pls_integer;
  4     emp_tbl tbl;
  5  begin
  6     open c;
  7     loop
  8             fetch c bulk collect into emp_tbl limit 100;
  9             exit when c%notfound;
10
11             forall i in 1..emp_tbl.count
12                     insert into emp_target ( eno, ename )
13                     values (emp_tbl(i).eno, emp_tbl(i).ename);
14     end loop;
15  end;
16  /
                        values (emp_tbl(i).eno, emp_tbl(i).ename);
ERROR at line 13:
ORA-06550: line 13, column 12:
PLS-00436: implementation restriction: cannot reference fields of BULK In-BIND
table of records
ORA-06550: line 13, column 12:
PLS-00382: expression is of wrong type
ORA-06550: line 13, column 28:
PLS-00436: implementation restriction: cannot reference fields of BULK In-BIND
table of records
ORA-06550: line 13, column 28:
PLS-00382: expression is of wrong type
ORA-06550: line 13, column 12:
PL/SQL: ORA-22806: not an object or REF
ORA-06550: line 12, column 4:
PL/SQL: SQL Statement ignoredSo you need to do it like this. Declare individual Table Type for each column of the cursor and use it.
SQL> declare
  2     cursor c is select * from emp;
  3     type eno_tbl is table of emp.eno%type index by pls_integer;
  4     type ename_tbl is table of emp.ename%type index by pls_integer;
  5     leno eno_tbl;
  6     lename ename_tbl;
  7  begin
  8     open c;
  9     loop
10             fetch c bulk collect into leno, lename limit 100;
11             exit when c%notfound;
12
13             forall i in 1..leno.count
14                     insert into emp_target ( eno, ename )
15                     values (leno(i), lename(i));
16     end loop;
17  end;
18  /
PL/SQL procedure successfully completed.
SQL> select count(*) from emp_target
  2  /
  COUNT(*)
      1000