Using Tabstrip on Report Selektion

Question

Hi,
I'm using a Tabstrip for a report selection this works fine. Now I would like to make a tab invisible depending on an entry of an other entry field on the screen (this field is not on any tab)
Any hints ?
Message was edited by: Olaf Bethke

Answer 1

Sure,  check this sample code......
report zrich_0001
       no standard page heading.
selection-screen begin of screen 101 as subscreen.
selection-screen begin of block b1 with frame title text-001.
parameters: P_rad1 radiobutton group grp1 default 'X'
                                         user-command check,
            p_rad2 radiobutton group grp1.
selection-screen end of block b1.
selection-screen end of screen 101.
selection-screen begin of screen 102 as subscreen.
selection-screen begin of block b2 with frame title text-002.
parameters: p_char1 type c.
selection-screen end of block b2.
selection-screen end of screen 102.
selection-screen begin of screen 103 as subscreen.
selection-screen begin of block b3 with frame title text-003.
parameters: p_char2 type c.
selection-screen end of block b3.
selection-screen end of screen 103.
selection-screen begin of tabbed block one for 20 lines.
selection-screen tab (15) name1 user-command ucomm1
default screen 101.
selection-screen tab (17) name2 user-command ucomm2
default screen 102.
selection-screen tab (17) name3 user-command ucomm3
default screen 103.
selection-screen end of block one.
initialization.
  name1 = 'Tab 1'.
  name2 = 'Tab 2'.
  name3 = 'Tab 3'.
at selection-screen output.
  loop at screen.
    if p_rad2 = 'X'.
      if screen-name = 'NAME3'.
        screen-invisible = '1'.
        modify screen.
      endif.
    endif.
  endloop.
start-of-selection.
Regards,
Rich Heilman