WD4A : Displaying images in ALV table

Question

Hi,
Does anyone know how to display images in ALV tables in Webdynpro?

Answer 1

Hello,
You can define an attribute in the context with the type CHAR 30 and define it value like an icon from WDA (like ~Icon/GreenLed). And then you need to create an method to define the attributes of the column that will have the image like follows:
METHOD display_alv .
  DATA: lr_alv_usage       TYPE REF TO   if_wd_component_usage,
        lr_config          TYPE REF TO   cl_salv_wd_config_table,
        lr_col_header      TYPE REF TO   cl_salv_wd_column_header,
        lr_function_wd     TYPE REF TO   cl_salv_wd_function,
        lr_button          TYPE REF TO   cl_salv_wd_fe_button,
        lr_image           TYPE REF TO   cl_salv_wd_uie_image,
        lr_header          TYPE REF TO   cl_salv_wd_header,
        lr_uie_link        TYPE REF TO   cl_salv_wd_uie_link_to_action,
        lr_if_controller   TYPE REF TO   iwci_salv_wd_table,
        lr_function_set    TYPE REF TO   if_salv_wd_function_settings,
        lr_table_settings  TYPE REF TO   if_salv_wd_table_settings,
        lr_column_settings TYPE REF TO   if_salv_wd_column_settings.
  DATA: lt_columns         TYPE          salv_wd_t_column_ref,
        ls_column          TYPE          salv_wd_s_column_ref,
        lv_text            TYPE          string.
* Instantiate ALV Component
  lr_alv_usage = wd_this->wd_cpuse_all_alv( ).
  IF lr_alv_usage->has_active_component( ) IS INITIAL.
    lr_alv_usage->create_component( ).
  ENDIF.
* get reference to model
  lr_if_controller = wd_this->wd_cpifc_all_alv( ).
  lr_config        = lr_if_controller->get_model( ).
* modify visible rows
  lr_config->if_salv_wd_table_settings~set_visible_row_count( iv_rows ).
  lr_config->if_salv_wd_table_settings~set_selection_mode(
                                       wd_assist->co_alv_selmode ).
* create function
  lr_function_set ?= lr_config.
  lr_function_wd = lr_function_set->create_function(
                   wd_assist->co_func_det_nfe ).
  CREATE OBJECT lr_button.
*read text
  lv_text = wd_assist->read_text( iv_key = '002' ).
  lr_button->set_text( lv_text ).
  lv_text = wd_assist->read_text( iv_key = '001' ).
  lr_button->set_tooltip( lv_text ).
  lr_button->set_image_source( wd_assist->co_icon_seldet ).
  lr_function_wd->set_editor( lr_button ).
* set table header
  lr_table_settings ?= lr_config.
  lr_header = lr_table_settings->get_header( ).
  lv_text = wd_assist->read_text( iv_key = '003' ).
  lr_header->set_text( lv_text ).
  lv_text = wd_assist->read_text( iv_key = '004' ).
  lr_header->set_tooltip( lv_text ).
  lr_header->set_image_source( wd_assist->co_icon_list ).
  lr_column_settings ?= lr_config.
  lt_columns = lr_column_settings->get_columns( ).
  LOOP AT lt_columns INTO ls_column.
    CASE ls_column-id.
      WHEN 'ICON'.
        CREATE OBJECT lr_image.
        lr_image->set_source_fieldname( ls_column-id ).
        lr_image->set_tooltip_fieldname( 'ICON_TOOLTIP' ).
        ls_column-r_column->set_cell_editor( lr_image ).
      WHEN 'ID'.
        CREATE OBJECT lr_uie_link.
        lr_uie_link->set_text_fieldname( ls_column-id ).
        ls_column-r_column->set_cell_editor( lr_uie_link ).
      WHEN 'ICON_TOOLTIP' or 'LOGSYS'.
        ls_column-r_column->set_visible(
                           cl_wd_uielement=>e_visible-none ).
    ENDCASE.
*set header binding of medium description, otherwise title
    lr_col_header = ls_column-r_column->get_header( ).
    lr_col_header->set_ddic_binding_field(
                        if_salv_wd_c_column_settings=>ddic_bind_medium ).
  ENDLOOP.
ENDMETHOD.
Here will be showed an icon (column ICON) and an link (column ID).
Regards,