Why does my function not return anything when I create as a schema object

Question

I have user ABC who owns several tables some of which have foreign key constraints.
I have user XYZ that has been granted access to all tables owned by user ABC.
When I create a function as user XYZ using following I get no return when I issue:
select XYZ.ztm_tables_depended_on('ABC', 'A_TABLE_OWNED_BY_ABC') from dual :
Please see after function definition.
CREATE OR REPLACE FUNCTION ZTM_TABLES_DEPENDED_ON(p_Owner VARCHAR2, p_Table_Name VARCHAR2) RETURN VARCHAR2 IS
  CURSOR C1 IS
  SELECT OWNER, CONSTRAINT_NAME, R_OWNER, R_CONSTRAINT_NAME
  FROM   ALL_CONSTRAINTS
  WHERE  OWNER           = p_Owner
  AND    TABLE_NAME      = p_Table_Name
  AND    CONSTRAINT_TYPE = 'R'
  ORDER  BY OWNER, CONSTRAINT_NAME, R_OWNER, R_CONSTRAINT_NAME;
  v_Referenced_Owner       VARCHAR2(31);
  v_Ret_Val                VARCHAR2(4000);
  FUNCTION CONSTRAINT_TABLE_NAME(p_Owner VARCHAR2, p_Constraint_Name VARCHAR2) RETURN VARCHAR2 IS
    CURSOR C1 IS
    SELECT TABLE_NAME
    FROM   ALL_CONSTRAINTS
    WHERE  OWNER           = p_Owner
    AND    CONSTRAINT_NAME = p_Constraint_Name;
    v_Ret_Val ALL_CONSTRAINTS.TABLE_NAME%TYPE;
  BEGIN
    OPEN  C1;
    FETCH C1 INTO v_Ret_Val;
    CLOSE C1;
    RETURN v_Ret_Val;
  END;
BEGIN
  FOR R IN C1 LOOP
    IF (R.OWNER <> R.R_OWNER) THEN v_Referenced_Owner := R.R_OWNER || '.';
    ELSE                           v_Referenced_Owner := NULL;
    END IF;
    v_Ret_Val := v_Ret_Val || ', ' || v_Referenced_Owner || CONSTRAINT_TABLE_NAME (R.R_OWNER, R.R_CONSTRAINT_NAME);
  END LOOP;
  RETURN LTRIM(v_Ret_Val, ', ');
END;
But, if I embed the function within an anonymous block as follows, I get results:
DECLARE
  CURSOR C1 IS
  select owner, table_name
  FROM   all_tables where owner = 'ABC';
  FUNCTION ZTM_TABLES_DEPENDED_ON(p_Owner VARCHAR2, p_Table_Name VARCHAR2) RETURN VARCHAR2 IS
    CURSOR C1 IS
    SELECT OWNER, CONSTRAINT_NAME, R_OWNER, R_CONSTRAINT_NAME
    FROM   ALL_CONSTRAINTS
    WHERE  OWNER           = p_Owner
    AND    TABLE_NAME      = p_Table_Name
    AND    CONSTRAINT_TYPE = 'R'
    ORDER  BY OWNER, CONSTRAINT_NAME, R_OWNER, R_CONSTRAINT_NAME;
    v_Referenced_Owner       VARCHAR2(31);
    v_Ret_Val                VARCHAR2(4000);
    FUNCTION CONSTRAINT_TABLE_NAME(p_Owner VARCHAR2, p_Constraint_Name VARCHAR2) RETURN VARCHAR2 IS
      CURSOR C1 IS
      SELECT TABLE_NAME
      FROM   ALL_CONSTRAINTS
      WHERE  OWNER           = p_Owner
      AND    CONSTRAINT_NAME = p_Constraint_Name;
      v_Ret_Val ALL_CONSTRAINTS.TABLE_NAME%TYPE;
    BEGIN
      OPEN  C1;
      FETCH C1 INTO v_Ret_Val;
      CLOSE C1;
      RETURN v_Ret_Val;
    END;
  BEGIN
    FOR R IN C1 LOOP
      IF (R.OWNER <> R.R_OWNER) THEN v_Referenced_Owner := R.R_OWNER || '.';
      ELSE                           v_Referenced_Owner := NULL;
      END IF;
      v_Ret_Val := v_Ret_Val || ', ' || v_Referenced_Owner || CONSTRAINT_TABLE_NAME (R.R_OWNER, R.R_CONSTRAINT_NAME);
    END LOOP;
    RETURN LTRIM(v_Ret_Val, ', ');
  END;
BEGIN
  FOR R IN C1 LOOP
    DBMS_OUTPUT.PUT_LINE(ztm_tables_depended_on(R.Owner, R.Table_Name));
  END LOOP;
END;
Any ideas what is happening here?

Answer 1

Any ideas what is happening here?
Justin explained the probable reason.
See the 'How Roles Work in PL/SQL Blocks' section of the database security doc for the details
http://docs.oracle.com/cd/E25054_01/network.1111/e16543/authorization.htm#i1007304
How Roles Work in PL/SQL Blocks
The use of roles in a PL/SQL block depends on whether it is an anonymous block or a named block (stored procedure, function, or trigger), and whether it executes with definer's rights or invoker's rights.
Roles Used in Named Blocks with Definer's Rights
All roles are disabled in any named PL/SQL block (stored procedure, function, or trigger) that executes with definer's rights. Roles are not used for privilege checking and you cannot set roles within a definer's rights procedure.
The SESSION_ROLES view shows all roles that are currently enabled. If a named PL/SQL block that executes with definer's rights queries SESSION_ROLES, then the query does not return any rows.
Roles Used in Named Blocks with Invoker's Rights and Anonymous PL/SQL Blocks
Named PL/SQL blocks that execute with invoker's rights and anonymous PL/SQL blocks are executed based on privileges granted through enabled roles. Current roles are used for privilege checking within an invoker's rights PL/SQL block. You can use dynamic SQL to set a role in the session.
See that line starting with 'All roles are disables in any named PL/SQL block'?