Using a Variable for Table Name with a cursor

Question

Hello All
Is it possible to use a Parameter passed to a procedure as the table name
in a cursor selection statment. I thought the below would work but I get
a error. Does anyone have any ideas?? The Error is listed below to.
Here's the code I just complied
CREATE OR REPLACE PROCEDURE Dup_Add(NEWQATABLE IN VARCHAR2) IS
CURSOR c1 IS SELECT MUNI,PROV FROM NEWQATABLE GROUP BY MUNI, PROV;
c1rec c1%ROWTYPE;
BEGIN
OPEN c1;
LOOP
FETCH c1 INTO c1rec;
EXIT WHEN c1%NOTFOUND;
DBMS_OUTPUT.PUT_LINE(c1rec.MUNI);
END LOOP;
CLOSE c1;
END;
Here is the errors
LINE/COL ERROR
3/8 PLS-00341: declaration of cursor 'C1' is incomplete or malformed
3/15 PL/SQL: SQL Statement ignored
3/38 PLS-00201: identifier 'NEWQATABLE' must be declared
5/7 PL/SQL: Item ignored
10/3 PL/SQL: SQL Statement ignored
10/17 PLS-00320: the declaration of the type of this expression is
incomplete or malformed
12/3 PL/SQL: Statement ignored
12/24 PLS-00320: the declaration of the type of this expression is
incomplete or malformed
LINE/COL ERROR
Thanks
Peter

Answer 1

If you are going to have a table name or a column name as a parameter, then you have to open the cursor dynamically. The following example uses Native Dynamic SQL (NDS) to open a ref cursor dynamically. I also eliminated the group by clause, since it is intended for use with aggregate functions and you weren't using an aggregate function. Also notice that there are some other differences in terms of defining variables and fetching and so forth.
SQL> CREATE TABLE test_table
  2  AS
  3  SELECT deptno AS muni,
  4         dname  AS prov
  5  FROM   dept
  6  /
Table created.
SQL> CREATE OR REPLACE PROCEDURE Dup_Add
  2    (newqatable IN VARCHAR2)
  3  IS
  4    TYPE cursor_type IS REF CURSOR;
  5    c1 cursor_type;
  6    c1muni NUMBER;
  7    c1prov VARCHAR2 (20);
  8  BEGIN
  9    OPEN c1 FOR 'SELECT muni, prov FROM ' || newqatable;
10    LOOP
11      FETCH c1 INTO c1muni, c1prov;
12      EXIT WHEN c1%NOTFOUND;
13      DBMS_OUTPUT.PUT_LINE (c1muni || ' ' || c1prov);
14    END LOOP;
15    CLOSE c1;
16  END;
17  /
Procedure created.
SQL> SHOW ERRORS
No errors.
SQL> SET SERVEROUTPUT ON
SQL> EXECUTE dup_add ('test_table')
10 ACCOUNTING
20 RESEARCH
30 SALES
40 OPERATIONS
PL/SQL procedure successfully completed.