WebUtil: Excel-process remains open

Question

Win-XP, Web-Util, iAS 9.0.2 (Windows XP)
Hello,
If I use WebUtil and OLE2 to access Excel, everything works fine - accept for the poor performance (!). But at the end, an "Excel" process (as can be seen in the task manager) remains open, although I used
CLIENT_OLE2.RELEASE_OBJ(application).
Everytime, I invoke
CLIENT_OLE2.CREATE_OBJ('Excel.Application')
a new Excel-process is started, but never stopped.
Does anybody have a idea to avoid this problem? Thank you for any answer!

Answer 1

I just tried the following example onw Win 2000 using word and this works ok (cleaning up the process).
DECLARE
app CLIENT_OLE2.OBJ_TYPE;
docs CLIENT_OLE2.OBJ_TYPE;
doc CLIENT_OLE2.OBJ_TYPE;
selection CLIENT_OLE2.OBJ_TYPE;
args CLIENT_OLE2.LIST_TYPE;
fname VARCHAR2(200) := 'c:\temp\example.doc';
BEGIN
-- set the filename
     IF :OLE_ASK_FILENAME = 'true' THEN
          fname := CLIENT_GET_FILE_NAME(null,null,null,null,OPEN_FILE,TRUE);
     END IF;
-- create a new document
app := CLIENT_OLE2.CREATE_OBJ('Word.Application');
CLIENT_OLE2.SET_PROPERTY(app,'Visible',1);
docs := CLIENT_OLE2.GET_OBJ_PROPERTY(app, 'Documents');
doc := CLIENT_OLE2.INVOKE_OBJ(docs, 'add');
selection := CLIENT_OLE2.GET_OBJ_PROPERTY(app, 'Selection');
-- insert data into new document from long item
CLIENT_OLE2.SET_PROPERTY(selection, 'Text', :long_item);
-- save document as example.doc
args := CLIENT_OLE2.CREATE_ARGLIST;
CLIENT_OLE2.ADD_ARG(args, fname);
CLIENT_OLE2.INVOKE(doc, 'SaveAs', args);
CLIENT_OLE2.DESTROY_ARGLIST(args);
-- close example.doc
args := CLIENT_OLE2.CREATE_ARGLIST;
CLIENT_OLE2.ADD_ARG(args, 0);
CLIENT_OLE2.INVOKE(doc, 'Close', args);
CLIENT_OLE2.DESTROY_ARGLIST(args);
CLIENT_OLE2.RELEASE_OBJ(selection);
CLIENT_OLE2.RELEASE_OBJ(doc);
CLIENT_OLE2.RELEASE_OBJ(docs);
-- exit MSWord
CLIENT_OLE2.INVOKE(app,'Quit');
END;
Have you actually quit the application?
Regards
Grant Ronald
Forms Product Management