Where should I close my cursor when an Exception arise ??

Question

Hi all,
My program has many procedures and functions. Among them I have a main procedure where everything starts, and everything should ends.
My main procedure has also an exepction part with a when others clause to log any unexpected exception.
I have another procedure (let's call it P1), that is called from my main procedure, where i use an explicit cursor in a bulk collect. While i process all my cursor data, i call many others procedures and functions, and they might call many others also.
In P1 i also have an Exception part, where i have a When others clause (in case an unexpected execption arise in any other procedure or function) where I close my cursor and raise the exception to my main procedure.
My problem is that when an exception is raised to my main program (from P1), i lose the true error line number of the exception. I am using this function to get my error trace: dbms_utility.format_error_backtrace.
I did a test, and I commented the exception part in P1, so that all exceptions goes straighly to my main procedure, and the result it was that I could see the true error line again.
So my problem was the raise statement in the when others inside of P1.
The thing is that I need to close my cursor in case of any exception, but if I do it in the when others, I will lose the true error line number of the expection.
By the way I can’t declare my cursor variable as global, so that I can remove the exception part in P1, and close my cursor in my main procedure.
I will really apreciate your help.
(I am using Oracle Databas 11g).

Answer 1

919448 wrote:
The cursor i am using is a ref cursor, so i have to close it explicitly as per you said.
The thing is that i don't want to lose my error line number when i raise the exception :(
Too bad if i can't get both things to be done.
I was thinking of creating my cursor variable in the main procedure, and send it as an input parameter to P1, so that i can close the cursor from the main, in case a exceptionExactly why does the error backtrace not work? Have you tried recording it earlier rather than later? E.g.
SQL> create or replace type TStackStruct is object(
  2          time timestamp,                      
  3          sqlCode integer,                     
  4          stack   varchar2(32767)              
  5  );                                           
  6  /                                            
Type created.
SQL> create or replace type TStackArray is table of TStackStruct;
  2  /                                                          
Type created.
SQL> create or replace package SessionData is
  2          stackArray      TStackArray;   
  3          procedure AddException( errCode integer );
  4          function Stack return TStackArray;       
  5  end;                                             
  6  /                                                
Package created.
SQL> create or replace package body SessionData as
  2                                              
  3          procedure AddException( errCode integer )  is
  4          begin                                       
  5                  if stackArray is null then          
  6                          stackArray := new TStackArray();
  7                  end if;                                
  8                                                         
  9                  stackArray.Extend(1);                  
10                  stackArray( stackArray.Count ) := new TStackStruct( SysTimestamp, errCode, dbms_utility.format_error_backtrace );
11          end;                                                                                                                    
12                                                                                                                                  
13          function Stack return TStackArray is                                                                                    
14          begin                                                                                                                   
15                  return( stackArray );                                                                                           
16          end;                                                                                                                    
17                                                                                                                                  
18  end;                                                                                                                            
19  /                                                                                                                               
Package body created.
SQL> create or replace procedure ProcA is
  2  begin
  3          raise NO_DATA_FOUND;    --// ProcA line 3 : error source
  4  exception when OTHERS then
  5          SessionData.AddException( SQLCODE );
  6          raise;
  7  end;
  8  /
Procedure created.
SQL> create or replace procedure ProcB is
  2  begin
  3          ProcA;
  4  exception when OTHERS then
  5          SessionData.AddException( SQLCODE );
  6          raise;
  7  end;
  8  /
Procedure created.
SQL>
SQL> begin
  2          ProcB;
  3  exception when OTHERS then
  4          SessionData.AddException( SQLCODE );
  5          raise;
  6  end;
  7  /
begin
ERROR at line 1:
ORA-01403: no data found
ORA-06512: at line 5
SQL>
SQL> select * from TABLE(SessionData.Stack);
TIME                              SQLCODE STACK
08/MAR/12 18:38:09.425072             100 ORA-06512: at "BILLY.PROCA", line 3
08/MAR/12 18:38:09.425384             100 ORA-06512: at "BILLY.PROCA", line 6
                                          ORA-06512: at "BILLY.PROCB", line 3
08/MAR/12 18:38:09.425463             100 ORA-06512: at "BILLY.PROCB", line 6
                                          ORA-06512: at line 2