Want to read a Query list of results into a defined variable "as Collection" for later use (ie create reports)

Question

The following code works great (Functions Main and OpenThisFile ) to select files from a folder and read into defined variable "FileToProcess As Collection" (I guess then renamed fil) and use that list of files to run through
an import process defined in a function "StartMe". 
What I want to do is read the results of a query into a similar collection variable and then use in a function like "StartMe" to run a series of reports.  The functions to do that below (PrintCKListTables and ReadQueryOfSDGs) currently
don't work erring out "For Each s In .selectedQuery".  I would appreciate any help guiding me how to fix function
      ReadQueryOfSDGs() As Collection
Thank you very much in advance for your help!
Public Function Main()
Dim FilesToProcess As Collection, fil
Dim initialFilePath As String
initialFilePath = CreateObject("WScript.Shell").specialfolders("C:\temp")
Set FilesToProcess = OpenThisFile(initialFilePath)
For Each fil In FilesToProcess
StartMe fil
Next fil
End Function
Public Function OpenThisFile(initialFilePath As String) As Collection
'Requires reference to Microsoft Office 12.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
'Clear listbox contents.
'Me.FileList.RowSource = ""
'Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
'Allow user to make multiple selections in dialog box.
.AllowMultiSelect = True
.InitialFileName = initialFilePath
'Set the title of the dialog box.
.Title = "Please select one or more files"
'Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "XML Files", "*.XML"
'Show the dialog box. If the .Show method returns True, the
'user picked at least one file. If the .Show method returns
'False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to the list box.
Dim s
Set OpenThisFile = New Collection
For Each s In .SelectedItems
OpenThisFile.Add s
Next s
Else
MsgBox "You clicked Cancel in the file dialog box."
NotContinue = True
End If
End With
End Function
Public Function PrintCkListTables()
    Dim FilesToProcess As Collection, fil
    Dim ListSDGs As String
    Set FilesToProcess = ReadQueryOfSDGs(ListSDGs)
    For Each fil In FilesToProcess
        fNameExportpdfReport (fil)
    Next fil
End FunctionPublic Function ReadQueryOfSDGs() As Collection       DoCmd.OpenQuery "y_qs_DataIn_All_SDGList"
       Dim s
       Set ReadQueryOfSDGs = New Collection
       For Each s In .selectedQuery
       ReadQueryOfSDGs.Add s
       Next s
End Function

Answer 1

There are a few problems here. In function PrintCkListTables() you define a string variable ListSDGs and then use that as an argument to the function ReadQueryOfSDGs(), but ReadQueryOfSDGs() as written does not accept any arguments.  It's also not clear
what ListSDGs represents...a list of files, names of queries? Also, the line
For Each s In .selectedQuery in
ReadQueryOfSDGs()
references something called .selectedQuery which is undefined. 
Is it that you want ReadQueryOfSDGs() to loop through the records returned by a query and add a field from each record to a collection?  If so, something like the following might better serve you:
Public Function ReadQueryOfSDGs() As Collection
    Dim C As New Collection
    Dim rst As DAO.Recordset
    Set rst = DBEngine(0)(0).OpenRecordset("y_qs_DataIn_All_SDGList", dbOpenForwardOnly, dbReadOnly)
    Do Until rst.EOF
        C.Add rst!MyField ' where MyField is the field in y_qs_DataIn_All_SDGList you want to add to your collection
        rst.MoveNext
    Loop
    rst.Close
    Set rst = Nothing
    Set ReadQueryOfSDGs = C
End Function