Want to upload file using shell

Question

Hello I'm making a dialog box with 2 tasks : 1 is download / second is upload.
The download part (first button) works but I need help with the upload part because the shell is downloading. The downloads_Folder is to much at the upload part... (set downloads_Folder to quoted form of POSIX path of "Users:X:Desktop:PRINT" too)
Can I get some help on this please. Thanks in advance.
Here is my code:
display dialog "DO MY THING" buttons {"DOWNLOAD", "UPLOAD", "Cancel"} cancel button "Cancel"
--First button reply and then action
if button returned of result is "DOWNLOAD" then
display dialog ("START DOWNLOAD") buttons {"OK", "Cancel"} cancel button "Cancel"
set user_name to "XXX"
set pass_word to "XXX"
set domain_Name to "XXX"
set downloads_Folder to quoted form of POSIX path of "Users:X:Desktop:PRINT"
do shell script ("mkdir -p " & downloads_Folder & "; cd " & downloads_Folder & "; /usr/bin/ncftpget -R ftp://" & user_name & ":" & pass_word & "@" & domain_Name)
display dialog ("Downloaden is ready") buttons {"DID DONE"} cancel button "DID DONE"
else
--2 button reply and then action from here need help
if button returned of result is "UPLOAD" then
display dialog ("START UPLOAD") buttons {"OK", "Cancel"} cancel button "Cancel"
tell application "Finder" to choose file
set user_name to "xxx"
set pass_word to "xxx"
set domain_Name to "xxx"
set downloads_Folder to quoted form of POSIX path of "Users:X:Desktop:PRINT"
do shell script ("mkdir -p " & downloads_Folder & "; cd " & downloads_Folder & "; /usr/bin/ncftpget -R ftp://" & user_name & ":" & pass_word & "@" & domain_Name)
display dialog ("UPLOAD FINISHED") buttons {"DID DONE"} cancel button "DID DONE"
end if
end if
Message was edited by: Colin @ mac.com

Answer 1

property dFolder : "~/Desktop/downloads_Folder" -- Full path of 'downloads_Folder' folder.
property user_name : "xxx"
property pass_word : "xxx"
property domain_Name : "xxx"
property remote_dir : "/" -- Directory of remote site, to place uploaded file(s) to.
set tResult to button returned of (display dialog "Receive / Send files" buttons {"Download", "Upload", "Cancel"} cancel button 3 default button 1)
-- First button reply and then action
if (tResult is equal to "Download") then
display dialog ("Start download") buttons {"Cancel", "OK"} default button 2
with timeout of 0 seconds -- Extends AppleScripts' timeout period indefinitly.
do shell script ("mkdir -p " & dFolder & "; cd " & dFolder & "; /usr/bin/ncftpget -R ftp://" & user_name & ":" & pass_word & "@" & domain_Name)
end timeout
display dialog ("Download completed") buttons {"OK"} default button 1
-- Second button reply and then action
else if (tResult is equal to "Upload") then
display dialog ("Start upload") buttons {"Cancel", "OK"} default button 2
set tFiles to choose file with multiple selections allowed without invisibles -- See 'StandardAdditions.osax' library dictionary.
set {fName, fCount} to {"", count tFiles}
repeat with i from 1 to fCount
tell application "Finder" to set fName to fName & (quoted form of POSIX path of ((item i of tFiles) as string))
if (i < fCount) then set fName to fName & " "
end repeat
with timeout of 0 seconds -- Extends AppleScripts' timeout period indefinitly.
do shell script ("/usr/bin/ncftpput -R -u " & user_name & " -p " & pass_word & " " & domain_Name & " " & remote_dir & " " & fName)
end timeout
display dialog ("Upload completed") buttons {"OK"} default button 1
end if