Variable to use as list of numbers for "in" clause

Question

Hello.
I am writing a proc that needs to dequeue an unknown number of messages from an advanced queue, and then query a standard table, returning a cursor. I have coded most of it, but I run into trouble when there is more than one message to be dequeued (which is the most likely scenario). Here is the code as it stands:
CREATE OR REPLACE PROCEDURE prc_get_actv_updts_ac(vConsumerName IN VARCHAR2,
vQueueName IN VARCHAR2,
vMaxIdCount IN INTEGER,
v_retrc OUT SYS_REFCURSOR) IS
obj consolidated_updt_msg_t;
deq_msgid RAW(16);
queueopts dbms_aq.dequeue_options_t;
msgprops dbms_aq.message_properties_t;
vIdList VARCHAR2(32767);
vIdCount INTEGER;
-- As we are dequeuing with the wait flag set to no_wait, an exception
-- will be thrown when there are no messages to dequeue. This will be used to
-- exit the loop (see below)
no_messages EXCEPTION;
PRAGMA EXCEPTION_INIT(no_messages, -25228);
BEGIN
queueopts.consumer_name := vConsumerName;
queueopts.dequeue_mode := dbms_aq.remove;
queueopts.navigation := dbms_aq.next_message;
queueopts.wait := dbms_aq.no_wait;
queueopts.visibility := dbms_aq.immediate;
vIdCount := 0;
-- Loop through the contents of the queue
WHILE vIdCount <= vMaxIdCount LOOP
dbms_aq.dequeue(queue_name => vQueueName,
dequeue_options => queueopts,
message_properties => msgprops,
payload => obj,
msgid => deq_msgid);
vIdCount := vIdCount + 1;
IF (vIdCount = 1) THEN
vIdList := obj.id;
ELSE
vIdList := vIdList || ',' || obj.id;
END IF;
END LOOP;
-- This will be thrown when there are no messages left to dequeue
EXCEPTION
WHEN no_messages THEN
-- Do nothing
NULL;
COMMIT;
DBMS_OUTPUT.put_line('vIdList: ' || vIdList);
OPEN v_retrc FOR
SELECT * FROM t_table t WHERE t.id IN (vIdList);
END prc_get_actv_updts_ac;
You may be wondering why we are trying to do this in the first place. It's a long story, but the plan was to have a c++ app dequeue messages from the queue, but the developer of that piece has run into issues, and because we are under time pressure, we decided to write this proc instead (he knows he can call procs and pull results out of cursors without difficulty). As I said, it works fine when there is only one row to dequeue, but once we have more than one, I get an error during the select statement saying vIdList is an invalid number (and example value of vIdList when I get that error is "6977418,12290358" (without the quotes!)).
Any thoughts?!

Answer 1

Hi OP,
There was another thread about splitting comma-separated numbers lately where a pipelined function solution looked pretty good (well I thought so anyway :) ). I applied a similar approach to your problem, but I obviously couldn't test it (except I tested a similar subselect for the syntax). It means a small re-design whereby the client uses this static select, with binds set appropriately:
SELECT *
  FROM t_table t
WHERE t.id IN (
SELECT COLUMN_VALUE
  FROM TABLE (prc_get_actv_updts_ac (?, ?, ?))
);and the pipelined function looks like this:
CREATE OR REPLACE FUNCTION prc_get_actv_updts_ac (
        vConsumerName       VARCHAR2,
        vQueueName          VARCHAR2,
        vMaxIdCount         INTEGER) RETURN SYS.OdciNumberList PIPELINED IS
  obj           consolidated_updt_msg_t;
  deq_msgid     RAW(16);
  queueopts     DBMS_AQ.dequeue_options_t;
  msgprops      DBMS_AQ.message_properties_t;
  no_messages   EXCEPTION;
  PRAGMA        EXCEPTION_INIT (no_messages, -25228);
BEGIN
  queueopts.consumer_name := vConsumerName;
  queueopts.dequeue_mode := DBMS_AQ.remove;
  queueopts.navigation := DBMS_AQ.next_message;
  queueopts.wait := DBMS_AQ.no_wait;
  queueopts.visibility := DBMS_AQ.immediate;
-- Loop through the contents of the queue
  FOR i IN 1..vMaxIdCount LOOP
    DBMS_AQ.Dequeue(
        queue_name          => vQueueName,
        dequeue_options     => queueopts,
        message_properties  => msgprops,
        payload             => obj,
        msgid               => deq_msgid);
    PIPE ROW (obj.id);
  END LOOP;
EXCEPTION
  WHEN no_messages THEN NULL;
END prc_get_actv_updts_ac;
/Edited by: BrendanP on 23-Nov-2011 11:36
I did actually test a similar subselect but I used positional parameter-passing there - as you have to in SQL, so updated to do same here.