Understanding Rowcount

Question

I want to write a store procedure that will insert data into a table, it will automatically increment a ID number.
The first test is to check if the table is empty if it is the first ID is set to 100.
The problem is testing that no rows are returned.
In the following code even though the table is empty rowcount returns 1.
here is my code:
CREATE OR REPLACE procedure INSERTINTOEMPLOYEE(empName IN varchar2, rt IN NUMBER)
IS
BEGIN
     DECLARE
     emID NUMBER;
     cursor empcursor IS select max(EMPID)from RedKiteEMPLOYEE;
     BEGIN
     OPEN empcursor;
FETCH empcursor INTO emID;
          dbms_output.put_line('empcursor%ROWCOUNT '|| empcursor%ROWCOUNT);
          IF empcursor%ROWCOUNT= 0 THEN
               dbms_output.put_line('0 rows returned');
               INSERT INTO RedKiteEMPLOYEE values (100,empName,rt);
     ELSE
     dbms_output.put_line('1 row returned');
               emID := emID+1;
               INSERT INTO RedKiteEMPLOYEE values (emID,empName,rt);
     END IF;
     END;
END;
Thanks for any help I though rowcount returns 0 if no rows are returned.
Tony

Answer 1

You are doing things the hard way. The traditional method is to create a sequence then create a trigger that automatically inserts the next value of that sequence. You can then insert using a simple insert statement from SQL*Plus or using a simple procedure that does the insert. Please see the example below.
scott@ORA92> -- table:
scott@ORA92> CREATE TABLE RedKiteEmployee
  2    (empid     NUMBER,
  3       empname VARCHAR2(15),
  4       rt     NUMBER)
  5  /
Table created.
scott@ORA92> -- sequence starting with 100:
scott@ORA92> CREATE SEQUENCE RedKiteEmployee_empid_seq
  2  START WITH 100
  3  /
Sequence created.
scott@ORA92> -- trigger:
scott@ORA92> CREATE OR REPLACE TRIGGER RedKiteEmployee_empid_trigger
  2    BEFORE INSERT ON RedKiteEmployee
  3    FOR EACH ROW
  4  BEGIN
  5    SELECT RedKiteEmployee_empid_seq.NEXTVAL
  6    INTO   :NEW.empid
  7    FROM   DUAL;
  8  END RedKiteEmployee_empid_trigger;
  9  /
Trigger created.
scott@ORA92> SHOW ERRORS
No errors.
scott@ORA92> -- procedure:
scott@ORA92> CREATE OR REPLACE procedure InsertIntoEmployee
  2    (p_empName IN RedKiteEmployee.empName%TYPE,
  3       p_rt       IN RedKiteEmployee.rt%TYPE)
  4  IS
  5  BEGIN
  6    INSERT INTO RedKiteEmployee (empname, rt)
  7    VALUES (p_empName, p_rt);
  8  END InsertIntoEmployee;
  9  /
Procedure created.
scott@ORA92> SHOW ERRORS
No errors.
scott@ORA92> -- insert with procedure:
scott@ORA92> EXECUTE InsertIntoEmployee ('Tony', 1)
PL/SQL procedure successfully completed.
scott@ORA92> -- insert without procedure:
scott@ORA92> INSERT INTO RedKiteEmployee (empname, rt) VALUES ('Barbara', 2)
  2  /
1 row created.
scott@ORA92> -- results:
scott@ORA92> SELECT * FROM RedKiteEmployee
  2  /
     EMPID EMPNAME                 RT
       100 Tony                     1
       101 Barbara                  2