Webcam Capture Picture Tool

Question

I want to write a program in VB 2010 that can capture photo using a webcam, and directly saves it to the database. Someone please help me. Thanks! 

Answer 1

Hi,
 Here is a small code a made a while back that uses the capCreateCaptureWindowA API to capture a webcam and save pictures when the Save Picture button is clicked. You can test it out by creating a new form project and adding 2 buttons and 1 picturebox.
Name one of the buttons (Button_SavePicture) and the other (Button_SetSizeColor). The picturebox i left as the default name (PictureBox1). In the Button_SavePicture click event you will want to change the path to where the images are saved or you will get
an error there. As far as saving it to a database i will have to leave that up to someone that knows about using them. There is also this LINK
where there is a few links to other ways using DirectShow and maybe more.
Imports System.Runtime.InteropServices
Public Class Form1
Dim cWnd As IntPtr = IntPtr.Zero
Dim devId As Integer = 0 '0 will be the first capture device found
Dim picnumber As Integer = 0
Dim tmppic As String = System.IO.Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.ApplicationData), "Temp.dib")
Private Const WS_CHILD As Integer = &H40000000
Private Const WS_VISIBLE As Integer = &H10000000
Private Const WM_USER As Integer = &H400
Private Const WM_CAP_DRIVER_CONNECT As Integer = WM_USER + 10
Private Const WM_CAP_DRIVER_DISCONNECT As Integer = WM_USER + 11
Private Const WM_CAP_SET_PREVIEW As Integer = WM_USER + 50
Private Const WM_CAP_SET_PREVIEWRATE As Integer = WM_USER + 52
Private Const WM_CAP_SET_SCALE As Integer = WM_USER + 53
Private Const WM_CAP_SAVEDIB As Integer = WM_USER + 25
Private Const WM_CAP_DLG_VIDEOFORMAT As Integer = WM_USER + 41
<DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Ansi)> Private Shared Function SendMessage(ByVal hWnd As IntPtr, ByVal Msg As Integer, ByVal wParam As Integer, ByVal lParam As String) As IntPtr
End Function
<DllImport("avicap32.dll", SetLastError:=True, CharSet:=CharSet.Auto)> Private Shared Function capCreateCaptureWindowA(ByVal lpszWindowName As String, ByVal dwStyle As Integer, ByVal x As Integer, ByVal y As Integer, ByVal nWidth As Integer, ByVal nHeight As Integer, ByVal hWndParent As IntPtr, ByVal nID As Integer) As IntPtr
End Function
<DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Unicode)> Private Shared Function DestroyWindow(ByVal hwnd As IntPtr) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
If Not cWnd.Equals(IntPtr.Zero) Then
SendMessage(cWnd, WM_CAP_DRIVER_DISCONNECT, devId, Nothing)
DestroyWindow(cWnd)
End If
If System.IO.File.Exists(tmppic) Then System.IO.File.Delete(tmppic)
End Sub
Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
cWnd = capCreateCaptureWindowA(devId.ToString, WS_VISIBLE Or WS_CHILD, 0, 0, PictureBox1.Width, PictureBox1.Height, PictureBox1.Handle, 0)
If Not SendMessage(cWnd, WM_CAP_DRIVER_CONNECT, devId, Nothing) = IntPtr.Zero Then
SendMessage(cWnd, WM_CAP_SET_SCALE, 1, Nothing)
SendMessage(cWnd, WM_CAP_SET_PREVIEWRATE, 66, Nothing)
SendMessage(cWnd, WM_CAP_SET_PREVIEW, 1, Nothing)
Else
MessageBox.Show("Error connecting to capture device. Make sure your WebCam is connected and try again.")
cWnd = IntPtr.Zero
Me.Close()
End If
End Sub
Private Sub Button_SavePicture_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button_SavePicture.Click
SendMessage(cWnd, WM_CAP_SAVEDIB, 0, tmppic)
Dim bmp As New Bitmap(tmppic)
Dim saveas As String = "C:\TestFolder\MyPic_" & picnumber.ToString & ".jpg"
picnumber += 1
bmp.Save(saveas, Imaging.ImageFormat.Jpeg)
bmp.Dispose()
End Sub
Private Sub Button_SetSizeColor_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button_SetSizeColor.Click
'Shows a dialog window to choose the size and color depth of the image that the webcam is capable of using.
SendMessage(cWnd, WM_CAP_DLG_VIDEOFORMAT, 0, Nothing)
End Sub
End Class