Using an applescript in a cocoa-applescript application

Question

Hello,
I have an applescript I am trying to use in a project. I have everything set up so when you click a button it runs this:
repeat
set statusOld to checkStatus()
set statusNew to checkStatus()
repeat while statusOld is equal to statusNew
delay 1
set statusNew to checkStatus()
end repeat
if statusNew is true then
display dialog "Device Added - put some real code here"
else
display dialog "Device Removed - put some real code here"
end if
end repeat
on checkStatus()
set myString to do shell script "system_profiler SPBluetoothDataType"
if myString does not contain "DR-BT101" then
return false
else
set AppleScript's text item delimiters to "name:"
set myList to the text items of myString
set numberOfDevices to count of myList
set counter to 1
repeat numberOfDevices times
if item counter of myList contains "DR-BT101" then
if item counter of myList contains "Connected: Yes" then
return true
else if item counter of myList contains "Connected: No" then
return false
else
display dialog "Error Parsing"
end if
end if
set counter to counter + 1
end repeat
end if
end checkStatus
However, It will not run because of the "on checkStatus()" part. How would I fix this and also make it so the user can stop running the script?

Answer 1

It's pretty easy to block the user interface when converting AppleScripts that use repeat loops. For an example of the other approach that uses a repeating timer, create a new example project (named "Timer Example") with the following script. Then from *Interface Builder*, create a couple of buttons (named "Start" and "Stop") and connect the buttons to the doButtonStuff action. You can see the progress of things in the run console.
The main difference is that instead of a tight repeat loop that hogs the entire run loop, a timer is set up to check things every once in a while. Since the application is now free to do other things in between firings of the timer, your user interface stays responsive.
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #DAFFB6;
overflow: auto;"
title="this text can be pasted into Xcode 3.2.x (Snow Leopard)">
# MARK: -
# MARK: Application Properties
property thisApp : current application
property NSTimer : class "NSTimer"
property NSRunLoop : class "NSRunLoop"
script Timer_ExampleAppDelegate -- change the name to match your example project if needed
# MARK: -
# MARK: Script Properties
property parent : class "NSObject"
property myTimer : missing value -- this will be a repeating timer
property statusOld : missing value -- this will be the original status
# MARK: -
# MARK: Interface Builder Actions
on doButtonStuff_(sender)
log "doButton..."
set theButton to (sender's |title| as text)
if theButton is "Start" then
log "timer started..."
if myTimer is missing value or not myTimer's isValid() then -- check if the timer is already running
set myTimer to NSTimer's timerWithTimeInterval_target_selector_userInfo_repeats_(2, me, "doCheck", missing value, true) -- create
NSRunLoop's mainRunLoop()'s addTimer_forMode_(myTimer, thisApp's NSDefaultRunLoopMode) -- start the timer
end if
else if theButton is "Stop" then
log "timer stopped..."
myTimer's invalidate() -- stop the timer
end if
end doButtonStuff_
# MARK: -
# MARK: Script Handlers
on doCheck()
script check
on checkStatus()
log "checkStatus..."
set myString to (do shell script "system_profiler SPBluetoothDataType")
if myString does not contain "DR-BT101" then return false
set tempTID to AppleScript's text item delimiters -- save existing delimiters
set AppleScript's text item delimiters to "name:"
set myList to the text items of myString
set AppleScript's text item delimiters to tempTID -- restore delimiters
repeat with anItem in myList
set anItem to contents of anItem -- dereference list item
if anItem contains "DR-BT101" then
if anItem contains "Connected: Yes" then
return true
else if anItem contains "Connected: No" then
return false
end if
end if
end repeat
display dialog "Error Parsing" -- oops
end checkStatus
end script
repeat
if statusOld is missing value then set statusOld to check's checkStatus()
set statusNew to check's checkStatus()
if statusNew is equal to statusOld then return -- no change
if statusNew is true then
-- myTimer's invalidate() -- stop the timer
display dialog "Device Added - put some real code here"
else
-- myTimer's invalidate() -- stop the timer
display dialog "Device Removed - put some real code here"
end if
end repeat
end doCheck
end script</pre>