What replaced the LOAD command in Visual Basic 6?

Question

VB6 died with XP. I'm trying to re-write a VB6 app in Visual Studio Community. The VB6 project used the LOAD and UNLOAD commands to create and delete copies of text boxes on the form. How do I accomplish that with the latest version of Visual Basic under
Visual Studio?
Thanks,
VBhobbist
VBHobbyist

Answer 1

Frank,
[snip]
I'm sure it can be done, but how can I learn without coming back to this forum with every little question?
[snip]
Hey, I will gladly be here for any questions.
Public Class Form1
'the new .NET manual is online now:
' - go to https://google.com
' - type 'msdn [keyword]' (i.e: 'msdn list')
' - the first result is almost what is desired
' - if not enough information is given that is what the forumns are for!
'declaring array for textbox
' also note that -1 is the size, this is desirable so that textBoxes is initialized as an empty array so that when properties such as '.length' is used an exception wont be thrown saying the array is nothing
' note that some people prefer List(Of T) T means any type -> List is one of the most useful things in .NET and HIGHLY optimized. I did not use it here because it is an entirely new concept
' to learn more about list: http://msdn.microsoft.com/en-us/library/6sh2ey19(v=vs.110).aspx
Private textBoxes(-1) As TextBox
Private Sub setupTextBoxes()
'setup the amount of textboxes you want
ReDim textBoxes(14)
'initialize an integer and loop thru the length of the array
For delta As Integer = 0 To textBoxes.Length - 1
'set current array position to a new object (note that the [TextBox class].New function will be called)
textBoxes(delta) = New TextBox()
'setup gui properties, note that as you are coding, the type will show up
' also note that when coding:
' x = New [type]
' it is similar to
' x = 0
' ^New Integer/String/Double/etc.
textBoxes(delta).Size = New Size(100, 21)
textBoxes(delta).Location = New Point(1, delta * 21)
textBoxes(delta).Visible = True
'note that all form objects that have a container can hold other form objects
' we add to the form
Me.Controls.Add(textBoxes(delta))
Next delta
End Sub
Private Sub getTextBoxStuff()
'note that all variables can be initialized uppon declaration
Dim strAllTextBoxes As String = ""
'initialize an integer and loop thru the length of the array
For delta As Integer = 0 To textBoxes.Length - 1
'note that there are new operators (+=, -=, &=, etc.)
'also, controlchars is the new way to use certain chars, and messagebox.show is the new msgbox
strAllTextBoxes &= "TextBox " & delta.ToString & " = '" & textBoxes(delta).Text & "'" & ControlChars.CrLf
'note: there are way more ways to concatenate strings now, for production you can benchmark each one for different purposes
Next delta
MessageBox.Show(strAllTextBoxes, "Form1", MessageBoxButtons.OK, MessageBoxIcon.Information)
End Sub
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load '< Note that this is how subs are linked to gui elements now with the 'Handles' keyword
'define a new button
Dim btnGather As New Button
'setup gui properties
btnGather.Size = New Size(100, 21)
btnGather.Location = New Point(110, 0)
btnGather.Text = "Click Me"
'add control to form, note that anywhere else, the button can be gathered again thru Me.Controls()
Me.Controls.Add(btnGather)
'add a handler, note that when typeing this, you can see what parameter types the handler needs
AddHandler btnGather.Click, AddressOf btnGather_Click
setupTextBoxes()
End Sub
Private Sub btnGather_Click(ByVal sender As Object, ByVal e As EventArgs)
getTextBoxStuff()
End Sub
End Class
Create a new Windows Form project and paste this, press play.
Enjoy.
EDIT:
If you post blocks of code here, I will personally convert it to .NET, although I highly recommend a creating new project when converting from VB6. If you post your entire project and it's not too big I will convert the entire thing (any complex concepts
will have to have provided comments).
If your project is not secure or personal you can copy it to your online cloud OneDrive and I can download the whole thing from there - let me know.